I_CustomerReturnItemImport

@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@EndUserText.label: 'Item Fields for Customer Return Import'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED }

@VDM: {
  lifecycle.contract.type: #PUBLIC_LOCAL_API,
  viewType: #COMPOSITE
}

define view entity I_CustomerReturnItemImport
  as select from I_CustomerReturnItem as CustomerReturnItem
  left outer to one join I_AdvncdReturnsMgmtProcessItem as AdvncdRetsMgmtProcessItem on  AdvncdRetsMgmtProcessItem.ReturnsDocument     = CustomerReturnItem.CustomerReturn
                                                                                       and AdvncdRetsMgmtProcessItem.RetsMgmtProcess     = CustomerReturnItem.RetsMgmtProcess
                                                                                       and AdvncdRetsMgmtProcessItem.RetsMgmtProcessItem = CustomerReturnItem.CustomerReturnItem

  left outer to one join I_AdvncdReturnsMgmtProcessStep as AdvncdRetsMgmtProcessStep on  AdvncdRetsMgmtProcessStep.ReturnsDocument         = CustomerReturnItem.CustomerReturn
                                                                                       and AdvncdRetsMgmtProcessStep.RetsMgmtProcess         = CustomerReturnItem.RetsMgmtProcess
                                                                                       and AdvncdRetsMgmtProcessStep.RetsMgmtProcessItem     = CustomerReturnItem.CustomerReturnItem
                                                                                       and AdvncdRetsMgmtProcessStep.RetsMgmtProcItmQtySplit = '000'
                                                                                       and AdvncdRetsMgmtProcessStep.RetsMgmtProcessStep     = '0001'
                                                                                       and AdvncdRetsMgmtProcessStep.ReturnsDocumentType     = '00'
                                                                                                                                                                       
  // Associations

  association [1..1] to I_CustomerReturnImport        as _CustomerReturn
    on $projection.CustomerReturn = _CustomerReturn.CustomerReturn

  association [0..*] to I_SalesDocItemCompletePartner as _Partner
    on  $projection.CustomerReturn     = _Partner.SalesDocument
    and $projection.CustomerReturnItem = _Partner.SalesDocumentItem

  association [0..*] to I_SalesDocItemPricingElement  as _PricingElement
    on  $projection.CustomerReturn     = _PricingElement.SalesDocument
    and $projection.CustomerReturnItem = _PricingElement.SalesDocumentItem

  // Extensibility

  association [0..1] to E_SalesDocumentItemBasic      as _Extension
    on  CustomerReturnItem.CustomerReturn     = _Extension.SalesDocument
    and CustomerReturnItem.CustomerReturnItem = _Extension.SalesDocumentItem

