I_BPCustomerSalesAreaProcessTP

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'BP Customer Sales Area Data - TP'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType: #TRANSACTIONAL
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity I_BPCustomerSalesAreaProcessTP
  as select from I_BPCustomerSalesAreaProcess
  composition [0..*] of I_BPCustPartnerFunctionsProcTP as _CustomerPartnerFunctions
  composition [0..*] of I_BPCustSalesTextGeneralProcTP as _CustomerSalesTextGeneral
  association        to parent I_BPCustomerProcessTP          as _Customer               on  $projection.MasterDataChangeProcess = _Customer.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep        = _Customer.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem  = _Customer.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject  = _Customer.MDChgProcessSrceObject
                                                                                         and $projection.BPAssignmentID          = _Customer.BPAssignmentID
  association        to I_BusinessPartnerProcessTP            as _BusinessPartner        on  $projection.MasterDataChangeProcess = _BusinessPartner.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep        = _BusinessPartner.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem  = _BusinessPartner.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject  = _BusinessPartner.MDChgProcessSrceObject
  association [0..1] to I_BPProcessKPIRecordType       as _RecordType                    on  $projection.MasterDataChangeProcess = _RecordType.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep        = _RecordType.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem  = _RecordType.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject  = _RecordType.MDChgProcessSrceObject
  association [0..1] to I_MDChangeProcessKPIRowVH      as _KPIUpdateStatusText           on  $projection.MDChgProcKPIUpdateStatus = _KPIUpdateStatusText.MDChgProcKPIUpdateStatus
  association [0..1] to I_SalesArea                    as _SalesArea                     on  $projection.SalesOrganization   = _SalesArea.SalesOrganization
                                                                                         and $projection.DistributionChannel = _SalesArea.DistributionChannel
                                                                                         and $projection.Division            = _SalesArea.Division
  association [0..1] to I_SalesDistrict                as _SalesDistrict                 on  $projection.SalesDistrict = _SalesDistrict.SalesDistrict
  association [0..1] to I_SalesAreaSalesOffice         as _SalesOffice                   on  $projection.SalesOrganization   = _SalesOffice.SalesOrganization
                                                                                         and $projection.DistributionChannel = _SalesOffice.DistributionChannel
                                                                                         and $projection.Division            = _SalesOffice.OrganizationDivision
                                                                                         and $projection.SalesOffice         = _SalesOffice.SalesOffice
  association [0..1] to I_SalesOfficeSalesGroup        as _SalesOfficeSalesGroup         on  $projection.SalesOffice = _SalesOfficeSalesGroup.SalesOffice
                                                                                         and $projection.SalesGroup  = _SalesOfficeSalesGroup.SalesGroup
  association [0..1] to I_CustomerGroup                as _CustomerGroup                 on  $projection.CustomerGroup = _CustomerGroup.CustomerGroup
  association [0..1] to I_BusPartAuthorizationGroup    as _AuthorizationGroup            on  $projection.AuthorizationGroup          = _AuthorizationGroup.AuthorizationGroup
                                                                                         and _AuthorizationGroup.AuthorizationObject = 'BUPA'
  association [0..1] to I_PriceListType                as _PriceListType                 on  $projection.PriceListType = _PriceListType.PriceListType
  association [0..1] to I_PartialDeliveryItem          as _PartialDeliveryItem           on  $projection.PartialDeliveryIsAllowed = _PartialDeliveryItem.PartialDeliveryIsAllowed
  association [0..1] to I_DeliveryPriority             as _DeliveryPriority              on  $projection.DeliveryPriority = _DeliveryPriority.DeliveryPriority
  association [0..1] to I_ShippingCondition            as _ShippingCondition             on  $projection.ShippingCondition = _ShippingCondition.ShippingCondition
  association [0..1] to I_FactoryCalendar              as _InvoiceCalendar               on  $projection.InvcCalendarDateIdentification = _InvoiceCalendar.FactoryCalendar
  association [0..1] to I_FactoryCalendar              as _InvoiceListSchedule           on  $projection.InvoiceListSchedule = _InvoiceListSchedule.FactoryCalendar
  association [0..1] to I_Currency                     as _Currency                      on  $projection.Currency = _Currency.Currency
  association [0..1] to I_CustomerPaymentTerms         as _PaymentTerms                  on  $projection.CustomerPaymentTerms = _PaymentTerms.CustomerPaymentTerms
  association [0..1] to I_Allwdplantsperslsorg         as _Plant                         on  $projection.SalesOrganization   = _Plant.SalesOrganization
                                                                                         and $projection.DistributionChannel = _Plant.DistributionChannel
                                                                                         and $projection.SupplyingPlant      = _Plant.Plant
  association [0..1] to I_AdditionalCustomerGroup1     as _AdditionalCustomerGroup1      on  $projection.AdditionalCustomerGroup1 = _AdditionalCustomerGroup1.AdditionalCustomerGroup1
  association [0..1] to I_AdditionalCustomerGroup2     as _AdditionalCustomerGroup2      on  $projection.AdditionalCustomerGroup2 = _AdditionalCustomerGroup2.AdditionalCustomerGroup2
  association [0..1] to I_AdditionalCustomerGroup3     as _AdditionalCustomerGroup3      on  $projection.AdditionalCustomerGroup3 = _AdditionalCustomerGroup3.AdditionalCustomerGroup3
  association [0..1] to I_AdditionalCustomerGroup4     as _AdditionalCustomerGroup4      on  $projection.AdditionalCustomerGroup4 = _AdditionalCustomerGroup4.AdditionalCustomerGroup4
  association [0..1] to I_AdditionalCustomerGroup5     as _AdditionalCustomerGroup5      on  $projection.AdditionalCustomerGroup5 = _AdditionalCustomerGroup5.AdditionalCustomerGroup5
  association [0..1] to I_CustomerPaytGuarProced       as _CustomerPaytGuarProced        on  $projection.CustomerPaytGuarProced = _CustomerPaytGuarProced.CustomerPaytGuarProced
  association [0..1] to I_CreditControlArea            as _CreditControlArea             on  $projection.CreditControlArea = _CreditControlArea.CreditControlArea
  association [0..1] to I_UOMGroup                     as _ProductUnitGroup              on  $projection.ProductUnitGroup = _ProductUnitGroup.ProductUnitGroup
  association [0..1] to I_IncotermsVersion             as _IncotermsVersion              on  $projection.IncotermsVersion = _IncotermsVersion.IncotermsVersion
  association [0..1] to I_IncotermsClassification      as _IncotermsClassification       on  $projection.IncotermsClassification = _IncotermsClassification.IncotermsClassification
  association [0..1] to I_DeliveryBlockReason          as _DeliveryBlockReason           on  $projection.DeliveryIsBlocked = _DeliveryBlockReason.DeliveryBlockReason
  association [0..1] to I_CustomerAccountAssgmtGroup   as _AccountAssgmtGroup            on  $projection.CustomerAccountAssignmentGroup = _AccountAssgmtGroup.CustomerAccountAssignmentGroup
  association [0..1] to I_BillingBlockReason           as _BillingBlockReason            on  $projection.BillingIsBlockedForCustomer = _BillingBlockReason.BillingBlockReason
  association [0..1] to I_CustomerPriceGroup           as _PriceGroup                    on  $projection.CustomerPriceGroup = _PriceGroup.CustomerPriceGroup
  association [0..1] to I_ExchangeRateType             as _ExchangeRateType              on  $projection.ExchangeRateType = _ExchangeRateType.ExchangeRateType

  association [0..1] to E_BPCustomerSalesAreaProcess   as _ExtBPCustomerSalesAreaProcess on  $projection.MasterDataChangeProcess = _ExtBPCustomerSalesAreaProcess.MasterDataChangeProcess
                                                                                         and $projection.MDChgProcessStep        = _ExtBPCustomerSalesAreaProcess.MDChgProcessStep
                                                                                         and $projection.MDChgProcessSrceSystem  = _ExtBPCustomerSalesAreaProcess.MDChgProcessSrceSystem
                                                                                         and $projection.MDChgProcessSrceObject  = _ExtBPCustomerSalesAreaProcess.MDChgProcessSrceObject
                                                                                         and $projection.BPAssignmentID          = _ExtBPCustomerSalesAreaProcess.BPAssignmentID
                                                                                         and $projection.SalesOrganization       = _ExtBPCustomerSalesAreaProcess.SalesOrganization
                                                                                         and $projection.DistributionChannel     = _ExtBPCustomerSalesAreaProcess.DistributionChannel
                                                                                         and $projection.Division                = _ExtBPCustomerSalesAreaProcess.Division

