I_ControllingOrder

@AbapCatalog.sqlViewName: 'ICTRLGORDER'
@ClientHandling.type: #CLIENT_DEPENDENT
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'OrderID'
@ObjectModel.semanticKey: 'OrderID'
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }
@Metadata.allowExtensions:true
@AbapCatalog.preserveKey:true
@EndUserText.label: 'Controlling Order'
@VDM.viewType: #BASIC
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@AbapCatalog.buffering: {type: #NONE, numberOfKeyFields: 0, status: #NOT_ALLOWED}
@Metadata.ignorePropagatedAnnotations: true
@Analytics.internalName:#LOCAL

define view I_ControllingOrder
  as select from           aufk as aufk
    left outer to one join afko as afko on afko.aufnr = aufk.aufnr
  association [0..1] to I_ProductCostCtrlgOrderItem   as _RepresentativeOrderItem     on  $projection.OrderID                = _RepresentativeOrderItem.OrderID
                                                                                      and _RepresentativeOrderItem.OrderItem = '0001'
  association [1..1] to I_ControllingArea             as _ControllingArea             on  $projection.ControllingArea = _ControllingArea.ControllingArea
  association [1..1] to I_CompanyCode                 as _CompanyCode                 on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [1..1] to E_ProductCostCtrlgOrder       as _Extension                   on  $projection.OrderID = _Extension.OrderID
  association [1..1] to I_OrderType                   as _OrderType                   on  $projection.OrderType = _OrderType.OrderType
  association [1..1] to I_OrderCategory               as _OrderCategory               on  $projection.OrderCategory = _OrderCategory.OrderCategory
  association [1..1] to I_FiscCalendarDateForCompCode as _FiscCalendarDateForCompCode on  $projection.CreationDate = _FiscCalendarDateForCompCode.CalendarDate
                                                                                      and $projection.CompanyCode  = _FiscCalendarDateForCompCode.CompanyCode
  association [0..1] to I_MaintenanceOrder            as _MaintenanceOrder            on  $projection.OrderID = _MaintenanceOrder.MaintenanceOrder
{
      @ObjectModel.text.element: 'OrderDescription'
  key cast(aufk.aufnr as fis_order_number)           as OrderID,
      @Semantics.text
      cast(aufk.ktext as fis_order_text)             as OrderDescription,

      aufk.auart                                     as OrderType,
      cast(aufk.autyp as fis_auftyp)                 as OrderCategory,
      aufk.refnr                                     as ReferenceOrder,
      cast(aufk.aufex as fis_external_order_number)  as ExternalOrder,
      aufk.objnr                                     as ObjectInternalID,
      aufk.waers                                     as Currency,
      aufk.werks                                     as Plant,
      afko.gmein                                     as BaseUnit,

      //Assignment

      aufk.kokrs                                     as ControllingArea,
      aufk.bukrs                                     as CompanyCode,
      _CompanyCode.Currency                          as CompanyCodeCurrency,
      aufk.gsber                                     as BusinessArea,
      aufk.prctr                                     as ProfitCenter,
      cast(aufk.kostv as fis_resp_cctr)              as ResponsibleCostCenter,
      cast(pspel as fis_wbsint_no_conv)              as WBSElementInternalID,

      aufk.loekz                                     as IsMarkedForDeletion,
      @Semantics.booleanIndicator:true
      cast(aufk.flg_mltps  as fis_co_mltps)          as MfgOrderHasMultipleItems,

      cast(afko.klvari as fis_kalkvarist)            as ActualCostsCostingVariant,
      cast(afko.klvarp as kalkvarpln )               as PlannedCostsCostingVariant,
      @Semantics.booleanIndicator:true
      @VDM.lifecycle.status:     #DEPRECATED
      @VDM.lifecycle.successor:  'EventBasedPostingMethod'
      aufk.eb_post                                   as OrderIsEventBasedPosting,
      aufk.eb_post                                   as EventBasedPostingMethod,
      aufk.eb_post_type                              as OrderSettlementTriggerType,
      

      cast(afko.aufpl  as pph_aufpl preserving type) as MfgOrderInternalID,

      //Process

      cast(case aufk.pdat1
        when '' then afko.ftrmp
        else aufk.pdat1
      end as fis_co_ftrmp)                           as PlannedReleaseDate,
      cast(aufk.pdat2 as fis_aufpdat2)               as PlannedCompletionDate,
      cast(aufk.ernam as fclm_bam_created_by)        as CreatedByUser,
      cast(aufk.erdat as fis_auferfdat)              as CreationDate,
      cast(aufk.aenam as fis_aufaenam)               as LastChangedByUser,
      cast(aufk.aedat as fis_aufaedat)               as LastChangeDate,
      cast(aufk.idat2 as fis_aufidat2)               as TechnicalCompletionDate,

      //Order Header PPS Orders

      cast(afko.gltrs as fis_co_gltrs)               as ScheduledBasicEndDate,
      cast(afko.ftrms as fis_co_ftrms)               as ScheduledReleaseDate,
      cast(afko.gstri as fis_co_gstri)               as ActualStartDate,
      cast(afko.getri as fis_getri)                  as ConfirmedEndDate,
      cast(afko.ftrmi as fis_co_ftrmi)               as ActualReleasedDate,


      aufk.astkz                                     as IsStatisticalOrder,
      aufk.akstl                                     as RequestingCostCenter,
      aufk.kostl                                     as CostCenter,
      aufk.cycle                                     as ActualPostedCostCenter,

      aufk.abgsl                                     as ResultAnalysisInternalID,
      aufk.ebw_key                                   as EventBasedProcessingKey,
      aufk.kdauf                                     as SalesOrder,
      aufk.kdpos                                     as SalesOrderItem,

      aufk.kalsm                                     as CostingSheet,

      _RepresentativeOrderItem,
      _ControllingArea,
      _CompanyCode,
      _OrderType,
      _OrderCategory,
      _FiscCalendarDateForCompCode,
      _MaintenanceOrder
}
where
     aufk.autyp = '04' //CO Production Order

  or aufk.autyp = '05' //Product Cost Collector

  or aufk.autyp = '10' //PP Production Order

  or aufk.autyp = '40' //Process Order

  or aufk.autyp = '01' //Internal Order (Controlling)

  or aufk.autyp = '30' //Maintenance order