I_BPAdditionalCustomerTP

@EndUserText.label: 'BO view for Additional Customers of BP'
@AbapCatalog.sqlViewName: 'IBPADDCUSTTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK

@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.writeEnabled: true
@ObjectModel.writeDraftPersistence: 'BPADDCUST_D'
@ObjectModel.semanticKey: [ 'BusinessPartner', 'Customer' ]
@ObjectModel.draftEnabled:true
@ObjectModel.createEnabled
@ObjectModel.deleteEnabled: 'EXTERNAL_CALCULATION'
@ObjectModel.updateEnabled
@Search.searchable: true


@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@Consumption.dbHints: [ 'USE_HEX_PLAN' ]
define view I_BPAdditionalCustomerTP
  as select from I_BPMultipleAssignment as BPAdditionalCustomer
    inner join   I_Customer             as Customer on BPAdditionalCustomer.BPObjectID = Customer.Customer

  association [1..1] to I_BusinessPartnerTP        as _BusinessPartner        on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  association [1..*] to I_BPAddlCustCompanyCodeTP  as _BPAddlCustCompanyCode  on  $projection.BusinessPartner = _BPAddlCustCompanyCode.BusinessPartner
                                                                              and $projection.Customer        = _BPAddlCustCompanyCode.Customer

  association [1..*] to I_BPAddlCustSalesAreaTP    as _BPAddlCustSalesArea    on  $projection.BusinessPartner = _BPAddlCustSalesArea.BusinessPartner
                                                                              and $projection.Customer        = _BPAddlCustSalesArea.Customer
  association [1..*] to I_BPAddlCustTelNmbrTP      as _BPAddlCustTelNmbr      on  $projection.BusinessPartner = _BPAddlCustTelNmbr.BusinessPartner
                                                                              and $projection.Customer        = _BPAddlCustTelNmbr.Customer
  association [1..*] to I_BPAddlCustEmailAddressTP as _BPAddlCustEmailAddress on  $projection.BusinessPartner = _BPAddlCustEmailAddress.BusinessPartner
                                                                              and $projection.Customer        = _BPAddlCustEmailAddress.Customer
  association [1..*] to I_BPAddlCustMblPhNumberTP  as _BPAddlCustMblPhNumber  on  $projection.BusinessPartner = _BPAddlCustMblPhNumber.BusinessPartner
                                                                              and $projection.Customer        = _BPAddlCustMblPhNumber.Customer
  association [1..*] to I_BPAddlCustWebsiteURLTP   as _BPAddlCustWebsiteURL   on  $projection.BusinessPartner = _BPAddlCustWebsiteURL.BusinessPartner
                                                                              and $projection.Customer        = _BPAddlCustWebsiteURL.Customer
  association [1..*] to I_BPAddlCustFaxNumberTP    as _BPAddlCustFaxNumber    on  $projection.BusinessPartner = _BPAddlCustFaxNumber.BusinessPartner
                                                                              and $projection.Customer        = _BPAddlCustFaxNumber.Customer
{

  key BPAdditionalCustomer.BusinessPartner,
  key Customer.Customer                    as Customer,
      @ObjectModel.foreignKey.association: null
      BPAdditionalCustomer.BusinessPartner as BusinessPartnerForEdit,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Customer.Customer                    as CustomerForEdit,
      BPAdditionalCustomer.BPAssignmentID,
      BPAdditionalCustomer.BPAssignmentCategory,
      BPAdditionalCustomer.BPAssignmentReasonID,
      BPAdditionalCustomer.IsStandardAssignment,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      BPAdditionalCustomer.AddressNumber,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Customer.CustomerAccountGroup,
      Customer.AlternativePayerAccount,
      Customer.DataMediumExchangeIndicator,
      Customer.Supplier,
      //@ObjectModel.text.association: 'Customer._CustomerClassification._Text'

      Customer.CustomerClassification,
      Customer.VATLiability,
      Customer.PostingIsBlocked,
      Customer.DeliveryIsBlocked,
      Customer.BillingIsBlockedForCustomer,
      Customer.OrderIsBlockedForCustomer,
      //Data protection and privacy Requirement

      Customer.AuthorizationGroup,
      Customer.CustomerName, 
      Customer.BPCustomerName,
      Customer.DeliveryDateTypeRule,
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      Customer.DeletionIndicator,

      //  _StandardAddress.PostalCode,

      //  _StandardAddress.StreetName,

      //  _StandardAddress.HouseNumber,

      //  _StandardAddress.CityName,

      //  _StandardAddress.Country,

      //  _StandardAddress.Region,

      //  _StandardAddress.POBoxPostalCode,

      //  _StandardAddress.POBox,

      //

      //  _StandardAddress.CorrespondenceLanguage,

      //  _StandardAddress.PrfrdCommMediumType,


      Customer._AddressDefaultRepresentation.PostalCode,
      Customer._AddressDefaultRepresentation.StreetName,
      Customer._AddressDefaultRepresentation.HouseNumber,
      Customer._AddressDefaultRepresentation.CityName,
      Customer._AddressDefaultRepresentation.Country,
      Customer._AddressDefaultRepresentation.Region,
      Customer._AddressDefaultRepresentation.POBoxPostalCode,
      Customer._AddressDefaultRepresentation.POBox,

      Customer._AddressDefaultRepresentation.CorrespondenceLanguage,
      Customer._AddressDefaultRepresentation.PrfrdCommMediumType,
      Customer._CustomerClassification,
      Customer._CustomerClassificationText,
        
      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _BusinessPartner,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _BPAddlCustCompanyCode,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _BPAddlCustSalesArea,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _BPAddlCustTelNmbr,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _BPAddlCustFaxNumber,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _BPAddlCustMblPhNumber,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _BPAddlCustEmailAddress,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _BPAddlCustWebsiteURL
    
}
where
      IsStandardAssignment <> 'X'
  and BPAssignmentCategory =  'CUST'