I_BLOCKFUNCFORENTPROJELMNT

CDS View

Basic view for block function calculation

I_BLOCKFUNCFORENTPROJELMNT is a CDS View in S/4HANA. Basic view for block function calculation. It contains 1 fields. 5 CDS views read from this table.

Used by 5 CDS view(s) 1 fields

CDS Views using this table (5)

ViewTypeJoinVDMDescription
C_EntProjElmntBlkdFunc view_entity from CONSUMPTION Project Element Block Functions
I_EntProjElmntBlockFunc_3 view_entity from COMPOSITE Blocked Functions by Project Element
I_EntProjElmntBlockFuncTP view from TRANSACTIONAL Transactional processing for Block Functions
R_EntProjElmntBlockFuncTP view from TRANSACTIONAL Transactional Processing for proj elmnt block function
R_EntProjElmntBlockFuncTP_2 view_entity from TRANSACTIONAL Trans Proc for proj elmnt block function

Fields (1)

KeyField CDS FieldsUsed in Views
ProjectUUID ProjectUUID 2 
@AbapCatalog.sqlViewName: 'IBLOCKFUNC'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@AccessControl.personalData.blocking:  #BLOCKED_DATA_EXCLUDED
@VDM: {
    viewType: #COMPOSITE
}
@ObjectModel: {

   usageType: {
     serviceQuality:  #D,
     dataClass:       #MIXED,
     sizeCategory:    #L
    }
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Basic view for block function calculation'
// This view not to be used for customer access

define view I_BlockFuncForEntProjElmnt
  as select from           R_EnterpriseProjectElement as ProjectElement
    left outer to one join I_EntProjElmntBlockFunc    as EntProjTimeRecgIsBlkd          on  ProjectElement.ProjectElementUUID              = EntProjTimeRecgIsBlkd.ParentObjectUUID
                                                                                        and EntProjTimeRecgIsBlkd.EntProjElementFunctionID = 'S001'
    left outer to one join I_EntProjElmntBlockFunc    as EntProjStaffExpensePostgIsBlkd on  ProjectElement.ProjectElementUUID                       = EntProjStaffExpensePostgIsBlkd.ParentObjectUUID
                                                                                        and EntProjStaffExpensePostgIsBlkd.EntProjElementFunctionID = 'S003'
    left outer to one join I_EntProjElmntBlockFunc    as EntProjServicePostingIsBlkd    on  ProjectElement.ProjectElementUUID                    = EntProjServicePostingIsBlkd.ParentObjectUUID
                                                                                        and EntProjServicePostingIsBlkd.EntProjElementFunctionID = 'S002'
    left outer to one join I_EntProjElmntBlockFunc    as EntProjOtherExpensePostgIsBlkd on  ProjectElement.ProjectElementUUID                       = EntProjOtherExpensePostgIsBlkd.ParentObjectUUID
                                                                                        and EntProjOtherExpensePostgIsBlkd.EntProjElementFunctionID = 'S004'
    left outer to one join I_EntProjElmntBlockFunc    as EntProjProcurementIsBlkd       on  ProjectElement.ProjectElementUUID                 = EntProjProcurementIsBlkd.ParentObjectUUID
                                                                                        and EntProjProcurementIsBlkd.EntProjElementFunctionID = 'S005'
{


  key  ProjectElement.ProjectElementUUID          as TaskUUID,
       ProjectElement.ProjectUUID                 as ProjectUUID,

       ProjectElement.EntProjectElementObjectType as ObjectType,
       ProjectElement.IsProjectMilestone          as IsProjectMilestone,

       case
       when EntProjTimeRecgIsBlkd.EntProjElementFunctionIsBlkd is null
                 then ' '
             else EntProjTimeRecgIsBlkd.EntProjElementFunctionIsBlkd
         end                                      as EntProjTimeRecgIsBlkd,


       case
       when EntProjStaffExpensePostgIsBlkd.EntProjElementFunctionIsBlkd is null
           then ' '
       else EntProjStaffExpensePostgIsBlkd.EntProjElementFunctionIsBlkd
       end                                        as EntProjStaffExpensePostgIsBlkd,

       case
       when EntProjServicePostingIsBlkd.EntProjElementFunctionIsBlkd is null
           then ' '
       else EntProjServicePostingIsBlkd.EntProjElementFunctionIsBlkd
       end                                        as EntProjServicePostingIsBlkd,

       case
       when EntProjOtherExpensePostgIsBlkd.EntProjElementFunctionIsBlkd is null
           then ' '
       else EntProjOtherExpensePostgIsBlkd.EntProjElementFunctionIsBlkd
       end                                        as EntProjOtherExpensePostgIsBlkd,

       case
       when EntProjProcurementIsBlkd.EntProjElementFunctionIsBlkd is null
          then ' '
       else EntProjProcurementIsBlkd.EntProjElementFunctionIsBlkd
       end                                        as EntProjPurchasingIsBlkd


}

where
  ProjectElement.IsProjectMilestone <> 'X';

Learn More