I_BPFaxNumberProcessTP

@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Search.searchable
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'View for fax numbers from BP (Process)'
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity I_BPFaxNumberProcessTP
  as select from I_BPFaxNumberProcess  

  composition [0..*] of I_BPFaxNumberTextProcTP               as _BPFaxNumberTextProcTP
  association [1..1] to I_BusinessPartnerProcessTP            as _BusinessPartner        on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association        to parent I_BusinessPartnerAddressProcTP as _BusinessPartnerAddress on  $projection.MasterDataChangeProcess = _BusinessPartnerAddress.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep        = _BusinessPartnerAddress.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem  = _BusinessPartnerAddress.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject  = _BusinessPartnerAddress.MDChgProcessSrceObject
                                                                                         and $projection.AddressNumber           = _BusinessPartnerAddress.AddressNumber
  association [0..1] to I_BusPartTelCountryPrefix             as _FaxCountryPrefix       on  $projection.FaxCountry = _FaxCountryPrefix.Country
  association [0..1] to I_BPProcessKPIRecordType              as _RecordType             on  $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep        = _RecordType.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem  = _RecordType.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject  = _RecordType.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessKPIRowVH             as _KPIUpdateStatusText    on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  association [0..*] to I_MDChgProcRecordMessages             as _RecordMessages         on  $projection.MasterDataChangeProcess = _RecordMessages.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep        = _RecordMessages.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem  = _RecordMessages.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject  = _RecordMessages.MDChgProcessSrceObject
{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key AddressNumber,
  key OrdinalNumber,
      AddrCommunicationValidFromDate,
      IsDefaultFaxNumber,
      FaxCountry,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      AddressFaxNumber,
      FaxNumberExtension,
      InternationalFaxNumber,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,
      MDChgProcSrceLastChgdDateTime,
      
      /* Record Identification */
      /* Has been moved to a virtual field in the projection layer, therefore the dummy entry */
      cast( '' as abap.char(209) )  as AddressLine1Text,
      cast( case
        when MDChgProcessSourceModified = '' then 'N'
        when MDChgProcessSourceModified = 'X' then 'M'
        else MDChgProcessSourceModified end as mdc_source_modified ) as MDChgProcKPIUpdateStatus,

      _BusinessPartner,
      _BusinessPartnerAddress,
      _BPFaxNumberTextProcTP,
      _BPProtectedAddress,
      _FaxCountryPrefix,
      _RecordType,
      _KPIUpdateStatusText,
      _RecordMessages
}