I_BPPhoneNumberTextProcTP

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'BP Address-Depend Phone Text (Process)'
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #XXL,
  dataClass: #TRANSACTIONAL
}
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity I_BPPhoneNumberTextProcTP
  as select from I_BPPhoneNumberTextProc
  
  association [1..1] to I_BusinessPartnerProcessTP            as _BusinessPartner     on  $projection.MasterDataChangeProcess  = _BusinessPartner.MasterDataChangeProcess
                                                                                      and $projection.MDChgProcessStep         = _BusinessPartner.MDChgProcessStep
                                                                                      and $projection.MDChgProcessSrceSystem   = _BusinessPartner.MDChgProcessSrceSystem
                                                                                      and $projection.MDChgProcessSrceObject   = _BusinessPartner.MDChgProcessSrceObject
  association to parent I_BusPartTelephoneNumberProcTP as _BusinessPartnerPhoneNumber on  $projection.MasterDataChangeProcess  = _BusinessPartnerPhoneNumber.MasterDataChangeProcess
                                                                                      and $projection.MDChgProcessStep         = _BusinessPartnerPhoneNumber.MDChgProcessStep
                                                                                      and $projection.MDChgProcessSrceSystem   = _BusinessPartnerPhoneNumber.MDChgProcessSrceSystem
                                                                                      and $projection.MDChgProcessSrceObject   = _BusinessPartnerPhoneNumber.MDChgProcessSrceObject
                                                                                      and $projection.AddressNumber            = _BusinessPartnerPhoneNumber.AddressNumber
                                                                                      and $projection.OrdinalNumber            = _BusinessPartnerPhoneNumber.OrdinalNumber
  association [0..1] to I_BPProcessKPIRecordType              as _RecordType          on  $projection.MasterDataChangeProcess  = _RecordType.MasterDataChangeProcess
                                                                                      and $projection.MDChgProcessStep         = _RecordType.MDChgProcessStep
                                                                                      and $projection.MDChgProcessSrceSystem   = _RecordType.MDChgProcessSrceSystem
                                                                                      and $projection.MDChgProcessSrceObject   = _RecordType.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessKPIRowVH             as _KPIUpdateStatusText on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  association [0..*] to I_MDChgProcRecordMessages             as _RecordMessages      on  $projection.MasterDataChangeProcess  = _RecordMessages.MasterDataChangeProcess
                                                                                      and $projection.MDChgProcessStep         = _RecordMessages.MDChgProcessStep
                                                                                      and $projection.MDChgProcessSrceSystem   = _RecordMessages.MDChgProcessSrceSystem
                                                                                      and $projection.MDChgProcessSrceObject   = _RecordMessages.MDChgProcessSrceObject
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key AddressNumber,
  key OrdinalNumber,
  key Language,
      AddrCommunicationValidFromDate,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      CommunicationRemarkText,
      MDChgProcSrceLastChgdDateTime,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,
      
      cast( case
        when MDChgProcessSourceModified = '' then 'N'
        when MDChgProcessSourceModified = 'X' then 'M'
        else MDChgProcessSourceModified end as mdc_source_modified) as MDChgProcKPIUpdateStatus,
      _BusinessPartnerPhoneNumber.PhoneNumber as PhoneNumber,
        
      /* Associations */
      _BPProtectedAddress,
      _BusinessPartner,
      _BusinessPartnerPhoneNumber,
      _RecordType,
      _KPIUpdateStatusText,
      _RecordMessages
}