{
  key MasterDataChangeProcess,
  key MDChgProcessStep,
  key MDChgProcessSrceSystem,
  key MDChgProcessSrceObject,
  key SalesOrganization,
  key DistributionChannel,
  key Division,
  key BPAssignmentID,
      Customer,
      AuthorizationGroup,
      DeletionIndicator,
      OrderIsBlockedForCustomer,
      BPCustomerPricingProcedure,
      CustomerGroup,
      SalesDistrict,
      CustomerPriceGroup,
      PriceListType,
      ItemOrderProbabilityInPercent,
      IncotermsClassification,
      IncotermsTransferLocation,
      DeliveryIsBlocked,
      CompleteDeliveryIsDefined,
      MaxNmbrOfPartialDelivery,
      PartialDeliveryIsAllowed,
      OrderCombinationIsAllowed,
      DeliveryPriority,
      AccountByCustomer,
      ShippingCondition,
      BillingIsBlockedForCustomer,
      ManualInvoiceMaintIsRelevant,
      InvcCalendarDateIdentification,
      InvoiceListSchedule,
      Currency,
      CustomerABCClassification,
      CustomerAccountAssignmentGroup,
      CustomerPaymentTerms,
      SupplyingPlant,
      SalesGroup,
      SalesOffice,
      SalesItemProposal,
      AdditionalCustomerGroup1,
      AdditionalCustomerGroup2,
      AdditionalCustomerGroup3,
      AdditionalCustomerGroup4,
      AdditionalCustomerGroup5,
      CustomerIsRebateRelevant,
      ExchangeRateType,
      InspSbstHasNoTimeOrQuantity,
      CustomerPaytGuarProced,
      CreditControlArea,
      @Semantics.booleanIndicator: true
      cast( case when BlockingForCustomerSalesArea = 'X ' then 'X' else '' end as boole_d ) as CustomerSalesAreaIsBlocked,
      SuplrIsRlvtForSettlmtMgmt,
      ProductUnitGroup,
      OverdelivTolrtdLmtRatioInPct,
      UnderdelivTolrtdLmtRatioInPct,
      SlsUnlmtdOvrdelivIsAllwd,
      CustProdProposalProcedure,
      SlsDocIsRlvtForProofOfDeliv,
      ProofOfDeliveryTimeValue,
      IncotermsVersion,
      IncotermsLocation1,
      IncotermsLocation2,
      @Semantics.booleanIndicator
      IsBusinessPurposeCompleted,
      MDChgProcSrceLastChgdDateTime,
      MDChgProcessSourceModified,
      MDChgProcessSourceModifBinary,
      cast(
        case
          when MDChgProcessSourceModified = '' then 'N'
          when MDChgProcessSourceModified = 'X' then 'M'
        else MDChgProcessSourceModified end as mdc_source_modified
      )                                                                                     as MDChgProcKPIUpdateStatus,

      _Customer,
      _BusinessPartner,
      _CustomerSalesTextGeneral,
      _CustomerPartnerFunctions,
      _RecordType,
      _KPIUpdateStatusText,
      _SalesArea,
      _SalesDistrict,
      _SalesOffice,
      _SalesOfficeSalesGroup,
      _CustomerGroup,
      _AuthorizationGroup,
      _PriceListType,
      _PartialDeliveryItem,
      _DeliveryPriority,
      _ShippingCondition,
      _InvoiceCalendar,
      _InvoiceListSchedule,
      _Currency,
      _PaymentTerms,
      _Plant,
      _AdditionalCustomerGroup1,
      _AdditionalCustomerGroup2,
      _AdditionalCustomerGroup3,
      _AdditionalCustomerGroup4,
      _AdditionalCustomerGroup5,
      _CustomerPaytGuarProced,
      _CreditControlArea,
      _ProductUnitGroup,
      _IncotermsVersion,
      _IncotermsClassification,
      _DeliveryBlockReason,
      _AccountAssgmtGroup,
      _BillingBlockReason,
      _PriceGroup,
      _ExchangeRateType
}