@AbapCatalog.sqlViewName: 'ICOSREVREASSTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Cost, Revenue Reassignment - Transactional View'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.sapObjectNodeType.name: 'JournalEntry'
@VDM: {
viewType: #TRANSACTIONAL,
lifecycle.contract.type: #SAP_INTERNAL_API
}
@ObjectModel:
{
modelCategory: #BUSINESS_OBJECT,
compositionRoot: true,
transactionalProcessingEnabled:true,
draftEnabled: true,
writeDraftPersistence: 'COSREVREASS_DRFT',
semanticKey: ['FiscalYearForEdit', 'ReferenceDocumentForEdit', 'ControllingAreaForEdit'],
createEnabled,
updateEnabled,
deleteEnabled
//entityChangeStateId: 'LastChangeTime'
}
@Consumption.dbHints: ['NO_USE_HEX_PLAN']
define view I_CostRevenueReassignmentTP
as select from R_CostRevenueReassignment
association [1..*] to I_CostRevnReassignmentItemTP as _Item on $projection.FiscalYear = _Item.FiscalYear
and $projection.ReferenceDocument = _Item.ReferenceDocument
and $projection.ControllingArea = _Item.ControllingArea
association [1..1] to I_CostRevenueReassignment as _CostRevenueReassignment on $projection.ControllingAreaForEdit = _CostRevenueReassignment.ControllingArea
and $projection.FiscalYearForEdit = _CostRevenueReassignment.FiscalYear
and $projection.ReferenceDocumentForEdit = _CostRevenueReassignment.ReferenceDocument
{
key FiscalYear,
key cast(ReferenceDocument as referencedocument) as ReferenceDocument,
key ControllingArea,
@ObjectModel.readOnly
FiscalYear as FiscalYearForEdit,
@ObjectModel.readOnly
ReferenceDocument as ReferenceDocumentForEdit,
@ObjectModel.mandatory: true
ControllingArea as ControllingAreaForEdit,
@ObjectModel.readOnly: true
cast(CompanyCode as receivercompanycode) as CompanyCode,
@ObjectModel.readOnly: true
cast(_CompanyCodeText.CompanyCodeName as fis_butxt) as CompanyCodeName,
@ObjectModel.readOnly: true
cast(SenderCompanyCode as sendercompanycode) as SenderCompanyCode,
@ObjectModel.readOnly: true
cast(_SenderCompanyCodeText.CompanyCodeName as fis_butxt) as SourceCompanyCodeName,
@ObjectModel.readOnly: true
cast(AccountingDocument as fis_belnr) as AccountingDocument,
AccountingDocumentHeaderText,
DocumentDate,
PostingDate,
FiscalPeriod,
cast(FiscalPeriod as fins_fiscalperiod) as CurrentFiscalPeriod,
@ObjectModel.readOnly
AccountingDocumentCreationDate,
@ObjectModel.readOnly
AccountingDocCreatedByUser,
@ObjectModel.readOnly
IsReversal,
@ObjectModel.readOnly
IsReversed,
// both cases to be adjusted for reposting
@ObjectModel.readOnly
cast(ControllingDocumentStatus as fco_document_status) as Status,
@ObjectModel.readOnly
cast(CtrlgOverheadStatusCriticality as abap.int1) as StatusCriticality,
@ObjectModel.readOnly
AllocationPostingType,
@ObjectModel.readOnly
ReferenceDocumentType,
@ObjectModel.readOnly
ReferenceDocumentContext,
@ObjectModel.readOnly
ReversalReferenceDocument,
@ObjectModel.readOnly
ReversedReferenceDocument,
CostRevenueReassignmentAction,
PostingFiscalYear,
ExchangeRateDate,
@Semantics.currencyCode:true
GlobalCurrency,
@Semantics: { amount : {currencyCode: 'GlobalCurrency'} }
TotalAmountInGlobalCurrency,
@ObjectModel.readOnly
ControllingBusTransacType,
@ObjectModel.readOnly
CostRevenueReassignmentType,
cast('' as fis_blart) as AccountingDocumentType,
//Sender and Receiver dummy fields
@ObjectModel.readOnly
cast('' as fco_allocation_account) as GLAccount,
@ObjectModel.readOnly
cast('' as lstar) as CostCtrActivityType,
@ObjectModel.readOnly
cast('' as sendercostcenter) as OriginCostCenter,
@ObjectModel.readOnly
cast('' as fis_skost) as PartnerCostCenter,
@ObjectModel.readOnly
cast('' as fis_par_lstar) as PartnerCostCtrActivityType,
@ObjectModel.readOnly
cast('' as fis_partner_wbsext_no_conv) as PartnerWBSElementExternalID,
@API.element.releaseState: #DEPRECATED
@API.element.successor: 'PartnerWBSElementExternalID'
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'PartnerWBSElementExternalID'
@ObjectModel.readOnly
cast('' as fis_par_psp_pnr_ext) as PartnerWBSElement,
@ObjectModel.readOnly
cast('' as fis_wbsext_no_conv) as WBSElementExternalID,
@API.element.releaseState: #DEPRECATED
@API.element.successor: 'WBSElementExternalID'
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'WBSElementExternalID'
@ObjectModel.readOnly
cast('' as ps_posid_edit) as WBSElement,
@ObjectModel.readOnly
cast('' as fco_psrvdoc_type) as PartnerServiceDocumentType,
@ObjectModel.readOnly
cast('' as fco_psrvdoc_id) as PartnerServiceDocument,
@ObjectModel.readOnly
cast('' as fco_psrvdoc_item_id) as PartnerServiceDocumentItem,
@ObjectModel.readOnly
cast('' as fco_srvdoc_type) as ServiceDocumentType,
@ObjectModel.readOnly
cast('' as fco_srvdoc_id) as ServiceDocument,
@ObjectModel.readOnly
cast('' as fco_srvdoc_item_id) as ServiceDocumentItem,
@ObjectModel.readOnly
cast('' as par_npln) as PartnerProjectNetwork,
@ObjectModel.readOnly
cast('' as par_vornr_auf) as PartnerProjectNetworkActivity,
@ObjectModel.readOnly
cast('' as nplnr) as ProjectNetwork,
@ObjectModel.readOnly
cast('' as npvrg) as RelatedNetworkActivity,
@ObjectModel.readOnly
cast('' as fis_par_aufnr) as PartnerOrder,
@ObjectModel.readOnly
cast('' as fis_aufnr) as OrderID,
@ObjectModel.readOnly
cast('' as vdm_vornr) as OrderOperation,
@ObjectModel.readOnly
cast('' as vdm_vornr) as PartnerOrderOperation,
@ObjectModel.readOnly
cast('' as par_kstrg) as PartnerCostObject,
@ObjectModel.readOnly
cast('' as kstrg) as CostObject,
@ObjectModel.readOnly
cast('' as fis_par_kdauf) as PartnerSalesDocument,
@ObjectModel.readOnly
cast('' as fis_par_kdpos) as PartnerSalesDocumentItem,
@ObjectModel.readOnly
cast('' as vbeln_va) as SalesDocument,
@ObjectModel.readOnly
cast('' as posnr_va) as SalesDocumentItem,
@ObjectModel.readOnly
cast('' as pernr_d) as PersonnelNumber,
@ObjectModel.readOnly
cast('' as par_prznr) as PartnerBusinessProcess,
@ObjectModel.readOnly
cast('' as sprznr) as BusinessProcess,
@ObjectModel.readOnly
cast('' as jv_recind_cds) as JointVentureCostRecoveryCode,
@ObjectModel.readOnly
cast('' as jv_srecind_cds) as SenderCostRecoveryCode,
@ObjectModel.readOnly
cast('' as fm_sfonds) as Fund,
@ObjectModel.readOnly
cast('' as fm_sfarea) as FunctionalArea,
@ObjectModel.readOnly
cast('' as gm_grant_sender) as GrantID,
@ObjectModel.readOnly
cast('' as fm_budget_period) as BudgetPeriod,
@ObjectModel.readOnly
cast('' as fm_efonds) as PartnerFund,
@ObjectModel.readOnly
cast('' as fm_efarea) as PartnerFunctionalArea,
@ObjectModel.readOnly
cast('' as gm_grant_receiver) as PartnerGrant,
@ObjectModel.readOnly
cast('' as fm_pbudget_period) as PartnerBudgetPeriod,
@ObjectModel.readOnly
cast('' as ebemot) as RcvrAcctgIndCode,
@ObjectModel.readOnly
cast('' as bemot) as BillableControl,
@ObjectModel.readOnly
@Semantics.booleanIndicator
cast('' as profitabilitysegmentisassigned) as PartProfitabilitySgmtIsAssgd,
@ObjectModel.readOnly
@Semantics.booleanIndicator
cast('' as profitabilitysegmentisassigned) as ProfitabilitySegmentIsAssigned,
@ObjectModel.readOnly
cast('' as pbukrs) as ReceiverRECompanyCode,
@ObjectModel.readOnly
cast('' as rebdvdmpbeno) as REPartnerBusinessEntity,
@ObjectModel.readOnly
cast('' as rebdvdmpbuno) as RealEstatePartnerBuilding,
@ObjectModel.readOnly
cast('' as rebdvdmpprno) as RealEstatePartnerProperty,
@ObjectModel.readOnly
cast('' as rebdvdmprono) as REPartnerRentalObject,
@ObjectModel.readOnly
cast('' as recnvdmpcnnr) as RealEstatePartnerContract,
@ObjectModel.readOnly
cast('' as rescvdmpsckey) as REPartnerServiceChargeKey,
@ObjectModel.readOnly
cast('' as rescvdmpsuid) as REPartnerSettlementUnitID,
@ObjectModel.readOnly
cast('00000000' as fins_par_dabrbez) as PartnerSettlementReferenceDate,
@ObjectModel.readOnly
cast('' as vvsbukrs) as SenderRECompanyCode,
@ObjectModel.readOnly
cast('' as rebdvdmbeno) as REBusinessEntity,
@ObjectModel.readOnly
cast('' as rebdvdmbuno) as RealEstateBuilding,
@ObjectModel.readOnly
cast('' as rebdvdmprno) as RealEstateProperty,
@ObjectModel.readOnly
cast('' as rebdvdmrono) as RERentalObject,
@ObjectModel.readOnly
cast('' as recnvdmcnnr) as RealEstateContract,
@ObjectModel.readOnly
cast('' as rescvdmsckey) as REServiceChargeKey,
@ObjectModel.readOnly
cast('' as rescvdmsuid) as RESettlementUnitID,
@ObjectModel.readOnly
cast('00000000' as farp_dabrbez) as SettlementReferenceDate,
@ObjectModel.readOnly
cast('' as j_obart) as AccountAssignmentType,
@ObjectModel.readOnly
cast('' as receiver_object_type) as PartnerAccountAssignmentType,
@ObjectModel.association.type: #TO_COMPOSITION_CHILD
_Item,
_ReferenceDocumentType,
_CostRevenueReassignment
}