{
  key CustomerReturnItem.CustomerReturn,
  key CustomerReturnItem.CustomerReturnItem,

      cast( '' as char6 ) as SourceSalesDocumentItemText,
      CustomerReturnItem.HigherLevelItem,

      CustomerReturnItem.CustomerReturnItemCategory,

      CustomerReturnItem.CustomerReturnItemText,

      CustomerReturnItem.PurchaseOrderByCustomer,
      CustomerReturnItem.Product,
      CustomerReturnItem.Material,
      CustomerReturnItem.MaterialByCustomer,
      CustomerReturnItem.ProductConfiguration,

      CustomerReturnItem.ProductGroup,
      CustomerReturnItem.Batch,

      @Semantics.quantity.unitOfMeasure: 'RequestedQuantityUnit'
      CustomerReturnItem.RequestedQuantity,

      CustomerReturnItem.RequestedQuantityUnit,

      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      CustomerReturnItem.ItemGrossWeight,

      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      CustomerReturnItem.ItemNetWeight,

      CustomerReturnItem.ItemWeightUnit,

      @Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
      CustomerReturnItem.ItemVolume,

      CustomerReturnItem.ItemVolumeUnit,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.NetAmount,

      CustomerReturnItem.TransactionCurrency,
      CustomerReturnItem.PricingDate,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.TaxAmount,

      CustomerReturnItem.MatlAccountAssignmentGroup,
      CustomerReturnItem.ControllingArea,

      cast(CustomerReturnItem.Plant as wsubst_rec_plant preserving type) as ProductionPlant,
      CustomerReturnItem.StorageLocation,
      cast(CustomerReturnItem.ShippingPoint as borgr_wanst preserving type) as ShippingPoint,
      CustomerReturnItem.DeliveryPriority,
      CustomerReturnItem.ShippingType,

      CustomerReturnItem.SalesDocumentRjcnReason,
      CustomerReturnItem.ItemBillingBlockReason,

      CustomerReturnItem.IncotermsClassification,
      CustomerReturnItem.IncotermsTransferLocation,
      CustomerReturnItem.IncotermsLocation1,
      CustomerReturnItem.IncotermsLocation2,
      CustomerReturnItem.CustomerPaymentTerms,

      CustomerReturnItem.ProfitCenter,
      CustomerReturnItem.WBSElementInternalID,
      CustomerReturnItem._WBSElementBasicData_2.WBSElementExternalID as WBSElementExternalID,

      CustomerReturnItem.RetsMgmtProcess,
      CustomerReturnItem.ReturnReason,
      CustomerReturnItem.RetsMgmtProcessingBlock,
      AdvncdRetsMgmtProcessStep.CustRetItmFollowUpActivity,
      @EndUserText.label: 'Product Received'
      @Semantics.booleanIndicator:true
      AdvncdRetsMgmtProcessStep.ReturnsMaterialHasBeenReceived,
      @ObjectModel.virtualElement: true
      cast ( '' as msr_cust_insp_comment )                          as CustRetItmCustomerText,
      @ObjectModel.virtualElement: true
      cast ( '' as msr_insp_comment )                               as CustRetItmInspectionText,
      AdvncdRetsMgmtProcessStep.ReturnsRefundType,
      cast(AdvncdRetsMgmtProcessStep.ReturnsRefundProcgMode as msr_refund_control preserving type) as ReturnsRefundProcgMode,
      AdvncdRetsMgmtProcessItem.RetsProdValnIsSuspended,
      AdvncdRetsMgmtProcessItem.RetsInspIsCrtedAutomly,
      AdvncdRetsMgmtProcessItem.RetsProdIsVltdWithRef,
      CustomerReturnItem.ReturnsRefundExtent,
      AdvncdRetsMgmtProcessStep.PrelimRefundIsDetermined,
      AdvncdRetsMgmtProcessItem.ReturnsRefundRjcnReason,

      cast(AdvncdRetsMgmtProcessStep.ReplacementMaterial as return_replace_product preserving type) as ReplacementMaterial,

      @Semantics.quantity.unitOfMeasure: 'ReplacementMaterialQtyUnit'
      AdvncdRetsMgmtProcessStep.ReplacementMaterialQuantity,

      AdvncdRetsMgmtProcessStep.ReplacementMaterialQtyUnit,
      AdvncdRetsMgmtProcessStep.ReplacementMaterialIsRequested,
      AdvncdRetsMgmtProcessStep.ReplacementMatlSupplyingPlant,

      AdvncdRetsMgmtProcessStep.NextPlantForFollowUpActivity,
      AdvncdRetsMgmtProcessStep.ReturnsTransshipmentPlant,
      AdvncdRetsMgmtProcessStep.Supplier,
      AdvncdRetsMgmtProcessStep.SupplierRetMatlAuthzn,
      AdvncdRetsMgmtProcessStep.SuplrRetMatlAuthznIsRequired,
      AdvncdRetsMgmtProcessItem.CustomerRetMatlInspResultCode,
      AdvncdRetsMgmtProcessItem.NextFllwUpActivityForMatlInsp,
      AdvncdRetsMgmtProcessStep.RetMatlInspResultCode,
      AdvncdRetsMgmtProcessStep.ProductIsInspectedAtCustSite,
      AdvncdRetsMgmtProcessItem.CustRetMatlAuthzn,

      AdvncdRetsMgmtProcessItem.CRMLogicalSystem,
      @Semantics.uuid:true
      AdvncdRetsMgmtProcessItem.CRMObjectUUID,
      AdvncdRetsMgmtProcessItem.CRMObjectID,
      AdvncdRetsMgmtProcessItem.CRMObjectType,

      AdvncdRetsMgmtProcessItem.RetsMgmtItmLogProcgStatus,
      AdvncdRetsMgmtProcessItem.RetsMgmtItmCompnProcgStatus,
      AdvncdRetsMgmtProcessItem.RetsMgmtItmProcgStatus,
      AdvncdRetsMgmtProcessStep.ReturnsDocumentStatus,
      AdvncdRetsMgmtProcessStep.ReturnsDocumentApprovalStatus,

      CustomerReturnItem.ReferenceSDDocument,
      CustomerReturnItem.ReferenceSDDocumentItem,
      CustomerReturnItem.ReferenceSDDocumentCategory,

      CustomerReturnItem.SDProcessStatus,
      CustomerReturnItem.SDDocumentRejectionStatus,

      CustomerReturnItem.ProductTaxClassification1,
      CustomerReturnItem.ProductTaxClassification2,
      CustomerReturnItem.ProductTaxClassification3,
      CustomerReturnItem.ProductTaxClassification4,
      CustomerReturnItem.ProductTaxClassification5,
      CustomerReturnItem.ProductTaxClassification6,
      CustomerReturnItem.ProductTaxClassification7,
      CustomerReturnItem.ProductTaxClassification8,
      CustomerReturnItem.ProductTaxClassification9,

      CustomerReturnItem.AdditionalMaterialGroup1,
      CustomerReturnItem.AdditionalMaterialGroup2,
      CustomerReturnItem.AdditionalMaterialGroup3,
      CustomerReturnItem.AdditionalMaterialGroup4,
      CustomerReturnItem.AdditionalMaterialGroup5,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.Subtotal1Amount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.Subtotal2Amount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.Subtotal3Amount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.Subtotal4Amount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.Subtotal5Amount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      CustomerReturnItem.Subtotal6Amount,

      _CustomerReturn,
      _Partner,
      _PricingElement
}