I_BPCUSTOMERSALESAREAPROCESS
BP Customer Sales Area Data
I_BPCUSTOMERSALESAREAPROCESS is a CDS View in S/4HANA. BP Customer Sales Area Data. It contains 9 fields. 4 CDS views read from this table.
CDS Views using this table (4)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_BPCustomerSalesAreaGov | view_entity | from | BASIC | BP Customer Sales Area Governance data |
| I_BPCustomerSalesAreaProcessTP | view_entity | from | TRANSACTIONAL | BP Customer Sales Area Data - TP |
| I_BPCustSalesAreaProcChanges | view_entity | from | TRANSACTIONAL | BP Customer Sales Area Process Changes |
| I_BPCustSalesAreaProcChanges | view_entity | union_all | TRANSACTIONAL | BP Customer Sales Area Process Changes |
Fields (9)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | BPAssignmentID | BPAssignmentID | 1 |
| KEY | DistributionChannel | DistributionChannel | 1 |
| KEY | Division | Division | 1 |
| KEY | MasterDataChangeProcess | MasterDataChangeProcess | 1 |
| KEY | MDChgProcessSrceObject | MDChgProcessSrceObject | 1 |
| KEY | MDChgProcessSrceSystem | MDChgProcessSrceSystem | 1 |
| KEY | MDChgProcessStep | MDChgProcessStep | 1 |
| KEY | SalesOrganization | SalesOrganization | 1 |
| MDChgProcessSourceModified | MDChgProcessSourceModified | 1 |
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'BP Customer Sales Area Data'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
serviceQuality: #X,
sizeCategory: #S,
dataClass: #MIXED
}
@VDM.viewType: #BASIC
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view entity I_BPCustomerSalesAreaProcess
as select from knvv_prc
association [0..1] to I_BPCustomerProcess as _Customer on $projection.MasterDataChangeProcess = _Customer.MasterDataChangeProcess
and $projection.MDChgProcessStep = _Customer.MDChgProcessStep
and $projection.MDChgProcessSrceSystem = _Customer.MDChgProcessSrceSystem
and $projection.MDChgProcessSrceObject = _Customer.MDChgProcessSrceObject
and $projection.BPAssignmentID = _Customer.BPAssignmentID
association [0..1] to E_BPCustomerSalesAreaProcess as _ExtBPCustomerSalesAreaProcess on $projection.MasterDataChangeProcess = _ExtBPCustomerSalesAreaProcess.MasterDataChangeProcess
and $projection.MDChgProcessStep = _ExtBPCustomerSalesAreaProcess.MDChgProcessStep
and $projection.MDChgProcessSrceSystem = _ExtBPCustomerSalesAreaProcess.MDChgProcessSrceSystem
and $projection.MDChgProcessSrceObject = _ExtBPCustomerSalesAreaProcess.MDChgProcessSrceObject
and $projection.BPAssignmentID = _ExtBPCustomerSalesAreaProcess.BPAssignmentID
and $projection.SalesOrganization = _ExtBPCustomerSalesAreaProcess.SalesOrganization
and $projection.DistributionChannel = _ExtBPCustomerSalesAreaProcess.DistributionChannel
and $projection.Division = _ExtBPCustomerSalesAreaProcess.Division
{
key process_id as MasterDataChangeProcess,
key process_step_no as MDChgProcessStep,
key source_system as MDChgProcessSrceSystem,
key source_id as MDChgProcessSrceObject,
key vkorg as SalesOrganization,
key vtweg as DistributionChannel,
key spart as Division,
key assignment_id as BPAssignmentID,
kunnr as Customer,
begru as AuthorizationGroup,
loevm as DeletionIndicator,
aufsd as OrderIsBlockedForCustomer,
kalks as BPCustomerPricingProcedure,
kdgrp as CustomerGroup,
bzirk as SalesDistrict,
konda as CustomerPriceGroup,
pltyp as PriceListType,
awahr as ItemOrderProbabilityInPercent,
inco1 as IncotermsClassification,
inco2 as IncotermsTransferLocation,
lifsd as DeliveryIsBlocked,
autlf as CompleteDeliveryIsDefined,
antlf as MaxNmbrOfPartialDelivery,
kztlf as PartialDeliveryIsAllowed,
kzazu as OrderCombinationIsAllowed,
lprio as DeliveryPriority,
eikto as AccountByCustomer,
vsbed as ShippingCondition,
faksd as BillingIsBlockedForCustomer,
mrnkz as ManualInvoiceMaintIsRelevant,
perfk as InvcCalendarDateIdentification,
perrl as InvoiceListSchedule,
waers as Currency,
klabc as CustomerABCClassification,
ktgrd as CustomerAccountAssignmentGroup,
zterm as CustomerPaymentTerms,
vwerk as SupplyingPlant,
vkgrp as SalesGroup,
vkbur as SalesOffice,
vsort as SalesItemProposal,
kvgr1 as AdditionalCustomerGroup1,
kvgr2 as AdditionalCustomerGroup2,
kvgr3 as AdditionalCustomerGroup3,
kvgr4 as AdditionalCustomerGroup4,
kvgr5 as AdditionalCustomerGroup5,
bokre as CustomerIsRebateRelevant,
kurst as ExchangeRateType,
prfre as InspSbstHasNoTimeOrQuantity,
kabss as CustomerPaytGuarProced,
kkber as CreditControlArea,
cassd as BlockingForCustomerSalesArea,
agrel as SuplrIsRlvtForSettlmtMgmt,
megru as ProductUnitGroup,
uebto as OverdelivTolrtdLmtRatioInPct,
untto as UnderdelivTolrtdLmtRatioInPct,
uebtk as SlsUnlmtdOvrdelivIsAllwd,
pvksm as CustProdProposalProcedure,
podkz as SlsDocIsRlvtForProofOfDeliv,
cast( division(podtg, 240000, 2 ) as cust_pod ) as ProofOfDeliveryTimeValue,
incov as IncotermsVersion,
inco2_l as IncotermsLocation1,
inco3_l as IncotermsLocation2,
@Semantics.booleanIndicator
cvp_xblck_v as IsBusinessPurposeCompleted,
source_recency as MDChgProcSrceLastChgdDateTime,
source_modified as MDChgProcessSourceModified,
source_modification_blip as MDChgProcessSourceModifBinary,
_Customer
}
where
assignment_id = '000000000002'
or assignment_id is initial