I_ClosingTaskList

@AbapCatalog: {sqlViewName: 'ICLSGTASKLIST', preserveKey: true}
@Analytics.dataCategory: #DIMENSION
@EndUserText.label: 'Closing Task List'
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: { compositionRoot: true,
                representativeKey: ['ClosingTaskListInstance'],
                usageType.serviceQuality: #B,
                usageType.sizeCategory: #M,
                usageType.dataClass: #MASTER }
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true

define view I_ClosingTaskList
  as select from fcco_hdr

  association [1..1] to I_ClosingTemplate              as _ClosingTemplate              on  $projection.ClosingTemplate              = _ClosingTemplate.ClosingTemplate
                                                                                        and $projection.FinancialTaskListContextType = _ClosingTemplate.FinancialTaskListContextType

  association [0..*] to I_ClosingTaskListText          as _ClosingTaskListText          on  $projection.ClosingTemplate              = _ClosingTaskListText.ClosingTemplate
                                                                                        and $projection.ClosingTaskListInstance      = _ClosingTaskListText.ClosingTaskListInstance
                                                                                        and $projection.FinancialTaskListContextType = _ClosingTaskListText.FinancialTaskListContextType

  association [1..1] to I_FinTaskListContextType       as _FinTaskListContextType       on  $projection.FinancialTaskListContextType = _FinTaskListContextType.FinancialTaskListContextType
  association [0..*] to I_FinTaskListContextTypeText   as _FinTaskListContextTypeText   on  $projection.FinancialTaskListContextType = _FinTaskListContextTypeText.FinancialTaskListContextType

  //Association to children

  association [0..*] to I_ClosingTask                  as _ClosingTask                  on  $projection.ClosingTemplate              = _ClosingTask.ClosingTemplate
                                                                                        and $projection.ClosingTaskListInstance      = _ClosingTask.ClosingTaskListInstance
                                                                                        and $projection.FinancialTaskListContextType = _ClosingTask.FinancialTaskListContextType

  association [0..*] to I_ClosingFolder                as _ClosingFolder                on  $projection.ClosingTemplate              = _ClosingFolder.ClosingTemplate
                                                                                        and $projection.ClosingTaskListInstance      = _ClosingFolder.ClosingTaskListInstance
                                                                                        and $projection.FinancialTaskListContextType = _ClosingFolder.FinancialTaskListContextType

  association [0..*] to I_ClosingHierarchyNode         as _ClosingHierarchyNode         on  $projection.ClosingTemplate              = _ClosingHierarchyNode.ClosingTemplate
                                                                                        and $projection.ClosingTaskListInstance      = _ClosingHierarchyNode.ClosingTaskListInstance
                                                                                        and $projection.FinancialTaskListContextType = _ClosingHierarchyNode.FinancialTaskListContextType

  //Associations to core views

  association [0..1] to I_ClosingTaskListHierarchyType as _ClosingTaskListHierarchyType on  $projection.ClosingTaskListHierarchyType = _ClosingTaskListHierarchyType.ClosingTaskListHierarchyType
  association [0..*] to I_ClosingTaskListHierTypeText  as _ClosingTaskListHierTypeText  on  $projection.ClosingTaskListHierarchyType = _ClosingTaskListHierTypeText.ClosingTaskListHierarchyType

  association [0..1] to I_ClosingTaskListStatus        as _ClosingTaskListStatus        on  $projection.ClosingTaskListStatus = _ClosingTaskListStatus.ClosingTaskListStatus
  association [0..*] to I_ClosingTaskListStatusText    as _ClosingTaskListStatusText    on  $projection.ClosingTaskListStatus = _ClosingTaskListStatusText.ClosingTaskListStatus

  association [0..1] to I_ClosingType                  as _ClosingType                  on  $projection.ClosingType = _ClosingType.ClosingType
  association [0..*] to I_ClosingTypeText              as _ClosingTypeText              on  $projection.ClosingType = _ClosingTypeText.ClosingType

  association [0..1] to I_ClsgTaskListFiscalYearVar    as _FiscalYearVariant            on  $projection.ClosingCommunicationProfile = _FiscalYearVariant.ClosingCommunicationProfile
                                                                                        and $projection.FiscalYearVariant           = _FiscalYearVariant.FiscalYearVariant
  association [0..*] to I_ClsgTskListFiscalYearVarText as _FiscalYearVariantText        on  $projection.ClosingCommunicationProfile = _FiscalYearVariantText.ClosingCommunicationProfile
                                                                                        and $projection.FiscalYearVariant           = _FiscalYearVariantText.FiscalYearVariant

  association [0..1] to I_TimeZone                     as _TimeZone                     on  $projection.ClosingTemplateTimeZone = _TimeZone.TimeZoneID
  association [0..*] to I_TimeZoneText                 as _TimeZoneText                 on  $projection.ClosingTemplateTimeZone = _TimeZoneText.TimeZoneID

  association [0..1] to I_ClosingTaskResponsibleType   as _ClosingTaskListRespType      on  $projection.ClosingTaskListResponsibleType = _ClosingTaskListRespType.ClosingTaskResponsibleType
  association [0..*] to I_ClosingTaskRespTypeText      as _ClosingTaskListRespTypeText  on  $projection.ClosingTaskListResponsibleType = _ClosingTaskListRespTypeText.ClosingTaskResponsibleType

  association [0..1] to I_ClosingTemplateType          as _ClosingTemplateType          on  $projection.ClosingTemplateType = _ClosingTemplateType.ClosingTemplateType
  association [0..*] to I_ClosingTemplateTypeText      as _ClosingTemplateTypeText      on  $projection.ClosingTemplateType = _ClosingTemplateTypeText.ClosingTemplateType

  association [0..1] to I_ClsgTaskListFactoryCal       as _FactoryCalendar              on  $projection.ClosingCommunicationProfile = _FactoryCalendar.ClosingCommunicationProfile
                                                                                        and $projection.FactoryCalendar             = _FactoryCalendar.FactoryCalendar
  association [0..*] to I_ClsgTskListFactoryCalText    as _FactoryCalendarText          on  $projection.ClosingCommunicationProfile = _FactoryCalendarText.ClosingCommunicationProfile
                                                                                        and $projection.FactoryCalendar             = _FactoryCalendarText.FactoryCalendar

  association [0..1] to I_ClosingTaskListLedger        as _Ledger                       on  $projection.ClosingCommunicationProfile = _Ledger.ClosingCommunicationProfile
                                                                                        and $projection.Ledger                      = _Ledger.Ledger
  association [0..*] to I_ClosingTaskListLedgerText    as _LedgerText                   on  $projection.ClosingCommunicationProfile = _LedgerText.ClosingCommunicationProfile
                                                                                        and $projection.Ledger                      = _LedgerText.Ledger

  association [0..1] to I_ClsgTaskListAcctgPrinciple   as _AccountingPrinciple          on  $projection.ClosingCommunicationProfile = _AccountingPrinciple.ClosingCommunicationProfile
                                                                                        and $projection.AccountingPrinciple         = _AccountingPrinciple.AccountingPrinciple
  association [0..*] to I_ClsgTskListAcctgPrncplText   as _AccountingPrincipleText      on  $projection.ClosingCommunicationProfile = _AccountingPrincipleText.ClosingCommunicationProfile
                                                                                        and $projection.AccountingPrinciple         = _AccountingPrincipleText.AccountingPrinciple

  association [0..1] to I_ClosingNotificationConfign   as _ClosingNotificationConfign   on  $projection.ClosingNotificationConfign = _ClosingNotificationConfign.ClosingNotificationConfign
  association [0..*] to I_ClsgNotificationConfignText  as _ClsgNotificationConfignText  on  $projection.ClosingNotificationConfign = _ClsgNotificationConfignText.ClosingNotificationConfign

  association [0..1] to I_ClosingAuthorizationGroup    as _ClosingAuthorizationGroup    on  $projection.ClosingAuthorizationGroup                    = _ClosingAuthorizationGroup.ClosingAuthorizationGroup
                                                                                        and _ClosingAuthorizationGroup.ClosingAuthorizationGroupType = 'ROOT'
  association [0..*] to I_ClsgAuthorizationGroupText   as _ClsgAuthorizationGroupText   on  $projection.ClosingAuthorizationGroup                     = _ClsgAuthorizationGroupText.ClosingAuthorizationGroup
                                                                                        and _ClsgAuthorizationGroupText.ClosingAuthorizationGroupType = 'ROOT'

  association [0..1] to I_ClosingCommProfile           as _ClosingCommunicationProfile  on  $projection.ClosingCommunicationProfile = _ClosingCommunicationProfile.ClosingCommunicationProfile

  association [0..1] to I_ClosingTaskTemplateSet       as _ClosingTaskTemplateSet       on  $projection.ClosingCommunicationProfile = _ClosingTaskTemplateSet.ClosingCommunicationProfile
                                                                                        and $projection.ClosingTaskTemplateSet      = _ClosingTaskTemplateSet.ClosingTaskTemplateSet
  association [0..*] to I_ClosingTaskTemplateSetText   as _ClosingTaskTemplateSetText   on  $projection.ClosingCommunicationProfile = _ClosingTaskTemplateSetText.ClosingCommunicationProfile
                                                                                        and $projection.ClosingTaskTemplateSet      = _ClosingTaskTemplateSetText.ClosingTaskTemplateSet

  association [0..1] to P_MyUserGroup                  as _MyUserGroupAsResp            on  $projection.ClosingTaskListResponsible = _MyUserGroupAsResp.ClosingUserGroup

  association [0..1] to P_MyUserGroupAsSubstitute      as _MyUserGroupAsRespSubst       on  $projection.ClosingTaskListResponsible = _MyUserGroupAsRespSubst.ClosingUserGroup

  association [0..1] to I_User                         as _CreatedByUser                on  $projection.CreatedByUser = _CreatedByUser.UserID

  association [0..1] to I_User                         as _LastChangedByUser            on  $projection.LastChangedByUser = _LastChangedByUser.UserID

{
      @ObjectModel: {foreignKey.association: '_ClosingTemplate', text.element: 'ClosingTaskListDefaultDesc' }
  key profile                                   as ClosingTemplate,
  key instance                                  as ClosingTaskListInstance,
      @ObjectModel.foreignKey.association: '_FinTaskListContextType'
  key flavor                                    as FinancialTaskListContextType,

      long_tasklist_id                          as ClosingTaskListExternalID,
      @ObjectModel.foreignKey.association: '_ClosingTaskListHierarchyType'
      method                                    as ClosingTaskListHierarchyType,
      cast(text as fcco_task_list_descr)        as ClosingTaskListDescription,
      @Semantics.text: true
      cast (text  as fcco_profile_default_text) as ClosingTaskListDefaultDesc,
      @ObjectModel.foreignKey.association: '_ClosingTaskListStatus'
      ready                                     as ClosingTaskListStatus,
      @ObjectModel.foreignKey.association: '_ClosingType'
      closing_type                              as ClosingType,
      @ObjectModel.foreignKey.association: '_FiscalYearVariant'
      periv                                     as FiscalYearVariant,
      @ObjectModel.foreignKey.association: '_FactoryCalendar'
      factory_calendar                          as FactoryCalendar,
      @ObjectModel.foreignKey.association: '_ClosingAuthorizationGroup'
      authgrp                                   as ClosingAuthorizationGroup,
      @ObjectModel.foreignKey.association: '_TimeZone'
      templ_tzone                               as ClosingTemplateTimeZone,
      res_usr_id                                as ClosingTaskListResponsible,
      @ObjectModel.foreignKey.association: '_ClosingTaskListRespType'
      cast(res_usr_type as fcco_task_res_otype) as ClosingTaskListResponsibleType, //reduced code list

      @ObjectModel.foreignKey.association: '_ClosingTemplateType'
      template_type                             as ClosingTemplateType,
      @ObjectModel.foreignKey.association: '_ClosingNotificationConfign'
      noti_con                                  as ClosingNotificationConfign,
      created_by                                as CreatedByUser,
      cast(created_on as fcco_created_on_short) as CreationDateTime,
      changed_by                                as LastChangedByUser,
      cast(changed_on as fcco_changed_on_short) as LastChangeDateTime,
      @ObjectModel.foreignKey.association: '_Ledger'
      rldnr                                     as Ledger,
      @ObjectModel.foreignKey.association: '_AccountingPrinciple'
      acc_principle                             as AccountingPrinciple,

      ddate                                     as KeyDate,
      gjahr                                     as FiscalYear,
      poper                                     as FiscalPeriod,

      @ObjectModel.foreignKey.association: '_ClosingCommunicationProfile'
      lead_communication_profile                as ClosingCommunicationProfile,

      @ObjectModel.foreignKey.association: '_ClosingTaskTemplateSet'
      taskset                                   as ClosingTaskTemplateSet,

      cast(case
        when (res_usr_type = 'US' and res_usr_id = $session.user) or
             (res_usr_type = 'UG' and _MyUserGroupAsResp.ClosingUserGroup is not null)
          then 'X'
        else ''
      end as fcco_is_resp)                      as UserIsClosingTaskListResp,

      cast(case
        when (res_usr_type = 'US' and
             res_usr_id = $session.user ) or
             (res_usr_type = 'UG' and (_MyUserGroupAsResp.ClosingUserGroup is not null or
              _MyUserGroupAsRespSubst.ClosingUserGroup is not null)) or
             (res_usr_type = 'US' and _MyUserGroupAsRespSubst.ClosingUserGroup is not null)
          then 'X'
        else ''
      end as fcco_is_resp_or_subst)             as UserIsClsgTskListRespOrSubstit,

      _ClosingTemplate,
      _ClosingTaskListText,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _ClosingTask,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _ClosingFolder,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _ClosingHierarchyNode,

      /* Associations */
      _FinTaskListContextType,
      _ClosingTaskListHierarchyType,
      _ClosingTaskListStatus,
      _ClosingType,
      _FiscalYearVariant,
      _FactoryCalendar,
      _TimeZone,
      _ClosingTaskListRespType,
      _ClosingTemplateType,
      _Ledger,
      _AccountingPrinciple,
      _ClosingNotificationConfign,
      _ClosingAuthorizationGroup,
      _ClosingCommunicationProfile,
      _ClosingTaskTemplateSet,
      _CreatedByUser,
      _LastChangedByUser,

      /*Text Associations */
      @Consumption.hidden: true
      _FinTaskListContextTypeText,
      @Consumption.hidden: true
      _ClosingTaskListHierTypeText,
      @Consumption.hidden: true
      _ClosingTaskListStatusText,
      @Consumption.hidden: true
      _ClosingTypeText,
      @Consumption.hidden: true
      _FiscalYearVariantText,
      @Consumption.hidden: true
      _TimeZoneText,
      @Consumption.hidden: true
      _ClosingTaskListRespTypeText,
      @Consumption.hidden: true
      _ClosingTemplateTypeText,
      @Consumption.hidden: true
      _FactoryCalendarText,
      @Consumption.hidden: true
      _LedgerText,
      @Consumption.hidden: true
      _AccountingPrincipleText,
      @Consumption.hidden: true
      _ClsgNotificationConfignText,
      @Consumption.hidden: true
      _ClsgAuthorizationGroupText,
      @Consumption.hidden: true
      _ClosingTaskTemplateSetText
}