I_IN_STODocument

@AbapCatalog.sqlViewName: 'IINSTODOC'
@VDM.viewType: #COMPOSITE

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'STO GR verified Documents for Invoice'
define view I_IN_STODocument
  as select from    I_IN_STOBilling 
    left outer join I_AccountingDocument on  I_IN_STOBilling.DocumentReferenceID = I_AccountingDocument.DocumentReferenceID
                                               and  I_AccountingDocument.ReferenceDocumentType = 'BKPFF' 
                                               and  I_AccountingDocument.ReverseDocument = ' ' 
                                               and  I_AccountingDocument.ReverseDocumentFiscalYear = '0000'
  association [1..1] to I_CompanyCode      as _CompanyCode      on $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to I_CompanyCodeStdVH as _CompanyCodeStdVH on $projection.CompanyCode = _CompanyCodeStdVH.CompanyCode
  association [1..1] to I_Plant            as _SupplyingPlant   on $projection.SupplyingPlant = _SupplyingPlant.Plant
  association [1..1] to I_Plant            as _ReceivingPlant   on $projection.ReceivingPlant = _ReceivingPlant.Plant 

{
  key PurchasingDocument,
  key PurchasingHistoryDocument as DeliveryDocument,
      AccountingDocument,
      PurchasingHistoryDocumentType,
      PurchasingHistoryDocumentYear,
      STOCreationDate,
      cast(left (STOCreationDate, 4) as abap.numc( 4 )) as CreationDateYear,
      cast(substring(STOCreationDate, 5, 2) as abap.numc( 2 )) as CreationDateMonth,
      I_IN_STOBilling.CompanyCode,
      SupplyingPlant,
      Plant                     as ReceivingPlant,
      PurchasingDocumentCategory,
      PurchasingHistoryCategory,
      BillingDocument,
      CreationDate              as BillingDocCreationDate,
      I_IN_STOBilling.DocumentReferenceID,
      I_IN_STOBilling.BillingDocumentType,
      I_IN_STOBilling.PostingDate,
      I_AccountingDocument.DocumentReferenceID as ExternalDocumentReferenceID,
      SubsequentDocument,

      /* Association */
      _CompanyCode,
//       _CompanyCodeStdVH,

      _SupplyingPlant,
      _ReceivingPlant
}