I_CostRevnReassignmentItemTP

@AbapCatalog.sqlViewName: 'ICOSREVREASSITP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Cost, Revenue Reassgmt Item - Transactional'

@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM: {
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type: #SAP_INTERNAL_API
}

@ObjectModel:
{ 
  writeDraftPersistence: 'COSREVREASSITMDR',
  semanticKey: ['FiscalYearForEdit', 'ReferenceDocumentForEdit', 'ControllingAreaForEdit', 'CompanyCodeForEdit', 'LedgerGLLineItemForEdit', 'ReferenceDocumentItemForEdit'],

  createEnabled,
  updateEnabled,
  deleteEnabled
  
  //entityChangeStateId: 'LastChangeTime'

}

@Consumption.dbHints: ['NO_USE_HEX_PLAN']

define view I_CostRevnReassignmentItemTP
  as select from I_CostRevenueReassignmentItem as _Item
  
  association [1..1] to I_CostRevenueReassignmentTP  as _Header    on  $projection.ControllingArea   = _Header.ControllingArea
                                                                    and $projection.FiscalYear        = _Header.FiscalYear
                                                                    and $projection.ReferenceDocument = _Header.ReferenceDocument  
  
  association [1..1] to E_JournalEntryItem           as _Extension  on $projection.SourceLedger       = _Extension.SourceLedger
                                                                    and $projection.CompanyCode        = _Extension.CompanyCode
                                                                    and $projection.FiscalYear         = _Extension.FiscalYear
                                                                    and $projection.AccountingDocument = _Extension.AccountingDocument
                                                                    and $projection.LedgerGLLineItem   = _Extension.LedgerGLLineItem     
                                                                                                                                                       
