I_BPAddlCustMblPhNumberTP

@AbapCatalog.sqlViewName: 'IBPADDCMPNTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'BO view for Mob Ph of MLTAS Customers'
@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.writeEnabled: true

@ObjectModel.writeDraftPersistence: 'BPADDCMPN_D'
@ObjectModel.draftEnabled:true

@ObjectModel.semanticKey: ['BusinessPartner', 'Customer', 'AddressID', 'Person', 'OrdinalNumber' ] // Need to check

@ObjectModel.createEnabled
@ObjectModel.updateEnabled
@ObjectModel.deleteEnabled

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER

@Search.searchable: true
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view I_BPAddlCustMblPhNumberTP as select from I_BPMobilePhoneNumber as BPMobileNumber  inner join I_BPMultipleAssignment as BPMultipleAssignment on BPMobileNumber.AddressID = BPMultipleAssignment.AddressNumber inner join I_Customer as Customer on BPMultipleAssignment.BPObjectID = Customer.Customer
association [1..1] to I_BusinessPartnerTP as _BusinessPartner on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
association [1..1] to I_BPAdditionalCustomerTP as _BPAdditionalCustomer on $projection.BusinessPartner = _BPAdditionalCustomer.BusinessPartner
                                                                         and $projection.Customer = _BPAdditionalCustomer.Customer 


{
    key BPMultipleAssignment.BusinessPartner,
    key Customer.Customer as Customer,
    key BPMobileNumber.AddressID, 
    key BPMobileNumber.Person, 
    key BPMobileNumber.OrdinalNumber, 
    BPMobileNumber.MobilePhoneCountry, 
    BPMobileNumber.IsDefaultPhoneNumber, 
    @Search.defaultSearchElement: true
    @Search.fuzzinessThreshold: 0.8
    @Search.ranking: #HIGH
    BPMobileNumber.MobilePhoneNumber, 
    BPMobileNumber.PhoneNumberType,
    BPMobileNumber._AddressCommunicationRemark.CommunicationRemarkText as AddressCommunicationRemarkText,
   // cast('' as ad_remark2 ) as AddressCommunicationRemarkText,

    @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT ]
    _BusinessPartner,
    @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT ]
    _BPAdditionalCustomer
   
}
where BPMultipleAssignment.IsStandardAssignment <> 'X' and BPMultipleAssignment.BPAssignmentCategory = 'CUST'