I_EntProjElmntBlockFuncTP

@AbapCatalog.sqlViewName: 'IBLOCKFUNCTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Transactional processing for Block Functions'

@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API
}
@ObjectModel: {
   writeDraftPersistence: 'ENT_PROBJ_BLK_D',

   representativeKey: 'TaskUUID',

   createEnabled:         true,
   updateEnabled:         true,
   deleteEnabled:         true,
     usageType:
     {
       serviceQuality:  #D,
       dataClass:       #MIXED,
       sizeCategory:    #L
     }
   }


@ClientHandling.algorithm: #SESSION_VARIABLE
define view I_EntProjElmntBlockFuncTP
  as select from I_BlockFuncForEntProjElmnt 

  association [1..1] to I_PPM_ProjectTaskTP as _Task        on $projection.TaskUUID = _Task.TaskUUID
  association [1..1] to I_PPM_ProjectTP     as _Root        on $projection.ProjectUUID = _Root.ProjectUUID
{
      @ObjectModel.readOnly
  key TaskUUID                                                      as TaskUUID,
      @ObjectModel.readOnly
      ProjectUUID                                                   as ProjectUUID,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast(EntProjTimeRecgIsBlkd as boolean preserving type )  as EntProjTimeRecgIsBlkd,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast(EntProjStaffExpensePostgIsBlkd as boolean preserving type ) as EntProjStaffExpensePostgIsBlkd,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast(EntProjServicePostingIsBlkd as boolean preserving type )      as EntProjServicePostingIsBlkd,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast(EntProjOtherExpensePostgIsBlkd as boolean preserving type )   as EntProjOtherExpensePostgIsBlkd,
      
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      cast(EntProjPurchasingIsBlkd as boolean preserving type ) as EntProjPurchasingIsBlkd,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT ]
      _Task,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT ]
      _Root
      
}