I_BusPartMobileNumberProcTP

DDL: I_BUSPARTMOBILENUMBERPROCTP Type: view_entity TRANSACTIONAL Package: MDC_BUPA_GOV_BO

BP Mobile Number (Process Data)

I_BusPartMobileNumberProcTP is a Transactional CDS View that provides data about "BP Mobile Number (Process Data)" in SAP S/4HANA. It reads from 1 data source (I_BusPartMobileNumberProc) and exposes 31 fields with key fields MasterDataChangeProcess, MDChgProcessStep, MDChgProcessSrceSystem, MDChgProcessSrceObject, AddressNumber. It has 6 associations to related views. Part of development package MDC_BUPA_GOV_BO.

1 data source(s) 31 fields

Data Sources (1)

SourceAliasJoin Type
I_BusPartMobileNumberProc BusinessPartnerTelephoneNumber from

Associations (6)

CardinalityTargetAliasCondition
[1..1] I_BusinessPartnerProcessTP _BusinessPartner $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess and $projection.MDChgProcessStep = _BusinessPartner.MDChgProcessStep and $projection.MDChgProcessSrceSystem = _BusinessPartner.MDChgProcessSrceSystem and $projection.MDChgProcessSrceObject = _BusinessPartner.MDChgProcessSrceObject
[0..1] I_BusPartTelCountryPrefix _TelCountryPrefix $projection.MobilePhoneCountry = _TelCountryPrefix.Country
[0..1] I_BPProcessKPIRecordType _RecordType $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess and $projection.MDChgProcessStep = _RecordType.MDChgProcessStep and $projection.MDChgProcessSrceSystem = _RecordType.MDChgProcessSrceSystem and $projection.MDChgProcessSrceObject = _RecordType.MDChgProcessSrceObject
[0..1] I_MDChangeProcessKPIRowVH _KPIUpdateStatusText $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
[0..*] I_MDChgProcRecordMessages _RecordMessages $projection.MasterDataChangeProcess = _RecordMessages.MasterDataChangeProcess and $projection.MDChgProcessStep = _RecordMessages.MDChgProcessStep and $projection.MDChgProcessSrceSystem = _RecordMessages.MDChgProcessSrceSystem and $projection.MDChgProcessSrceObject = _RecordMessages.MDChgProcessSrceObject
[0..*] I_BPMobileNumberTextProcTP _BPMobileNumberTextProc

Annotations (9)

NameValueLevelField
AccessControl.authorizationCheck #CHECK view
EndUserText.label BP Mobile Number (Process Data) view
AccessControl.personalData.blocking #REQUIRED view
ObjectModel.usageType.serviceQuality #B view
ObjectModel.usageType.sizeCategory #XXL view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
Search.searchable true view
VDM.viewType #TRANSACTIONAL view
VDM.lifecycle.contract.type #SAP_INTERNAL_API view

Fields (31)

