I_EnterpriseProjectTP_2

@Metadata.ignorePropagatedAnnotations: true

@AccessControl: {
    authorizationCheck:     #CHECK,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}

@ObjectModel: {
   sapObjectNodeType:{
      name: 'EnterpriseProject'},
    usageType: {
      dataClass:       #MASTER,
      serviceQuality:  #C,
      sizeCategory:    #XL
    }
}

@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API
}

@EndUserText.label: 'Appl. Interface for Enterprise Project'
define root view entity I_EnterpriseProjectTP_2
  as select from R_EnterpriseProject as _Project
  composition [0..1] of I_EnterpriseProjectJVATP_2     as _EnterpriseProjectJVA
  composition [0..1] of I_EntProjectPublicSectorTP_2   as _EntProjectPublicSector
  composition [0..*] of I_EnterpriseProjectElementTP_2 as _EnterpriseProjectElement
  composition [0..*] of I_EntProjProjectObjectLinkTP   as _EntProjProjectObjectLink
  composition [0..1] of R_EntProjectBlockFunctionTP_2  as _EntProjBlkFunc
  composition [0..*] of R_EnterpriseProjectRoleTP      as _EntProjRole
  composition [0..*] of R_EntProjectTeamMemberTP       as _EntProjTeamMember
  composition [0..*] of R_EntProjTeamRoleStaffIntTP    as _EntProjRoleStaffing
  composition [0..*] of R_EnterpriseProjectHierarchyTP as _EntProjHierarchy
  composition [0..*] of R_EntProjectElementChangeTP    as _EntProjElemChange
  composition [1..1] of R_EntProjLongDescriptionTP     as _EntProjLongDesc
  composition [0..*] of R_EntProjStatusAreaTP          as _EntProjStatusArea

  association [0..*] to I_EnterpriseProjectElementTP_2 as _ProjWBSElement             on  _ProjWBSElement.ProjectUUID        = $projection.ProjectUUID
                                                                                      and _ProjWBSElement.IsProjectMilestone = ''
  association [0..*] to I_EnterpriseProjectElementTP_2 as _ProjMilestone              on  _ProjMilestone.ProjectUUID        = $projection.ProjectUUID
                                                                                      and _ProjMilestone.IsProjectMilestone = 'X'

  association [1..1] to R_EntProjTeamRoleStaffIntTP    as _EntProjManager             on  _EntProjManager.ProjectUUID = $projection.ProjectUUID
  association [1..1] to R_EntProjStatusAreaTP          as _StatusAreaData             on  _StatusAreaData.ProjectUUID = $projection.ProjectUUID
  association [1..1] to R_EntProjectNextEsnlMilestone  as _NextEsnlMilestone          on  _NextEsnlMilestone.ProjectUUID = $projection.ProjectUUID
  association [1..1] to R_EntProjectNextRlvtMilestone  as _NextRlvtMilestone          on  _NextRlvtMilestone.ProjectUUID = $projection.ProjectUUID
  association [0..1] to I_EntProjWorkflowOverview      as _EntProjWorkflowOverview    on  _EntProjWorkflowOverview.ProjectUUID = $projection.ProjectUUID
  association [0..*] to R_EnterpriseProjectBriefCost   as _ProjectCostLineItem        on  _ProjectCostLineItem.ProjectInternalID = $projection.ProjectInternalID
  association [0..1] to I_EntProjUserRoleAssignment    as _EntProjUserRoleAssignment  on  _EntProjUserRoleAssignment.ProjectUUID = $projection.ProjectUUID
  // Association for extensibility

  association [1..1] to E_PPM_Project                  as _ProjectHeaderExtension     on  $projection.ProjectUUID = _ProjectHeaderExtension.ProjectUUID
  association [1..1] to E_PPM_EngagementProject        as _EngagementProjectExtension on  $projection.ProjectUUID = _EngagementProjectExtension.ProjectUUID
{
  key ProjectUUID                            as ProjectUUID,
      ProjectSummaryTaskUUID                 as ProjectSummaryTaskUUID,
      ProjectInternalID                      as ProjectInternalID,
      Project                                as Project,

      @Consumption.hidden: true
      ProjectCategory                        as ProjectCategory,
      ProjectDescription                     as ProjectDescription,
      EnterpriseProjectType                  as EnterpriseProjectType,
      PriorityCode                           as PriorityCode,
      ProjectStartDate                       as ProjectStartDate,
      ProjectEndDate                         as ProjectEndDate,
      ActualStartDate                        as ActualStartDate,
      ActualFinishDate                       as ActualEndDate,
      //2008 C4P Harmonization Start

      CustomerUUID                           as CustomerUUID,
      EnterpriseProjectServiceOrg            as EnterpriseProjectServiceOrg,
      @Semantics.booleanIndicator
      EntProjectIsConfidential               as EntProjectIsConfidential,
      RestrictedTimePosting                  as RestrictedTimePosting,
      //2008 C4P Harmonization End

      ProcessingStatus                       as ProcessingStatus,
      ResponsibleCostCenter                  as ResponsibleCostCenter,

      ProfitCenter                           as ProfitCenter,
      ProjectProfileCode                     as ProjectProfileCode,
      FunctionalArea                         as FunctionalArea,
      CompanyCode                            as CompanyCode,
      ControllingArea                        as ControllingArea,
      Plant                                  as Plant,
      Location                               as Location,
      TaxJurisdiction                        as TaxJurisdiction,
      Currency                               as ProjectCurrency,
      AvailabilityControlProfile             as AvailabilityControlProfile,
      AvailabilityControlIsActive            as AvailabilityControlIsActive,

      FunctionalLocation                     as FunctionalLocation,
      InvestmentProfile                      as InvestmentProfile,
      IsBillingRelevant                      as IsBillingRelevant,
      LastChangeDateTime                     as LastChangeDateTime,
      LastChangedByUser                      as LastChangedByUser,
      ProjectLastChangedDateTime             as ProjectLastChangedDateTime,
      ProjectLastChangedByUser               as ProjectLastChangedByUser,
      //2102 SD eppm N:1 indicator

      EntProjIsMultiSlsOrdItmsEnbld          as EntProjIsMultiSlsOrdItmsEnbld,

      // CE2602 Profitability Segment

      EntProjProfitabilitySegment            as EntProjProfitabilitySegment,

      cast ( '' as boole_d preserving type ) as EntProjDemandCopyIsRequested,
      cast ( '' as boole_d preserving type ) as EntProjSettlmtRuleCpyIsReqd,

      EntProjHasProjectStockEnabled          as EntProjHasProjectStockEnabled,
      EntProjectSettlementType               as EntProjectSettlementType,
      EntProjectSettlementElement            as EntProjectSettlementElement,
      InventorySpecialStockValnType          as InventorySpecialStockValnType,
//      EntProjSettlementRuleControl           as EntProjSettlementRuleControl,


      //2202 Enable draft for RAP BO ---Start

      CreatedByUser                          as CreatedByUser,
      CreationDateTime                       as CreationDateTime,
      LeadingSalesOrder                      as LeadingSalesOrder,
      LeadingSalesOrderItem                  as LeadingSalesOrderItem,
      ResultAnalysisInternalID               as ResultAnalysisInternalID,
      WBSElementInternalID                   as WBSElementInternalID,

      FactoryCalendar                        as FactoryCalendar,
      WBSElementObject                       as WBSElementObject,
      ProjectObject                          as ProjectObject,
      CostingSheet                           as CostingSheet,
      CostCenter                             as CostCenter,
      WBSIsStatisticalWBSElement             as IsStatistical,
      ProjectTemplateUUID                    as ProjectTemplateUUID,
      cast( '' as bu_partner )               as ProjectManager,
      //    IsMyProject                            as IsMyProject,

      //    MasterProjectIsConfidential            as MasterProjectIsConfidential,


      //2202 Enable draft for RAP BO ---End

      _EntProjManager,
      _StatusAreaData,
      _NextEsnlMilestone,
      _NextRlvtMilestone,
      _ProcessingStatusText,
      _ProjectProfileText,
      _FunctionalLocationText,
      _PriorityText,
      _AvailabilityCtrlProfileText,
      _FunctionalAreaText,
      _InvestmentProfileText,
      _EnterpriseProjectTypeText,
      _EntProjectSettlementTypeText,
      _RsltAnlysKeyText,

      _ControllingArea,
      _ResponsibleCostCenter,
      _ProfitCenter,
      _CreatedByUser,
      _CostCenter,
      _EntProjWorkflowOverview,
      _CompanyCode,
      _Plant,
      _Location,
      _CostingSheetProcedure,

      _ProjWBSElement,
      _ProjMilestone,

      _EnterpriseProjectJVA,
      _EntProjectPublicSector,
      _EnterpriseProjectElement,
      _EntProjBlkFunc,
      _EntProjProjectObjectLink,
      _EntProjRole,
      _EntProjTeamMember,
      _EntProjRoleStaffing,
      _EntProjElemChange,
      _EntProjLongDesc,
      _EntProjHierarchy,
      _ProjectCostLineItem,
      _EntProjStatusArea,
      _CustomerToBusinessPartner,
      _EnterpriseProjectSrvcOrgText,
      _EntProjProfnlSrvcProjStgeTxt,
      _EnterpriseProjectForUser,
      _ProjectCurrencyText,
      _EntProjUserRoleAssignment
}