I_ChmlCmplncInfoTP

@AbapCatalog:
{
 sqlViewName: 'ICCINFOTP',
 compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #CHECK,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}
--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@ObjectModel:
{
  modelCategory: #BUSINESS_OBJECT,
  compositionRoot: true,
  draftEnabled: true,
  transactionalProcessingEnabled: true,
  createEnabled: true,
  updateEnabled: 'EXTERNAL_CALCULATION',
  deleteEnabled: 'EXTERNAL_CALCULATION',
  writeDraftPersistence: 'ehfndw_cci',
  writeActivePersistence: 'ehfndv_cci',
  entityChangeStateId: 'LastChangeUTCDateTime',
  semanticKey:  [ 'ChmlCmplncInfoUUID' ],
  sapObjectNodeType.name: 'ChemicalComplianceInfo',
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L,
    serviceQuality: #B
  }
}

@EndUserText.label: 'Chemical Compliance Info'
define view I_ChmlCmplncInfoTP
  as select from I_ChmlCmplncInfo

  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  // association returns data only for packaged products; it's the assigned unpackaged product for the packaged product   

  association [0..1] to I_ChmlCmplncProdAssgmtTP      as _ProductAssignment   on $projection.ChmlCmplncInfoUUID = _ProductAssignment.ChmlCmplncInfoUUID
  
  association [0..*] to I_ChmlCmplncPrpsAssgmtTP      as _PurposeAssignment   on $projection.ChmlCmplncInfoUUID = _PurposeAssignment.ChmlCmplncInfoUUID
  association [0..*] to I_ChmlCmplncMktReqTP          as _MarketRequest       on $projection.ChmlCmplncInfoUUID = _MarketRequest.ChmlCmplncInfoUUID
  association [0..*] to I_ChmlCmplncMktCvrgTP         as _MarketCoverage      on $projection.ChmlCmplncInfoUUID = _MarketCoverage.ChmlCmplncInfoUUID
  association [0..*] to I_ChmlCmplncMatlAssgmtTP      as _MaterialAssignment  on $projection.ChmlCmplncInfoUUID = _MaterialAssignment.ChmlCmplncInfoUUID
  association [0..*] to I_ChmlCmplncApplAssgmtTP      as _Application         on $projection.ChmlCmplncInfoUUID = _Application.ChmlCmplncInfoUUID
  //  association [0..*] to I_ChmlCmplncApplicationTP     as _Application               on $projection.ChmlCmplncInfoUUID = _Application.ChmlCmplncInfoUUID

  association [0..*] to I_ChmlCmplncSuplrMatlAssgmtTP as _SuplrMatlAssignment on $projection.ChmlCmplncInfoUUID = _SuplrMatlAssignment.ChmlCmplncInfoUUID
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_ChmlCmplncWasteDataTP       as _WasteData           on $projection.ChmlCmplncInfoUUID = _WasteData.ChmlCmplncInfoUUID
{

      @ObjectModel.mandatory: true
  key ChmlCmplncInfoUUID,
      @ObjectModel.readOnly: true
      ChmlCmplncInfoUUID as ActiveChmlCmplncInfoUUID, --Active UUID of Chemical Compliance Information
      @ObjectModel.readOnly: true
      CreationUTCDateTime,
      @ObjectModel.readOnly: true
      CreatedByUser,
      @ObjectModel.readOnly: true
      LastChangeUTCDateTime,
      @ObjectModel.readOnly: true
      LastChangedByUser,
      @ObjectModel.mandatory: true
      ProdStewardshipRespUnit,
      DngrsGdsRespUnit,
      @ObjectModel.mandatory: true
      ChmlCmplncInfoType,
      @ObjectModel.mandatory: true
      ChmlCmplncInternalName,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      ChmlCmplncProdCatztnPhrsUUID,
      MaterialIsBaseProduct,
      MaterialIsSold,
      MaterialIsTransported,
      MaterialIsSourced,
      MaterialIsProduced,
      MaterialIsDisposed,
      MaterialIsEmissionRelevant,
      MatlIsMultiComponentProduct,

      // @ObjectModel.mandatory: true

      Specification,

      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      ChmlCmplncProdIsResearched,

      SpecificationInternalID,

      -- indicators to disable essential checks
      MatlIsNotDngrsGdsRlvt,
      MatlIsNotProdMarketabilityRlvt,
      MatlIsNotProdSafetyRlvt,
            
      /* Associations */
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _MarketRequest,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _MarketCoverage,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _MaterialAssignment,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _ProductAssignment,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _PurposeAssignment,
      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _Application,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _SuplrMatlAssignment,
      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _WasteData,
      _CreatedByUser,
      _LastChangedByUser,
      _RespUnitForDangerousGoods,
      _RespUnitForProductStewardship
      
}