I_CustomerReturnImport

@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@EndUserText.label: 'Header Fields for Customer Return Import'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.compositionRoot: true
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED }

@VDM: {
  lifecycle.contract.type: #PUBLIC_LOCAL_API,
  viewType: #COMPOSITE
}

define view entity I_CustomerReturnImport
  as select from I_CustomerReturn as CustomerReturn

  // Associations

  association [0..*] to I_CustomerReturnItemImport    as _Item           on $projection.CustomerReturn = _Item.CustomerReturn
  association [1..*] to I_CustomerReturnPartner       as _Partner        on $projection.CustomerReturn = _Partner.CustomerReturn
  association [0..*] to I_SalesDocumentPricingElement as _PricingElement on $projection.CustomerReturn = _PricingElement.SalesDocument

  // Extensibility

  association [0..1] to E_SalesDocumentBasic          as _Extension      on CustomerReturn.CustomerReturn = _Extension.SalesDocument

{
  key CustomerReturn,

      cast (CustomerReturnType as msr_returns_order_type preserving type) as CustomerReturnType,
      CustomerReturnDate,

      SoldToParty,
      SalesOrganization,
      DistributionChannel,

      OrganizationDivision,
      SalesOffice,
      SalesGroup,
      SalesDistrict,

      CreationDate,
      CreatedByUser,
      LastChangedByUser,
      CreationTime,
      LastChangeDate,

      PurchaseOrderByCustomer,
      CustomerPurchaseOrderType,
      CustomerPurchaseOrderDate,
      SDDocumentReason,
      PricingDate,
      RequestedDeliveryDate,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalNetAmount,

      TransactionCurrency,
      HeaderBillingBlockReason,
      DeliveryBlockReason,
      SDPricingProcedure,

      IncotermsClassification,
      IncotermsTransferLocation,
      IncotermsLocation1,
      IncotermsLocation2,
      IncotermsVersion,

      CustomerPaymentTerms,
      PaymentMethod,
      BillingCompanyCode,

      CustomerTaxClassification1,
      CustomerTaxClassification2,
      CustomerTaxClassification3,
      CustomerTaxClassification4,
      CustomerTaxClassification5,
      CustomerTaxClassification6,
      CustomerTaxClassification7,
      CustomerTaxClassification8,
      CustomerTaxClassification9,

      AccountingDocExternalReference,
      AssignmentReference,
      ShippingType,
      ShippingCondition,
      CustomerReturnApprovalReason,
      SalesDocApprovalStatus,

      ReferenceSDDocument,
      ReferenceSDDocumentCategory,

      _Item,
      _Partner,
      _PricingElement
}