I_AsstmtMdlMDGenerationError_2

@EndUserText.label: 'Error During Assortment Postprocessing'
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.usageType: {
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@VDM.viewType: #BASIC
define view entity I_AsstmtMdlMDGenerationError_2
  as select from rfm_asm_error2
    inner join   I_Product on  I_Product.Product             = rfm_asm_error2.article
                           and I_Product.IsMarkedForDeletion is initial

  association [1..1] to I_Product         as _Product   on $projection.Product = _Product.Product
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
  association [0..1] to I_Site            as _Site      on $projection.AssortmentModuleUser = _Site.SiteCustomer
  association [0..1] to I_UserContactCard as _Processor on _Processor.ContactCardID = $projection.Processor
{
  key rfm_asm_error2.asm_user           as AssortmentModuleUser,
  key rfm_asm_error2.article            as Product,
  key rfm_asm_error2.structured_article as ProductOfSuprordLstgCondition,
      rfm_asm_error2.message_id         as SystemMessageClass,
      rfm_asm_error2.message_number     as SystemMessageNumber,
      rfm_asm_error2.message_var1       as SystemMessageVariable1,
      rfm_asm_error2.message_var2       as SystemMessageVariable2,
      rfm_asm_error2.message_var3       as SystemMessageVariable3,
      rfm_asm_error2.message_var4       as SystemMessageVariable4,
      rfm_asm_error2.latest_md_gen_date as LatestMasterDataGenerationDate,
      rfm_asm_error2.processor          as Processor,
      rfm_asm_error2.last_changed_at    as LastChangeDateTime,
      rfm_asm_error2.md_gen_is_running  as MasterDataGenerationIsRunning,
      _Product,
      _Site,
      _Processor
}