I_EnterpriseProjectElementTP_2

@Metadata.ignorePropagatedAnnotations: true

@AccessControl: {
    authorizationCheck:     #CHECK,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}

@ObjectModel: {
    semanticKey:       [ 'ProjectElement' ],
    representativeKey: 'ProjectElementUUID',
    alternativeKey: [ { id : 'WBSElementInternalID',       element: ['WBSElementInternalID'],         uniqueness: #UNIQUE } ],
    usageType: {
      dataClass:       #MASTER,
      serviceQuality:  #C,
      sizeCategory:    #XL
    }
}

@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API
}
@EndUserText.label: 'Version2 of TP-view for EPPM CRUD API'


define view entity I_EnterpriseProjectElementTP_2
  as select from R_EnterpriseProjectElement as Workpackage


  association        to parent I_EnterpriseProjectTP_2 as _EnterpriseProject           on  $projection.ProjectUUID = _EnterpriseProject.ProjectUUID

  association [0..1] to I_EnterpriseProjectElementTP_2 as _ParentProjElement           on  $projection.ParentObjectUUID = _ParentProjElement.ProjectElementUUID
  association [1..*] to I_EnterpriseProjectElementTP_2 as _SubProjElement              on  $projection.ProjectElementUUID = _SubProjElement.ParentObjectUUID

  association [0..1] to I_EnterpriseProjectElementTP_2 as _ParentMilestone             on  $projection.ParentObjectUUID        = _ParentMilestone.ProjectElementUUID
                                                                                       and _ParentMilestone.IsProjectMilestone = 'X'
  association [1..*] to I_EnterpriseProjectElementTP_2 as _ChildMilestone              on  $projection.ProjectElementUUID     = _ChildMilestone.ParentObjectUUID
                                                                                       and _ChildMilestone.IsProjectMilestone = 'X'

  association [0..1] to I_EnterpriseProjectElementTP_2 as _ParentWBSElement            on  $projection.ParentObjectUUID         = _ParentWBSElement.ProjectElementUUID
                                                                                       and _ParentWBSElement.IsProjectMilestone = ''
  association [1..*] to I_EnterpriseProjectElementTP_2 as _ChildWBSElement             on  $projection.ProjectElementUUID      = _ChildWBSElement.ParentObjectUUID
                                                                                       and _ChildWBSElement.IsProjectMilestone = ''
                                                                                       
  // Cross BO   

  association [0..*] to I_ProjectDemandTP              as _Team                        on  _Team.ReferencedObjectUUID            = $projection.ProjectElementUUID 
                                                                                       and _Team.ProjectDemandType               = 'S302'
                                                                                       
  association [0..*] to I_ProjectDemandTP              as _Expense                     on  _Expense.ReferencedObjectUUID         = $projection.ProjectElementUUID 
                                                                                       and _Expense.ProjectDemandType            = 'S401' 
                                                                                       
  ---Extension Association
  association [1..1] to E_PPM_Task                     as _ProjectElementExtension     on  $projection.ProjectElementUUID = _ProjectElementExtension.TaskUUID
  association [1..1] to E_PPM_EngagementProjElmnt      as _EngagementProjElmtExtension on  $projection.ProjectElementUUID = _EngagementProjElmtExtension.TaskUUID
  composition [0..1] of I_EntProjectElementJVATP_2     as _EntProjectElementJVA
  composition [0..1] of I_EntProjElmntPublicSectorTP_2 as _EntProjectElmntPublicSector
  composition [0..1] of R_EntProjElmntBlockFuncTP_2    as _EntProjElmntBlkFunc
  composition [0..1] of R_EntProjElmntLongDescTP       as _EntProjElmntLongDesc
  composition [0..*] of R_EntProjElmntDlvbrlTP         as _EntProjElmntDlvbrl
  composition [0..*] of R_EntProjElmntWorkItemTP       as _EntProjElmntWorkItem
  //composition [0..1] of R_EntProjElmntIntIdfrTP        as _EntProjElmntIntIdfr


{
  key Workpackage.ProjectElementUUID,
      Workpackage.ProjectElement,
      Workpackage.WBSElementInternalID,
      Workpackage.ProjectUUID                                   as ProjectUUID,
      Workpackage.ProjectElementDescription,
      Workpackage.ParentObjectUUID                              as ParentObjectUUID,
      Workpackage.TaskTemplateUUID                              as TaskTemplateUUID,
      Workpackage.ProjectElementOrdinalNumber                   as ProjectElementOrdinalNumber,
      Workpackage.ProcessingStatus                              as ProcessingStatus,
      @Semantics.booleanIndicator: true
      Workpackage.IsProjectMilestone                            as IsProjectMilestone,
      Workpackage.PlannedStartDate                              as PlannedStartDate,
      Workpackage.PlannedEndDate                                as PlannedEndDate,
      Workpackage.ActualStartDate                               as ActualStartDate,
      Workpackage.ActualFinishDate                              as ActualEndDate,
      Workpackage.ResponsibleCostCenter                         as ResponsibleCostCenter,
      Workpackage.CompanyCode                                   as CompanyCode,
      Workpackage.ProfitCenter                                  as ProfitCenter,
      Workpackage.FunctionalArea                                as FunctionalArea,
      Workpackage.ControllingArea                               as ControllingArea,
      Workpackage.Plant                                         as Plant,
      Workpackage.Location                                      as Location,
      Workpackage.TaxJurisdiction                               as TaxJurisdiction,
      Workpackage.FunctionalLocation                            as FunctionalLocation,
      Workpackage.EntProjectElementType,
      Workpackage.FactoryCalendar                               as FactoryCalendar,
      Workpackage.CostingSheet                                  as CostingSheet,
      Workpackage.InvestmentProfile                             as InvestmentProfile,
      Workpackage.WBSIsStatisticalWBSElement                    as WBSIsStatisticalWBSElement,
      Workpackage.CostCenter                                    as CostCenter,
      Workpackage.WBSElementIsBillingElement                    as WBSElementIsBillingElement,
      Workpackage.ResultAnalysisInternalID                      as ResultAnalysisInternalID,
      Workpackage.LeadingSalesOrder                             as LeadingSalesOrder,
      Workpackage.LeadingSalesOrderItem                         as LeadingSalesOrderItem,
      Workpackage.EntProjectElementObjectType                   as EntProjectElementObjectType,
      // CE2408 Hierarchical Settlement Changes

      Workpackage.EntProjectSettlementElement,
      Workpackage.EntProjIsSettlmtRuleInherited,
      // CE2602 Profitability Segment

      Workpackage.EntProjProfitabilitySegment                   as EntProjProfitabilitySegment,

      //admin data

      Workpackage.CreatedByUser                                 as CreatedByUser,
      Workpackage.CreationDateTime                              as CreationDateTime,
      Workpackage.LastChangedByUser                             as LastChangedByUser,
      Workpackage.LastChangeDateTime                            as LastChangeDateTime, 

      //Milestone

      Workpackage.ForecastedEndDate,
      Workpackage.MilestoneApprovalStatus,
      Workpackage.IsMainMilestone,

      //      //Hierarchy

      cast('' as abap.char( 50 ) )                              as HierarchyNode,
      cast( '' as abap.sstring(1333) )                          as HierarchyParentNode,
      cast( 0 as abap.int4 )                                    as HierarchyDistanceFromRoot,
      cast( 0 as abap.int4 )                                    as HierarchyDescendantCount,
      cast( '' as abap.char(22) )                               as HierarchyDrillState, // leaf, expanded, collapsed

      cast( 0 as hum_hierarchy_rank )                           as HierarchyRank,
      cast( 0 as abap.int4 )                                    as HierarchyLevel,

      cast ( '' as boole_d preserving type )                    as EntProjElmntDmndCpyIsReqd,
      cast ( '' as boole_d preserving type )                    as EntProjElmntSettlmtCpyIsReqd,
      // Category 7 Professional Service Application (Fiori)

      cast ( 0 as /s4ppm/tv_distributiontype preserving type )  as EntProjElmntDistributionOption,
      

      //For Authorization

      @Consumption.hidden: true
      _EnterpriseProject.ProjectCategory                        as ProjectCategory,
      @Consumption.hidden: true
      _EnterpriseProject.EnterpriseProjectServiceOrg            as EnterpriseProjectServiceOrg,
      //Association


      _ProcessingStatusText,
      _InvestmentProfileText,
      _FunctionalAreaText,
      _FactoryCalendarText,
      _FunctionalLocationText,
      _CostCenter,
      _ResponsibleCostCenter,
      _ProfitCenter,
      _CreatedByUser,
      _LastChangedByUser,
      _CompanyCode,
      _Plant,
      _ControllingArea,
      _MilestoneApprovalStatus,
      _MilestoneApprovalStatusText,
      _RsltAnlysKeyText,

      _EnterpriseProject,

      _ParentProjElement,
      _SubProjElement,
      _ParentMilestone,
      _ChildMilestone,
      _ParentWBSElement,
      _ChildWBSElement,

      _EntProjectElementJVA,
      _EntProjectElmntPublicSector,
      //      _ProjectElementExtension,

      _EntProjElmntBlkFunc,
      _EntProjElmntLongDesc,
      @Semantics.valueRange.maximum: '1'
      _EntProjElmntDlvbrl,
      _EntProjElmntWorkItem,
      _EnterpriseProjectForUser,
      
      // Cross BO

      _Team,
      _Expense
      //_EntProjElmntIntIdfr


}