I_AsstmtMdlMDGenerationError

@AbapCatalog.sqlViewName: 'IASSTMTMDLGENERR'
@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Error During Assortment Postprocessing'
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.usageType: {
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}
@VDM.viewType: #COMPOSITE
define view I_AsstmtMdlMDGenerationError
  as select from I_AsstmtMdlMDGenerationError_1 as rfm_asm_error
    inner join   I_Product on  I_Product.Product             = rfm_asm_error.Product
                           and I_Product.IsMarkedForDeletion is initial

  association [1..1] to I_Product         as _Product                       on $projection.Product = _Product.Product
  association [1..1] to I_Product         as _ProductOfSuprordLstgCondition on $projection.ProductOfSuprordLstgCondition = _ProductOfSuprordLstgCondition.Product
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
  association [0..1] to I_Site            as _Site                          on $projection.AssortmentModuleUser = _Site.SiteCustomer
  association [0..1] to I_UserContactCard as _Processor                     on _Processor.ContactCardID = $projection.Processor
{
  key rfm_asm_error.AssortmentModuleUser,
  key rfm_asm_error.Product,
  key rfm_asm_error.Product as ProductOfSuprordLstgCondition,
      rfm_asm_error.SystemMessageClass,
      rfm_asm_error.SystemMessageNumber,
      rfm_asm_error.SystemMessageVariable1,
      rfm_asm_error.SystemMessageVariable2,
      rfm_asm_error.SystemMessageVariable3,
      rfm_asm_error.SystemMessageVariable4,
      rfm_asm_error.LatestMasterDataGenerationDate,
      rfm_asm_error.Processor,
      rfm_asm_error.LastChangeDateTime,
      rfm_asm_error.MasterDataGenerationIsRunning,
      _Product,
      _Site,
      _Processor,
      _ProductOfSuprordLstgCondition
}
union all select distinct from I_AsstmtMdlMDGenerationError_2 as rfm_asm_error2
  inner join                   I_Product on  I_Product.Product             = rfm_asm_error2.Product
                                         and I_Product.IsMarkedForDeletion is initial

association [1..1] to I_Product         as _Product                       on $projection.Product = _Product.Product
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
association [0..1] to I_Site            as _Site                          on $projection.AssortmentModuleUser = _Site.SiteCustomer
association [0..1] to I_UserContactCard as _Processor                     on _Processor.ContactCardID = $projection.Processor
association [1..1] to I_Product         as _ProductOfSuprordLstgCondition on $projection.ProductOfSuprordLstgCondition = _ProductOfSuprordLstgCondition.Product

{
  key rfm_asm_error2.AssortmentModuleUser,
  key rfm_asm_error2.Product,
  key rfm_asm_error2.ProductOfSuprordLstgCondition,
      rfm_asm_error2.SystemMessageClass,
      rfm_asm_error2.SystemMessageNumber,
      rfm_asm_error2.SystemMessageVariable1,
      rfm_asm_error2.SystemMessageVariable2,
      rfm_asm_error2.SystemMessageVariable3,
      rfm_asm_error2.SystemMessageVariable4,
      rfm_asm_error2.LatestMasterDataGenerationDate,
      rfm_asm_error2.Processor,
      rfm_asm_error2.LastChangeDateTime,
      rfm_asm_error2.MasterDataGenerationIsRunning,
      _Product,
      _Site,
      _Processor,
      _ProductOfSuprordLstgCondition
}