{
  key FiscalYear,
  key ReferenceDocument,
  key ControllingArea,
  key CompanyCode,  
  key LedgerGLLineItem,
  key ReferenceDocumentItem,
      
      AccountingDocument,
      SourceLedger,  
       
      FiscalYear as FiscalYearForEdit,
      ReferenceDocumentForEdit,
      ControllingArea as ControllingAreaForEdit,
      CompanyCode as CompanyCodeForEdit,  
      LedgerGLLineItem as LedgerGLLineItemForEdit,
      ReferenceDocumentItem as ReferenceDocumentItemForEdit,      
      
      DocumentItemText,
      
      GLAccount, 
            
      AccountAssignment,      
      AccountAssignmentType,
      
      PartnerAccountAssignment,      
      PartnerAccountAssignmentType,
      
      CostCtrActivityType,
      OriginCostCenter,
      
      PartnerCostCenter,
      //Cost Center/Activity Type

      PartnerCostCtrActivityType,            
      
      //WBS Element

      PartnerWBSElementExternalID,
      @ObjectModel.readOnly
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:   'PartnerWBSElementExternalID'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'PartnerWBSElementExternalID'
      PartnerWBSElement,
      
      WBSElementExternalID,  
      @ObjectModel.readOnly  
      @API.element.releaseState: #DEPRECATED
      @API.element.successor:   'WBSElementExternalID'
      @VDM.lifecycle.status:    #DEPRECATED
      @VDM.lifecycle.successor: 'WBSElementExternalID'
      WBSElement,
      @ObjectModel.readOnly
      PartnerWBSElementInternalID,
      @ObjectModel.readOnly
      WBSElementInternalID,
      
      //Service Contract Item and Service Order Item

      PartnerServiceDocumentType,
      PartnerServiceDocument,
      PartnerServiceDocumentItem,
      
      ServiceDocumentType,
      ServiceDocument,
      ServiceDocumentItem,
      
      //Network

      PartnerProjectNetwork,
      PartnerProjectNetworkActivity,
      
      RelatedNetworkActivity,      
      ProjectNetwork,
      
      //Activity or Order

      PartnerOrder,
      
      OrderID,
      
      //Order operation

      PartnerOrderOperation,
      OrderOperation,
      
      cast('' as receivercompanycode) as PartnerCompanyCode, //Dummy field, cannot delete, because of db table inconsistency

      SenderCompanyCode,
      
      //Cost object

      PartnerCostObject, 
      CostObject,
      
      //Sales Order

      PartnerSalesDocument,
      PartnerSalesDocumentItem,
      
      SalesDocument,
      SalesDocumentItem,
      
      PersonnelNumber,
      
      PartnerBusinessProcess, 
      BusinessProcess,
      
      JointVentureCostRecoveryCode,
      SenderCostRecoveryCode,
      
      cast('' as costrevenuereassignmentaction)    as CostRevenueReassignmentAction,
      cast('' as fco_drct_acty_is_posted) as Status,
      
      //Public Sector

      Fund,
      FunctionalArea,
      GrantID,
      BudgetPeriod,
      PartnerFund,
      PartnerFunctionalArea,
      PartnerGrant,
      PartnerBudgetPeriod,
      
      WorkItem,
      PartnerWorkItem,
      
      @ObjectModel.readOnly
      FinancialManagementArea,
      
      RcvrAcctgIndCode,
      BillableControl,
      
      @Semantics.unitOfMeasure:true
      BaseUnit,
      
      @Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
      Quantity,
      
      @Semantics.currencyCode:true
      TransactionCurrency,
      
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      AmountInTransactionCurrency,
      
      @Semantics.currencyCode:true
      CompanyCodeCurrency,
      @Semantics: { amount : {currencyCode: 'CompanyCodeCurrency'} }
      AmountInCompanyCodeCurrency,
      
      @Semantics.currencyCode:true
      GlobalCurrency,
      @Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
      AmountInGlobalCurrency,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency1,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency1'} }
      AmountInFreeDefinedCurrency1,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency2,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency2'} }
      AmountInFreeDefinedCurrency2,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency3,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency3'} }
      AmountInFreeDefinedCurrency3,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency4,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency4'} }
      AmountInFreeDefinedCurrency4,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency5,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency5'} }
      AmountInFreeDefinedCurrency5,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency6,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency6'} }
      AmountInFreeDefinedCurrency6,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency7,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency7'} }
      AmountInFreeDefinedCurrency7,
      
      @Semantics.currencyCode:true
      FreeDefinedCurrency8,
      @Semantics: { amount : {currencyCode: 'FreeDefinedCurrency8'} }
      AmountInFreeDefinedCurrency8,
      
      @Semantics.currencyCode:true
      FunctionalCurrency,
      @Semantics: { amount : {currencyCode: 'FunctionalCurrency'} }
      AmountInFunctionalCurrency,
      
      ChartOfAccounts,
      ControllingBusTransacType,
      PostingDate,
      
      PartnerProfitabilitySegment,
      ProfitabilitySegment,
      @ObjectModel.readOnly
      @Semantics.booleanIndicator
      PartProfitabilitySgmtIsAssgd,
      @ObjectModel.readOnly
      @Semantics.booleanIndicator
      ProfitabilitySegmentIsAssigned,
      @ObjectModel.readOnly
      OperatingConcern,
      
      ReceiverRECompanyCode,
      REPartnerBusinessEntity,
      RealEstatePartnerBuilding,
      RealEstatePartnerProperty,
      REPartnerRentalObject,
      RealEstatePartnerContract,
      REPartnerServiceChargeKey,
      REPartnerSettlementUnitID,
      PartnerSettlementReferenceDate,
      
      SenderRECompanyCode,
      REBusinessEntity,
      RealEstateBuilding,
      RealEstateProperty,
      RERentalObject,
      RealEstateContract,
      REServiceChargeKey,
      RESettlementUnitID,
      SettlementReferenceDate,
      
      ProfitCenter,
      PartnerProfitCenter,
      
      PartnerControllingObject,
      ControllingObject,
      TransactionSubitem,      
      
      @ObjectModel.readOnly: true
      _Item.AccountingDocumentType,
                  
      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _Header,
      
      _BaseUnit,
      _Fund,
      _PartnerFund,
      _Grant,
      _PartnerGrant,
      _BudgetPeriod,
      _PartnerBudgetPeriod,
      _FunctionalArea,
      _PartnerFunctionalArea      

}