I_ChmlCmplncIdfr

@EndUserText.label: 'Chemical Compliance Identifier'

@AccessControl:{
  authorizationCheck: #MANDATORY,
  // set not_required because admin data fields do not count as personal data and releasedby/processor point to the user

  // and it's not possible to block users

  personalData.blocking: #NOT_REQUIRED,
  privilegedAssociations: [ '_CreatedByUser', '_LastChangedByUser' ]
}

@VDM.viewType: #BASIC

@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  modelingPattern: #NONE,
  semanticKey: ['ChmlCmplncIdfrUUID'],
  supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ],
  usageType: {
    serviceQuality: #A,
    sizeCategory: #L,
    dataClass: #TRANSACTIONAL
  }
}
define root view entity I_ChmlCmplncIdfr
  as select from ehfndd_ccidfr
  composition [0..*] of I_ChmlCmplncIdfrValue as _ChmlCmplncIdfrValue

  association [0..1] to I_User                as _CreatedByUser     on _CreatedByUser.UserID = $projection.CreatedByUser
  association [0..1] to I_User                as _LastChangedByUser on _LastChangedByUser.UserID = $projection.LastChangedByUser
  association [0..1] to I_ChmlCmplncInfo      as _ChmlCmplncInfo    on _ChmlCmplncInfo.ChmlCmplncInfoUUID = $projection.ChmlCmplncIdfrParentUUID
  association [0..1] to I_BusinessUserBasic   as _Processor         on _Processor.BusinessPartner = $projection.ChmlCmplncIdfrProcessor
  association [0..1] to I_BusinessUserBasic   as _ReleasedByUser    on _ReleasedByUser.BusinessPartner = $projection.ChmlCmplncIdfrReldByUser

{
  key chmlcmplncidfruuid        as ChmlCmplncIdfrUUID,

      @Semantics.systemDateTime.createdAt: true
      creationutcdatetime       as CreationUTCDateTime,

      @Semantics.user.createdBy: true
      createdbyuser             as CreatedByUser,

      @Semantics.systemDateTime.lastChangedAt: true
      lastchangeutcdatetime     as LastChangeUTCDateTime,

      @Semantics.user.lastChangedBy: true
      lastchangedbyuser         as LastChangedByUser,

      cast( chmlcmplncidfrparentid as ehfnd_internal_nr_nc preserving type ) as ChmlCmplncIdfrParentID,
      chmlcmplncidfrparentuuid  as ChmlCmplncIdfrParentUUID,
      chmlcmplncidfrparenttype  as ChmlCmplncIdfrParentType,

      chmlcmplncidfrprocgstatus as ChmlCmplncIdfrProcgStatus,
      chmlcmplncidfrprocessor   as ChmlCmplncIdfrProcessor,
      
      chmlcmplncidfrreldbyuser  as ChmlCmplncIdfrReldByUser,
      validitystartdatetime     as ValidityStartDateTime,
      validityenddatetime       as ValidityEndDateTime,

      /* Associations */
      _ChmlCmplncIdfrValue,
      _CreatedByUser,
      _LastChangedByUser,
      _Processor,
      _ReleasedByUser,
      _ChmlCmplncInfo      
}