I_CharcAttributeCode

DDL: I_CHARCATTRIBUTECODE Type: view_entity BASIC Package: VDM_QM_INSPECTION

Characteristic Attribute Code

I_CharcAttributeCode is a Basic CDS View that provides data about "Characteristic Attribute Code" in SAP S/4HANA. It reads from 1 data source (qpcd) and exposes 10 fields with key fields CharacteristicAttributeCodeGrp, CharacteristicAttributeCode. It has 2 associations to related views. Part of development package VDM_QM_INSPECTION.

1 data source(s) 10 fields

Data Sources (1)

SourceAliasJoin Type
qpcd qpcd from

Associations (2)

CardinalityTargetAliasCondition
[1..1] I_CharcAttributeCodeGrp _CharcAttributeCodeGrp $projection.CharacteristicAttributeCodeGrp = _CharcAttributeCodeGrp.CharacteristicAttributeCodeGrp
[0..*] I_CharcAttributeCodeText _Text $projection.CharacteristicAttributeCodeGrp = _Text.CharacteristicAttributeCodeGrp and $projection.CharacteristicAttributeCode = _Text.CharacteristicAttributeCode

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
EndUserText.label Characteristic Attribute Code view
VDM.viewType #BASIC view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.representativeKey CharacteristicAttributeCode view
Analytics.technicalName ICHARCATTRIBCODE view
Metadata.ignorePropagatedAnnotations true view

Fields (10)

KeyFieldSource TableSource FieldDescription
KEY CharacteristicAttributeCodeGrp codegruppe
KEY CharacteristicAttributeCode code
CharcAttributeCodeStatus inaktiv
CharcAttribCodeCreatedBy qpcd ersteller
CharcAttribCodeCreatedOn qpcd e_datum
CharcAttribCodeLastChgdBy qpcd aenderer
CharcAttribCodeLastChangedOn qpcd a_datum
CharacteristicAttributeCodeTxt
_Text _Text
_CharcAttributeCodeGrp _CharcAttributeCodeGrp 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Characteristic Attribute Code'
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities:
    [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.usageType: { dataClass: #CUSTOMIZING, sizeCategory: #S, serviceQuality: #A }
@ObjectModel.representativeKey: 'CharacteristicAttributeCode'
@Analytics.technicalName: 'ICHARCATTRIBCODE'
@Metadata.ignorePropagatedAnnotations: true
define view entity I_CharcAttributeCode as select from qpcd
    association [1..1] to I_CharcAttributeCodeGrp as _CharcAttributeCodeGrp
      on $projection.CharacteristicAttributeCodeGrp = _CharcAttributeCodeGrp.CharacteristicAttributeCodeGrp
    association [0..*] to I_CharcAttributeCodeText as _Text 
      on $projection.CharacteristicAttributeCodeGrp = _Text.CharacteristicAttributeCodeGrp 
      and $projection.CharacteristicAttributeCode = _Text.CharacteristicAttributeCode
{
    @Consumption.valueHelpDefinition: [ 
      { entity:  { name:    'I_CharcAttributeCodeGrpStdVH',
                   element: 'CharacteristicAttributeCodeGrp' }
      }]
    @ObjectModel.foreignKey.association: '_CharcAttributeCodeGrp'
    key codegruppe as CharacteristicAttributeCodeGrp,
//  key qpcd.version --> is always 1 so we could leave out

    @ObjectModel.text.association: '_Text'
    key code as  CharacteristicAttributeCode,
    inaktiv  as CharcAttributeCodeStatus,    

    @Semantics.user.createdBy: true
    qpcd.ersteller      as CharcAttribCodeCreatedBy,
    @Semantics.businessDate.at: true
    qpcd.e_datum        as CharcAttribCodeCreatedOn,
    @Semantics.user.lastChangedBy: true
    qpcd.aenderer       as CharcAttribCodeLastChgdBy,
    @Semantics.businessDate.at: true
    qpcd.a_datum        as CharcAttribCodeLastChangedOn,
    
    //Associations

    @Semantics.text: true
    _Text[1:Language = $session.system_language].CharacteristicAttributeCodeTxt,
    _Text,
    _CharcAttributeCodeGrp
}
where katalogart = '1' and version = '000001'

Learn More