I_CharcAttribSelectedSetCode

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Selected Set Code for Charc Attribute'
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities:
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.usageType: {
    dataClass: #CUSTOMIZING,
    sizeCategory: #S,
    serviceQuality: #A
}
@Metadata.ignorePropagatedAnnotations: true
define view entity I_CharcAttribSelectedSetCode as select from qpac 
   association [0..1] to I_CharcAttributeCodeGrp as _CharcAttributeCodeGrp
      on $projection.CharacteristicAttributeCodeGrp = _CharcAttributeCodeGrp.CharacteristicAttributeCodeGrp
      
   association [0..1] to I_CharcAttributeCode as _CharcAttributeCode
      on  $projection.CharacteristicAttributeCodeGrp = _CharcAttributeCode.CharacteristicAttributeCodeGrp
      and $projection.CharacteristicAttributeCode  = _CharcAttributeCode.CharacteristicAttributeCode
      
   association [0..1] to I_Indicator as _CodeIsInactive
      on $projection.CodeIsInactive = _CodeIsInactive.IndicatorValue

// Required for authority checks

   association [0..1] to I_CharcAttribSelectedCodeSet as _CharcAttribSelectedCodeSet
      on  $projection.SelectedCodeSetPlant = _CharcAttribSelectedCodeSet.SelectedCodeSetPlant
      and $projection.SelectedCodeSet      = _CharcAttribSelectedCodeSet.SelectedCodeSet

{
    key qpac.werks      as SelectedCodeSetPlant,
    //key katalogart as CharacteristicAttributeCatalog,

    key qpac.auswahlmge as SelectedCodeSet,
    key qpac.codegruppe as CharacteristicAttributeCodeGrp, 
    key qpac.code       as CharacteristicAttributeCode,
    //  key qpcd.version --> is always 1 so we could leave out   

    qpac.bewertung      as CharcAttributeValuation,
    qpac.geloescht      as CodeIsInactive,
    qpac.fehlklasse     as DefectClass,
    
    @Semantics.user.createdBy: true
    qpac.ersteller      as CharcAttribSeldSetCodeCrtedBy,
    @Semantics.businessDate.at: true
    qpac.e_datum        as CharcAttribSeldSetCodeCrtedOn,
    @Semantics.user.lastChangedBy: true
    qpac.aenderer       as CharcAttribSeldSetCodeChgdBy,
    @Semantics.businessDate.at: true
    qpac.a_datum        as CharcAttribSeldSetCodeChgdOn,
        
    /* Associations */
    _CharcAttributeCodeGrp,
    _CharcAttributeCode,
    _CodeIsInactive,
    _CharcAttribSelectedCodeSet
}
where katalogart = '1' and qpac.versionam = '000001'