I_AssetBalanceOverview

DDL: I_ASSETBALANCEOVERVIEW SQL: IASSETBALOVW Type: view COMPOSITE Package: ODATA_AA_ASSET_OVERVIEWPAGE

Asset Balance Overview

I_AssetBalanceOverview is a Composite CDS View that provides data about "Asset Balance Overview" in SAP S/4HANA. It reads from 1 data source (I_AssetBalanceCube) and exposes 38 fields with key fields CompanyCode, MasterFixedAsset, FixedAsset, AssetDepreciationArea, Ledger. Part of development package ODATA_AA_ASSET_OVERVIEWPAGE.

1 data source(s) 38 fields

Data Sources (1)

SourceAliasJoin Type
I_AssetBalanceCube I_AssetBalanceCube from

Parameters (5)

NameTypeDefault
P_TodayDate fagl_keydate
P_AssetAccountingKeyFigureSet faa_key_figure_set
P_FiscalYear fis_ryear
P_FiscalPeriod fis_poper
P_KeyDate fagl_keydate

Annotations (10)

NameValueLevelField
AbapCatalog.sqlViewName IASSETBALOVW view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #REQUIRED view
EndUserText.label Asset Balance Overview view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #COMPOSITE view
ClientHandling.algorithm #SESSION_VARIABLE view

Fields (38)

KeyFieldSource TableSource FieldDescription
KEY CompanyCode CompanyCode
KEY MasterFixedAsset MasterFixedAsset
KEY FixedAsset FixedAsset
KEY AssetDepreciationArea AssetDepreciationArea
KEY Ledger Ledger
KEY LedgerFiscalYear LedgerFiscalYear
KEY FiscalYear FiscalYear
KEY FiscalPeriod FiscalPeriod
KEY SubLedgerAcctLineItemType SubLedgerAcctLineItemType
KEY AssetAcctTransClassfctn AssetAcctTransClassfctn
KEY AssetAccountingKeyFigure AssetAccountingKeyFigure
KEY AssetAccountingKeyFigureSet AssetAccountingKeyFigureSet
KEY AccountingDocument AccountingDocument
KEY LedgerGLLineItem LedgerGLLineItem
KEY TransactionSubitem TransactionSubitem
KEY DebitCreditCode DebitCreditCode
KEY CurrencyRole CurrencyRole
SelectedCurrencyBranch SelectedCurrencyBranch
FiscalYearVariant FiscalYearVariant
ChartOfDepreciation ChartOfDepreciation
ControllingArea ControllingArea
AssetClass AssetClass
AssetAccountDetermination AssetAccountDetermination
AssetDeactivationDate AssetDeactivationDate
AssetCapitalizationDate AssetCapitalizationDate
AssetCountryOfOrigin
AssetSupplier Supplier
SupplierAccountGroup
SupplierBasicAuthorizationGrp
AssetCostCenter AssetCostCenter
AssetPlant AssetPlant
AssetProfitCenter AssetProfitCenter
AssetSegment AssetSegment
AssetUnderConstIsInvmtMsr _FixedAsset AssetUnderConstIsInvmtMsr
IsLineItemSettled _FixedAsset IsLineItemSettled
FixedAssetDescription _FixedAsset FixedAssetDescription
DisplayCurrency DisplayCurrency
NetBookValueAmtInDspCrcy AmountInDisplayCurrency 
@AbapCatalog.sqlViewName: 'IASSETBALOVW'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Asset Balance Overview'
@ObjectModel.usageType: {
  sizeCategory: #XL,
  serviceQuality: #D,
  dataClass: #MIXED
}
@VDM.viewType: #COMPOSITE
@ClientHandling.algorithm: #SESSION_VARIABLE

define view I_AssetBalanceOverview
  with parameters
    P_TodayDate                   : fagl_keydate,
    P_AssetAccountingKeyFigureSet : faa_key_figure_set,
    P_FiscalYear                  : fis_ryear,
    P_FiscalPeriod                : fis_poper,
    P_KeyDate                     : fagl_keydate
  as select from I_AssetBalanceCube( P_AssetAccountingKeyFigureSet: :P_AssetAccountingKeyFigureSet,
                                     P_FiscalYear:                  :P_FiscalYear,
                                     P_FiscalPeriod:                :P_FiscalPeriod,
                                     P_KeyDate:                     :P_KeyDate )
{
  key CompanyCode,
  key MasterFixedAsset,
  key FixedAsset,
  key AssetDepreciationArea,
  key Ledger,
  key LedgerFiscalYear,
  key FiscalYear,
  key FiscalPeriod,
  key SubLedgerAcctLineItemType,
  key AssetAcctTransClassfctn,
  key AssetAccountingKeyFigure,
  key AssetAccountingKeyFigureSet,
  key AccountingDocument,
  key LedgerGLLineItem,
  key TransactionSubitem,
  key DebitCreditCode,
  key CurrencyRole,

      @Environment.sql.passValue: true
      SelectedCurrencyBranch,

      FiscalYearVariant,
      ChartOfDepreciation,
      ControllingArea,

      /* Fields from Fixed Asset */
      AssetClass,
      AssetAccountDetermination,
      AssetDeactivationDate,
      AssetCapitalizationDate,
      cast(_FixedAsset.AssetCountryOfOrigin as faa_asset_cntry_of_origin) as AssetCountryOfOrigin,
      Supplier                                                            as AssetSupplier,
      _FixedAsset._Supplier.SupplierAccountGroup,
      _FixedAsset._Supplier.AuthorizationGroup                            as SupplierBasicAuthorizationGrp,

      /* Fields from Fixed Asset (Time-Dependent Data) */
      AssetCostCenter,
      AssetPlant,
      AssetProfitCenter,
      AssetSegment,

      /* Fixed Asset Under Construction */
      _FixedAsset.AssetUnderConstIsInvmtMsr,
      _FixedAsset.IsLineItemSettled,

      /* Text Fields */
      _FixedAsset.FixedAssetDescription,

      /* Amounts */
      @Semantics.currencyCode: true
      DisplayCurrency,

      @Semantics.amount.currencyCode: 'DisplayCurrency'
      AmountInDisplayCurrency                                             as NetBookValueAmtInDspCrcy
}
where
  AssetAccountingKeyFigure = '0010790401' // Net Book Value at Reporting Date, Planned - "KeyFigure" - see view FAAV_KFCSET_SPEC

Learn More