I_FixedAssetCountryData

@AbapCatalog: {sqlViewName:'IFIASTCNTRYDATA', preserveKey: true}
@Analytics: { dataCategory: #DIMENSION,
              dataExtraction: {
                  enabled: true,
                  delta.changeDataCapture: {
                      mapping:[
                          { table: 'glo_faat_md', role: #MAIN,
                            viewElement: ['CompanyCode', 'MasterFixedAsset','FixedAsset'],
                            tableElement: ['comp_code', 'asset_no','asset_subno']
                          },
                          { table: 't001', role: #LEFT_OUTER_TO_ONE_JOIN,
                            viewElement: ['CompanyCode'],
                            tableElement: ['bukrs']
                          }]
                        }
                    }
                 }
@EndUserText.label: 'Country/Region Specific Fixed Asset'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: { representativeKey: 'FixedAsset',
                usageType.serviceQuality: #C,
                usageType.sizeCategory: #L,
                usageType.dataClass: #MASTER }
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE]
@Metadata:{ignorePropagatedAnnotations: true, allowExtensions:true}
@ObjectModel.sapObjectNodeType.name: 'FixedAsset'

define view I_FixedAssetCountryData

  as select from glo_faat_md
    left outer to one join t001                                 on t001.bukrs = glo_faat_md.comp_code
  //Association with Asset Master Reference

  association [1..1] to I_FixedAsset       as _FixedAsset       on  $projection.CompanyCode      = _FixedAsset.CompanyCode
                                                                and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
                                                                and $projection.FixedAsset       = _FixedAsset.FixedAsset

  association [0..1] to I_CompanyCode      as _CompanyCode      on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_Country          as _Country          on  $projection.Country = _Country.Country
  association [0..1] to I_MasterFixedAsset as _MasterFixedAsset on  $projection.CompanyCode      = _MasterFixedAsset.CompanyCode
                                                                and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset
{
      //Key fields

      @ObjectModel.foreignKey.association: '_CompanyCode'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
  key glo_faat_md.comp_code as CompanyCode,
      @ObjectModel.foreignKey.association: '_MasterFixedAsset'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MasterFixedAssetStdVH', element: 'MasterFixedAsset' },
                                            additionalBinding:  [ { localElement: 'CompanyCode', element:'CompanyCode' } ]
                                        } ]
  key glo_faat_md.asset_no as MasterFixedAsset,
  key glo_faat_md.asset_subno as FixedAsset,

      //National Classification

      glo_faat_md.glo_natl_clfn_code as NationalClassification,
      glo_faat_md.glo_tax_depr_grp as TaxDepreciationGroup,

      //RU General Data

      glo_faat_md.glo_rus_sernr as RU_LongSerialNumber,
      glo_faat_md.glo_rus_matnr as RU_WorkwearMaterial,
      glo_faat_md.glo_rus_ret_asset_num as RU_RetiredMasterFixedAsset,
      glo_faat_md.glo_rus_ret_asset_sub as RU_RetiredFixedAsset,
    //RU Traceability

      glo_faat_md.glo_rus_trc_begd as RU_ProdTraceabilityStartDate,
      glo_faat_md.glo_rus_trc_endd as RU_ProdTraceabilityEndDate,  
      glo_faat_md.glo_rus_trc_tnved as RU_AssetTNVED,      
      //RU Transport Tax

      glo_faat_md.glo_rus_ttx_type as RU_AssetTransportType,
      glo_faat_md.glo_rus_ttx_vin as RU_VehicleIdNumber,
      glo_faat_md.glo_rus_ttx_mnfd as RU_ManufacturingDate,
      glo_faat_md.glo_rus_eco_cls as RU_VehicleEcologicalClass,
      glo_faat_md.glo_rus_prt_addr as RU_PropertyAddress,
      cast(glo_faat_md.glo_rus_prt_owrd as firu_real_estate_own_regn_date) as RU_PropertyOwnershipRegnDate,
      cast(glo_faat_md.glo_rus_prt_owtd as firu_real_estate_own_term_date) as RU_PropertyOwnershipTermnDate,

      //JP specific fields for Property Tax Report and Annex-16 Report

      glo_faat_md.glo_jp_ax16_strc as JP_Annex16AssetStructure,
      glo_faat_md.glo_jp_ax16_item as JP_Annex16AssetItem,
      glo_faat_md.glo_jp_ax16_lease_agreement_da as JP_Annex16LeasingAgrmtDate,
      glo_faat_md.glo_jp_ptx_city_code as JP_PrptyTxRptCity,
      glo_faat_md.glo_jp_ptx_classification_key as JP_PrptyTxRptClassfctnKey,
      glo_faat_md.glo_jp_ptx_special_dep_code as JP_PrptyTxRptSpclDepr,
      cast(glo_faat_md.glo_jp_ptx_additional_depr_cod as glo_jp_propt_prdcd) as JP_PrptyTxRptAddlDepr,

      //IN specific fields

      glo_faat_md.glo_in_blk_key as IN_AssetBlock,
      glo_faat_md.glo_in_ast_use as IN_AssetPutToUseDate,
      glo_faat_md.glo_in_adnlblk as IN_AdditionalAssetBlock,
      glo_faat_md.glo_in_r_d_asset as IN_AssetIsResearchAndDev,
      glo_faat_md.glo_in_prior_yr as IN_AssetIsPriorYear,

      //PT specific fields for Fiscal Maps

      glo_faat_md.glo_pt_vehicletype as PT_VehicleTypeByEnergy,
      glo_faat_md.glo_pt_isvehiclewolimit as PT_VehicleIsWithoutLimit,
      glo_faat_md.glo_pt_repairassetlink as PT_BigRepairAssetLink,
      glo_faat_md.glo_pt_landassetlink as PT_LandAssetLink,
      glo_faat_md.glo_pt_assetrepformcat as PT_AssetReportFormCategory,
      glo_faat_md.glo_pt_isamassetreval as PT_AmortizedAssetIsReevaluated,

      //IL Investment center

      glo_faat_md.glo_il_internal_code as IL_InvmtCtrInternalCode,
      glo_faat_md.glo_il_approval_number as IL_InvmtCtrApprovalDocNmbr,
      glo_faat_md.glo_il_approval_version as IL_InvmtCtrApprovalVersion,
      glo_faat_md.glo_il_bogus_anln1 as IL_InvmtCtrBogusAssetNumber,
      glo_faat_md.glo_il_asset_version as IL_InvmtCtrAssetVersion,
      
      //RS specific fields in new asset master

      glo_faat_md.glo_rs_exclusion_year as RS_GroupDeprExclusionYear,
      glo_faat_md.glo_rs_last_invoice_date as RS_AssetLastInvoiceDate,
      
      //PL specific fields in new asset master

      glo_faat_md.glo_pl_acqn_prodn_date   as PL_AcquisitionProductionDate,
      glo_faat_md.glo_pl_acqn_doc_type     as PL_AcquisitionDocumentType,
      glo_faat_md.glo_pl_acqn_form_nmbr    as PL_AcquisitionFormNumber,
      glo_faat_md.glo_pl_ast_tax_group     as PL_AssetTaxGroup,
      
      @ObjectModel.foreignKey.association: '_Country'
      t001.land1 as Country,

      // Define association to parent

      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _CompanyCode,
      _Country,
      _FixedAsset,
      _MasterFixedAsset
}