KeyFieldSource TableSource FieldDescription
KEY MasterDataChangeProcess MasterDataChangeProcess
KEY MDChgProcessStep MDChgProcessStep
KEY MDChgProcessSrceSystem MDChgProcessSrceSystem
KEY MDChgProcessSrceObject MDChgProcessSrceObject
KEY AddressNumber AddressNumber
KEY OrdinalNumber OrdinalNumber
AddrCommunicationValidFromDate AddrCommunicationValidFromDate
MobilePhoneCountry MobilePhoneCountry
TelephoneCountryPrefix _TelCountryPrefix TelephoneCountryPrefix
IsDefaultPhoneNumber IsDefaultPhoneNumber
CommNumberIsNotUsed CommNumberIsNotUsed
MobilePhoneNumber MobilePhoneNumber
CompleteTelephoneNumber CompleteTelephoneNumber
PhoneIsSMSEnabled PhoneIsSMSEnabled
PhoneNumberType PhoneNumberType
ValidityStartDateTime ValidityStartDateTime
ValidityEndDateTime ValidityEndDateTime
datsendasValidityStartDate
datsendasValidityEndDate
MDChgProcessSourceModified MDChgProcessSourceModified
MDChgProcessSourceModifBinary MDChgProcessSourceModifBinary
MDChgProcSrceLastChgdDateTime MDChgProcSrceLastChgdDateTime
AddressLine1Text
_BusinessPartner _BusinessPartner
_BusinessPartnerAddress _BusinessPartnerAddress
_BPMobileNumberTextProc _BPMobileNumberTextProc
_BPProtectedAddress _BPProtectedAddress
_TelCountryPrefix _TelCountryPrefix
_RecordType _RecordType
_KPIUpdateStatusText _KPIUpdateStatusText
_RecordMessages _RecordMessages 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BP Mobile Number (Process Data)'
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity I_BusPartMobileNumberProcTP
  as select from I_BusPartMobileNumberProc as BusinessPartnerTelephoneNumber
  
  composition [0..*] of I_BPMobileNumberTextProcTP            as _BPMobileNumberTextProc
  association [1..1] to I_BusinessPartnerProcessTP            as _BusinessPartner        on  $projection.MasterDataChangeProcess  = _BusinessPartner.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep         = _BusinessPartner.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem   = _BusinessPartner.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject   = _BusinessPartner.MDChgProcessSrceObject
  association        to parent I_BusinessPartnerAddressProcTP as _BusinessPartnerAddress on  $projection.MasterDataChangeProcess  = _BusinessPartnerAddress.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep         = _BusinessPartnerAddress.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem   = _BusinessPartnerAddress.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject   = _BusinessPartnerAddress.MDChgProcessSrceObject
                                                                                         and $projection.AddressNumber            = _BusinessPartnerAddress.AddressNumber
  association [0..1] to I_BusPartTelCountryPrefix             as _TelCountryPrefix       on  $projection.MobilePhoneCountry       = _TelCountryPrefix.Country
  association [0..1] to I_BPProcessKPIRecordType              as _RecordType             on  $projection.MasterDataChangeProcess  = _RecordType.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep         = _RecordType.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem   = _RecordType.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject   = _RecordType.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessKPIRowVH             as _KPIUpdateStatusText    on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  association [0..*] to I_MDChgProcRecordMessages             as _RecordMessages         on  $projection.MasterDataChangeProcess  = _RecordMessages.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep         = _RecordMessages.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem   = _RecordMessages.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject   = _RecordMessages.MDChgProcessSrceObject
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key AddressNumber,
  key OrdinalNumber,
      AddrCommunicationValidFromDate,
      MobilePhoneCountry,
      _TelCountryPrefix.TelephoneCountryPrefix                             as TelephoneCountryPrefix,
      IsDefaultPhoneNumber,
      CommNumberIsNotUsed,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      MobilePhoneNumber,
      CompleteTelephoneNumber,
      PhoneIsSMSEnabled,
      PhoneNumberType,
      ValidityStartDateTime,
      ValidityEndDateTime,
      @Semantics.businessDate.from: true
      case when ValidityStartDateTime != ''
      then cast ( (substring(ValidityStartDateTime,1,8) ) as abap.dats )
      else cast ( '00010101' as abap.dats )
      end                                                                  as ValidityStartDate,
      @Semantics.businessDate.to: true
      case when ValidityEndDateTime != ''
      then cast ( (substring(ValidityEndDateTime,1,8) ) as abap.dats )
      else cast ( '99991231' as abap.dats )
      end                                                                  as ValidityEndDate,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,
      MDChgProcSrceLastChgdDateTime,
      
      /* Record Identification */
      /* Has been moved to a virtual field in the projection layer, therefore the dummy entry */
      cast( '' as abap.char(209) )  as AddressLine1Text,
      cast( case
              when MDChgProcessSourceModified = '' then 'N'
              when MDChgProcessSourceModified = 'X' then 'M'
              else MDChgProcessSourceModified end as mdc_source_modified ) as MDChgProcKPIUpdateStatus,

      /* Associations */
      _BusinessPartner,
      _BusinessPartnerAddress,
      _BPMobileNumberTextProc,
      _BPProtectedAddress,
      _TelCountryPrefix,
      _RecordType,
      _KPIUpdateStatusText,
      _RecordMessages
}

Learn More