I_ClosingTaskExecution

@AbapCatalog: {sqlViewName: 'ICLSGTASKEXEC', preserveKey: true}
@EndUserText.label: 'Closing Task Execution'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: { representativeKey: 'ClosingTaskExecutionUUID',
                usageType.serviceQuality: #A,
                usageType.sizeCategory: #L,
                usageType.dataClass: #MASTER }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true

define view I_ClosingTaskExecution
  as select from fcco_task_exec

  association [1..1] to I_ClosingTaskList           as _ClosingTaskList           on  $projection.ClosingTemplate              = _ClosingTaskList.ClosingTemplate
                                                                                  and $projection.ClosingTaskListInstance      = _ClosingTaskList.ClosingTaskListInstance
                                                                                  and $projection.FinancialTaskListContextType = _ClosingTaskList.FinancialTaskListContextType

  association [1..1] to I_ClosingTask               as _ClosingTask               on  $projection.ClosingTemplate              = _ClosingTask.ClosingTemplate
                                                                                  and $projection.ClosingTaskListInstance      = _ClosingTask.ClosingTaskListInstance
                                                                                  and $projection.FinancialTaskListContextType = _ClosingTask.FinancialTaskListContextType
                                                                                  and $projection.ClosingTask                  = _ClosingTask.ClosingTask

  association [1..1] to I_ClosingTemplate           as _ClosingTemplate           on  $projection.ClosingTemplate              = _ClosingTemplate.ClosingTemplate
                                                                                  and $projection.FinancialTaskListContextType = _ClosingTemplate.FinancialTaskListContextType

  association [1..1] to I_FinTaskListContextType    as _FinTaskListContextType    on  $projection.FinancialTaskListContextType = _FinTaskListContextType.FinancialTaskListContextType

  association [1..1] to I_ClosingTaskExecutionGroup as _ClosingTaskExecutionGroup on  $projection.ClosingTemplate               = _ClosingTaskExecutionGroup.ClosingTemplate
                                                                                  and $projection.ClosingTaskListInstance       = _ClosingTaskExecutionGroup.ClosingTaskListInstance
                                                                                  and $projection.FinancialTaskListContextType  = _ClosingTaskExecutionGroup.FinancialTaskListContextType
                                                                                  and $projection.ClosingTask                   = _ClosingTaskExecutionGroup.ClosingTask
                                                                                  and $projection.ClosingTaskExecutionGroupUUID = _ClosingTaskExecutionGroup.ClosingTaskExecutionGroupUUID

{
         @ObjectModel.foreignKey.association: '_ClosingTemplate'
  key    profile                                                                                                                                                                             as       ClosingTemplate,
         @ObjectModel.foreignKey.association: '_ClosingTaskList'
  key    instance                                                                                                                                                                            as       ClosingTaskListInstance,
         @ObjectModel.foreignKey.association: '_FinTaskListContextType'
  key    flavor                                                                                                                                                                              as       FinancialTaskListContextType,
         @ObjectModel.foreignKey.association: '_ClosingTask'
  key    item                                                                                                                                                                                as       ClosingTask,
         @ObjectModel.foreignKey.association: '_ClosingTaskExecutionGroup'
  key    exec_grp_uuid                                                                                                                                                                       as       ClosingTaskExecutionGroupUUID,
  key    execuuid                                                                                                                                                                            as       ClosingTaskExecutionUUID,

         created_by                                                                                                                                                                          as       CreatedByUser,
         created_on                                                                                                                                                                          as       CreationDateTime,
         last_changed_by                                                                                                                                                                     as       LastChangedByUser,
         last_changed_on                                                                                                                                                                     as       LastChangeDateTime,
         life_cycle_status                                                                                                                                                                   as       ClosingTaskLifecycleStatus,
         combined_status                                                                                                                                                                     as       ClosingTaskStatus,
         btc_job_name                                                                                                                                                                        as       ApplicationJobName,
         btc_job_id                                                                                                                                                                          as       ApplicationJob,
         duration                                                                                                                                                                            as       ApplJobDurationInSeconds,
         btc_start_on                                                                                                                                                                        as       ApplicationJobStartDateTime,
         btc_end_on                                                                                                                                                                          as       ApplicationJobEndDateTime,
         text                                                                                                                                                                                as       ClsgTaskStatusChgReasonDesc,
         manual_changed                                                                                                                                                                      as       ClsgTaskStatusIsChgdManually,
         is_testrun                                                                                                                                                                          as       IsApplicationJobTestRun,
         btc_planned_start_on                                                                                                                                                                as       ApplJobPlannedStartDateTime,
         approval_text                                                                                                                                                                       as       ReviewComment,
         bukrs                                                                                                                                                                               as       CompanyCode,
         kokrs                                                                                                                                                                               as       ControllingArea,
         werks                                                                                                                                                                               as       Plant,
         communication_profile                                                                                                                                                               as       ClosingCommunicationProfile,

         @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
         _ClosingTaskList,
         _ClosingTemplate,
         _FinTaskListContextType,
         _ClosingTask,
         @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
         _ClosingTaskExecutionGroup
}