I_MasterFixedAsset

DDL: I_MASTERFIXEDASSET Type: view BASIC Package: FINS_FIS_AA_MD

Master Fixed Asset

I_MasterFixedAsset is a Basic CDS View (Dimension) that provides data about "Master Fixed Asset" in SAP S/4HANA. It reads from 1 data source (faat_md_root) and exposes 6 fields with key fields CompanyCode, MasterFixedAsset. It has 2 associations to related views. Part of development package FINS_FIS_AA_MD.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
faat_md_root root from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_CompanyCode _CompanyCode $projection.CompanyCode = _CompanyCode.CompanyCode
[1..*] I_FixedAsset _FixedAsset $projection.CompanyCode = _FixedAsset.CompanyCode and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset

Annotations (14)

NameValueLevelField
AbapCatalog.sqlViewName IFIMASTFIXASSET view
AbapCatalog.preserveKey true view
Analytics.dataCategory #DIMENSION view
EndUserText.label Master Fixed Asset view
VDM.viewType #BASIC view
AccessControl.authorizationCheck #CHECK view
ObjectModel.representativeKey MasterFixedAsset view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.modelingPattern #ANALYTICAL_DIMENSION view
ClientHandling.algorithm #SESSION_VARIABLE view
Metadata.ignorePropagatedAnnotations true view
Metadata.allowExtensions true view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY CompanyCode faat_md_root comp_code
KEY MasterFixedAsset faat_md_root asset_no
MasterFixedAssetDescription
AssetAuthorizationContext
_CompanyCode _CompanyCode
_FixedAsset _FixedAsset 
@AbapCatalog: {sqlViewName: 'IFIMASTFIXASSET', preserveKey: true}
@Analytics: { dataCategory: #DIMENSION }
@EndUserText.label: 'Master Fixed Asset'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: { representativeKey: 'MasterFixedAsset',
                usageType.serviceQuality: #A,
                usageType.sizeCategory: #XL,
                usageType.dataClass: #MASTER,
                modelingPattern: #ANALYTICAL_DIMENSION,
                supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE]
              }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata: {ignorePropagatedAnnotations: true, allowExtensions:true}

define view I_MasterFixedAsset
  as select from           faat_md_root as root
    left outer to one join faat_md      as main on  main.comp_code   = root.comp_code
                                                and main.asset_no    = root.asset_no
                                                and main.asset_subno = root.asset_subno

  association [1..1] to I_CompanyCode as _CompanyCode on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..*] to I_FixedAsset  as _FixedAsset  on  $projection.CompanyCode      = _FixedAsset.CompanyCode
                                                      and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
  key root.comp_code                    as CompanyCode,
      @ObjectModel.text.element:  [ 'MasterFixedAssetDescription' ]
  key root.asset_no                     as MasterFixedAsset,

      @Semantics.text: true
      cast(main.description as anlhtxt) as MasterFixedAssetDescription,

      @Consumption.hidden: true
      @VDM.lifecycle.status: #DEPRECATED
      cast('NEW' as  faa_authcntxt)     as AssetAuthorizationContext, //Needed for DCL


      _CompanyCode,
      _FixedAsset
}
where
      root.is_main_asset    =  'X'
  and root.lifecycle_status <> '2'
  and root.lifecycle_status <> '8'

Learn More