I_ASSETBALANCECUBE
Asset Balances - Cube
I_ASSETBALANCECUBE is a CDS View in S/4HANA. Asset Balances - Cube. It contains 3 fields. 33 CDS views read from this table.
CDS Views using this table (33)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_AssetBalance | view | from | CONSUMPTION | Asset Balances |
| C_AT_StRpAuditAssetTransacQ | view | from | CONSUMPTION | Austrian Audit Asset Transaction Query |
| C_BG_StRpTaxDeprTransCube | view | from | CONSUMPTION | Tax depreciation plan trans - Cube |
| C_GB_StRpFxdAstRevalRsrvCube | view | from | CONSUMPTION | GB Asset Revaluation Reserves - Cube |
| C_LU_StRpFxdAstApndxAcqnCube | view | from | CONSUMPTION | Fixed Ast Appendix Acquisitions - Cube |
| C_LU_StRpFxdAstApndxDeprCube | view | from | CONSUMPTION | Fixed Ast Appendix Depreciation - Cube |
| C_PL_SAFTFixedAssetValueCube | view_entity | from | CONSUMPTION | PL SAFT Fixed Asset Values - Cube |
| C_RO_SAFTFixedAssetCube | view | inner | CONSUMPTION | RO SAFT Fixed Asset - Cube |
| C_RO_SAFTFixedAssetTransCube | view | from | CONSUMPTION | RO SAFT Fixed Asset Transaction - Cube |
| C_StRpFxdAssetAcquisitionFormC | view | from | CONSUMPTION | Fixed Asset Acquisition Form Cube |
| C_StRpFxdAssetLocTransferFormC | view | inner | CONSUMPTION | Fixed Asset Location Transfer Form Cube |
| C_StRpFxdAstRetirementFormCube | view | from | CONSUMPTION | Fixed Asset Retirement Form Cube |
| I_AssetBalanceOverview | view | from | COMPOSITE | Asset Balance Overview |
| I_AstDeprValInCurPeriod | view | from | COMPOSITE | Asset Depreciation Value In Current Period |
| I_AstPlndDeprInCurPeriod | view | from | COMPOSITE | Asset Planned Depreciation In Current Period |
| I_CN_CADEFixedAssetValueCube | view | left_outer | COMPOSITE | Fixed Asset Balance Cube for CADE |
| I_IL_AssetBalanceCube | view_entity | from | COMPOSITE | IL AA Depreciation for Statutory Reporting - Cube |
| I_IL_SumPostdDeprAmtPerAstC | view_entity | from | COMPOSITE | IL AA Posted Depreciation Amount of KFC 0007700500 - Cube |
| I_SG_CapitalAllowanceCube | view | from | COMPOSITE | Singapore CA Report - Cube |
| I_TH_AssetDepreciationCube | view | from | COMPOSITE | Cube View for Thailand Depreciation List |
| P_AssetBalanceOverview | view | from | COMPOSITE | Asset Balance Overview |
| P_AssetBalancesYrOvrYrComprn | view_entity | from | COMPOSITE | Analytical Query for Asset Balances Review Booklet YoY Comp |
| P_AstBalDeprOvrDeprComprn | view_entity | from | COMPOSITE | Analytical Query for Asset Balances Review Booklet DoD Comp |
| P_AstPlndDeprInCurPeriod | view | from | COMPOSITE | Asset Planned Depreciation In Current Period |
| P_AT_AssetBalanceCube | view_entity | from | CONSUMPTION | Austria : Asset Balance Cube |
| P_AUDIT_AT_AstTransByKeyFigs | view | from | COMPOSITE | Austrian Audit Asset Transaction by Key Figures |
| P_BG_StRpFixedAssetReport | view | from | CONSUMPTION | Fixed Asset Report - Fixed Asset Fields |
| P_BG_StRpTaxDeprValue | view | from | CONSUMPTION | Tax depreciation plan values |
| P_JP_FIXEDASSETVALUE | view | from | CONSUMPTION | Summarization of Company code Currency |
| P_PE_AssetValuationAggrgd | view_entity | from | CONSUMPTION | Asset Valuation Aggregated for Peru Reporting |
| P_PL_SAFTAssetRetirement10 | view_entity | from | CONSUMPTION | PL SAFT Asset Retirement, level 10 |
| P_RS_TaxGroupDepreciation | view | inner | COMPOSITE | RS Tax Group Depreciation |
| P_RS_TaxIndivDeprKeyFigure | view | inner | COMPOSITE | RS Tax Indiv Depr - Key Figures |
Fields (3)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| AcquisitionValueDate | AcquisitionValueDate | 1 | |
| AssetCapitalizationDate | AssetCapitalizationDate | 1 | |
| AssetDeactivationDate | AssetDeactivationDate | 1 |
@AccessControl.auditFilter: #ENABLED
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@Analytics: { dataCategory: #CUBE, internalName: #LOCAL }
@EndUserText.label: 'Asset Balances - Cube'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@ObjectModel: { usageType.serviceQuality: #D,
usageType.sizeCategory: #XXL,
usageType.dataClass: #MIXED,
supportedCapabilities: [ #ANALYTICAL_PROVIDER, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE ],
modelingPattern: #ANALYTICAL_CUBE }
@Metadata: {ignorePropagatedAnnotations: true, allowExtensions:true}
@Consumption.dbHints: [ 'JOIN_THRU_AGGR', 'USE_HEX_PLAN' ]
define view entity I_AssetBalanceCube
with parameters
P_AssetAccountingKeyFigureSet : faa_key_figure_set,
P_FiscalYear : fis_gjahr,
P_FiscalPeriod : fis_poper,
P_KeyDate : fagl_keydate
as select from P_AssetBalanceCube1( P_AssetAccountingKeyFigureSet: $parameters.P_AssetAccountingKeyFigureSet, P_FiscalYear: $parameters.P_FiscalYear, P_FiscalPeriod: $parameters.P_FiscalPeriod )
left outer to one join I_FixedAsset as FixedAsset on FixedAsset.CompanyCode = P_AssetBalanceCube1.CompanyCode
and FixedAsset.MasterFixedAsset = P_AssetBalanceCube1.MasterFixedAsset
and FixedAsset.FixedAsset = P_AssetBalanceCube1.FixedAsset
association [1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [1] to I_FixedAsset as _FixedAsset on $projection.CompanyCode = _FixedAsset.CompanyCode
and $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
and $projection.FixedAsset = _FixedAsset.FixedAsset
association [0..1] to I_MasterFixedAsset as _MasterFixedAsset on $projection.CompanyCode = _MasterFixedAsset.CompanyCode
and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset
association [0..1] to I_FixedAssetCountryData as _FixedAssetCountryData on $projection.CompanyCode = _FixedAssetCountryData.CompanyCode
and $projection.MasterFixedAsset = _FixedAssetCountryData.MasterFixedAsset
and $projection.FixedAsset = _FixedAssetCountryData.FixedAsset
association [0..1] to I_FixedAssetGroup as _FixedAssetGroup on $projection.FixedAssetGroup = _FixedAssetGroup.FixedAssetGroup
association [0..1] to I_InternalOrder as _InvestmentOrder on $projection.InvestmentOrder = _InvestmentOrder.InternalOrder
association [0..1] to I_Group1AssetEvaluationKey as _Group1AssetEvaluationKey on $projection.Group1AssetEvaluationKey = _Group1AssetEvaluationKey.Group1AssetEvaluationKey
association [0..1] to I_Group2AssetEvaluationKey as _Group2AssetEvaluationKey on $projection.Group2AssetEvaluationKey = _Group2AssetEvaluationKey.Group2AssetEvaluationKey
association [0..1] to I_Group3AssetEvaluationKey as _Group3AssetEvaluationKey on $projection.Group3AssetEvaluationKey = _Group3AssetEvaluationKey.Group3AssetEvaluationKey
association [0..1] to I_Group4AssetEvaluationKey as _Group4AssetEvaluationKey on $projection.Group4AssetEvaluationKey = _Group4AssetEvaluationKey.Group4AssetEvaluationKey
association [0..1] to I_Group5AssetEvaluationKey as _Group5AssetEvaluationKey on $projection.Group5AssetEvaluationKey = _Group5AssetEvaluationKey.Group5AssetEvaluationKey
association [0..1] to I_UnitOfMeasure as _UnitOfMeasure on $projection.BaseUnit = _UnitOfMeasure.UnitOfMeasure
association [0..1] to I_LedgerGroup as _LedgerGroup on $projection.LedgerGroup = _LedgerGroup.LedgerGroup
association [0..1] to I_AssetKeyFigure as _AssetKeyFigure on $projection.AssetAccountingKeyFigure = _AssetKeyFigure.AssetAccountingKeyFigure
association [0..1] to I_AssetKeyFigureSet as _AssetKeyFigureSet on $projection.AssetAccountingKeyFigureSet = _AssetKeyFigureSet.AssetAccountingKeyFigureSet
association [1] to I_AssetSortedKeyFigureSetSpec as _AssetSortedKeyFigureSetSpec on $projection.AssetAccountingKeyFigureSet = _AssetSortedKeyFigureSetSpec.AssetAccountingKeyFigureSet
and $projection.AssetAccountingSortedKeyFigure = _AssetSortedKeyFigureSetSpec.AssetAccountingSortedKeyFigure
association [0..1] to I_DepreciationAreaForLedger as _DepreciationArea on $projection.CompanyCode = _DepreciationArea.CompanyCode
and $projection.Ledger = _DepreciationArea.Ledger
and $projection.AssetDepreciationArea = _DepreciationArea.AssetDepreciationArea
association [0..1] to I_Ledger as _Ledger on $projection.Ledger = _Ledger.Ledger
association [0..1] to I_SubLedgerAccLineItemType as _SubLedgerAccLineItemType on $projection.SubLedgerAcctLineItemType = _SubLedgerAccLineItemType.SubLedgerAcctLineItemType
association [0..1] to I_MovementCategory as _AssetAcctTransClassfctn on $projection.AssetAcctTransClassfctn = _AssetAcctTransClassfctn.AssetAcctTransClassfctn
association [0..1] to I_ChartOfDepreciation as _ChartOfDepreciation on $projection.ChartOfDepreciation = _ChartOfDepreciation.ChartOfDepreciation
association [0..1] to I_AssetClass as _AssetClass on $projection.AssetClass = _AssetClass.AssetClass
association [0..1] to I_AssetAcctDetermination as _AssetAccountDetermination on $projection.AssetAccountDetermination = _AssetAccountDetermination.AssetAccountDetermination
association [0..1] to I_ControllingArea as _ControllingArea on $projection.ControllingArea = _ControllingArea.ControllingArea
association [0..1] to I_FinancialAccountType as _FinancialAccountType on $projection.FinancialAccountType = _FinancialAccountType.FinancialAccountType
association [1] to I_AccountingPrinciple as _AccountingPrinciple on $projection.AccountingPrinciple = _AccountingPrinciple.AccountingPrinciple
association [0..1] to I_AssetTransactionType as _AssetTransactionType on $projection.AssetTransactionType = _AssetTransactionType.AssetTransactionType
association [0..1] to I_BusinessTransactionCategory as _BusinessTransactionCategory on $projection.BusinessTransactionCategory = _BusinessTransactionCategory.BusinessTransactionCategory
association [0..1] to I_BusinessTransactionType as _BusinessTransactionType on $projection.BusinessTransactionType = _BusinessTransactionType.BusinessTransactionType
association [0..*] to I_CostCenter as _CostCenter on $projection.CostCenter = _CostCenter.CostCenter
and $projection.ControllingArea = _CostCenter.ControllingArea
association [0..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [0..1] to I_BusinessArea as _BusinessArea on $projection.BusinessArea = _BusinessArea.BusinessArea
association [0..*] to I_ProfitCenter as _ProfitCenter on $projection.ProfitCenter = _ProfitCenter.ProfitCenter
and $projection.ControllingArea = _ProfitCenter.ControllingArea
association [0..1] to I_Segment as _Segment on $projection.Segment = _Segment.Segment
association [0..1] to I_FunctionalArea as _FunctionalArea on $projection.FunctionalArea = _FunctionalArea.FunctionalArea
association [0..1] to I_JournalEntry as _JournalEntry on $projection.CompanyCode = _JournalEntry.CompanyCode
and $projection.FiscalYear = _JournalEntry.FiscalYear
and $projection.AccountingDocument = _JournalEntry.AccountingDocument
association [0..*] to I_CostCenter as _AssetCostCenter on $projection.ControllingArea = _AssetCostCenter.ControllingArea
and $projection.AssetCostCenter = _AssetCostCenter.CostCenter
association [0..*] to I_CostCenterActivityType as _AssetCostCenterActivityType on $projection.AssetCostCtrActivityType = _AssetCostCenterActivityType.CostCtrActivityType
and $projection.ControllingArea = _AssetCostCenterActivityType.ControllingArea
association [0..1] to I_WBSElementBasicData as _AssetWBSElement on $projection.AssetWBSElementInternalID = _AssetWBSElement.WBSElementInternalID
association [0..1] to I_BusinessArea as _AssetBusinessArea on $projection.AssetBusinessArea = _AssetBusinessArea.BusinessArea
association [0..*] to I_ProfitCenter as _AssetProfitCenter on $projection.AssetProfitCenter = _AssetProfitCenter.ProfitCenter
and $projection.ControllingArea = _AssetProfitCenter.ControllingArea
association [0..1] to I_FunctionalArea as _AssetFunctionalArea on $projection.AssetFunctionalArea = _AssetFunctionalArea.FunctionalArea
association [0..1] to I_Segment as _AssetSegment on $projection.AssetSegment = _AssetSegment.Segment
association [0..1] to I_Location as _AssetLocation on $projection.assetlocation = _AssetLocation.Location
and $projection.AssetPlant = _AssetLocation.Plant
association [0..1] to I_Plant as _AssetPlant on $projection.AssetPlant = _AssetPlant.Plant
association [0..1] to I_REObjectByIntFinNumber as _AssetRealEstateObject on $projection.reinternalfinnumber = _AssetRealEstateObject.REInternalFinNumber
association [0..1] to I_DepreciationKey as _DepreciationKey on $projection.ChartOfDepreciation = _DepreciationKey.ChartOfDepreciation
and $projection.depreciationkey = _DepreciationKey.DepreciationKey
association [0..1] to I_FixedAssetUsageObject as _FixedAssetUsageObject on $projection.CompanyCode = _FixedAssetUsageObject.CompanyCode
and $projection.fixedassetusageobject = _FixedAssetUsageObject.FixedAssetUsageObject
association [0..1] to I_AssetRevaluationIndex as _AssetRevaluationIndex on $projection.assetrevaluationindex = _AssetRevaluationIndex.AssetRevaluationIndex
association [0..1] to I_InvestmentSupportMeasure as _InvestmentSupportMeasure on $projection.ChartOfDepreciation = _InvestmentSupportMeasure.ChartOfDepreciation
and $projection.investmentsupportmeasure = _InvestmentSupportMeasure.InvestmentSupportMeasure
association [0..1] to I_ChartOfAccounts as _ChartOfAccounts on $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts
association [0..1] to I_ChartOfAccounts as _CountryChartOfAccounts on $projection.CountryChartOfAccounts = _CountryChartOfAccounts.ChartOfAccounts
association [0..1] to I_GLAccountInChartOfAccounts as _GLAccountInChartOfAccounts on $projection.ChartOfAccounts = _GLAccountInChartOfAccounts.ChartOfAccounts
and $projection.GLAccount = _GLAccountInChartOfAccounts.GLAccount
association [0..1] to I_GLAccountInChartOfAccounts as _AlternativeGLAccount on $projection.CountryChartOfAccounts = _AlternativeGLAccount.ChartOfAccounts
and $projection.AlternativeGLAccount = _AlternativeGLAccount.GLAccount
association [0..1] to I_GLAccountInChartOfAccounts as _AcqnProdnCostGLAccount on $projection.ChartOfAccounts = _AcqnProdnCostGLAccount.ChartOfAccounts
and $projection.acqnprodncostglaccount = _AcqnProdnCostGLAccount.GLAccount
association [0..1] to I_AssetBalanceSheetAccount as _BalanceSheetAccount on $projection.CompanyCode = _BalanceSheetAccount.CompanyCode
and $projection.AssetAccountDetermination = _BalanceSheetAccount.AssetAccountDetermination
and $projection.AssetDepreciationArea = _BalanceSheetAccount.AssetRealDepreciationArea
association [0..1] to I_Supplier as _Supplier on $projection.Supplier = _Supplier.Supplier
association [0..1] to I_Currency as _Currency on $projection.DisplayCurrency = _Currency.Currency
association [0..1] to I_CurrencyRole as _CurrencyRole on $projection.CurrencyRole = _CurrencyRole.CurrencyRole
association [0..1] to I_SelectedCurrencyBranch as _SelectedCurrencyBranch on $projection.SelectedCurrencyBranch = _SelectedCurrencyBranch.SelectedCurrencyBranch
association [0..1] to I_FiscalYearForCompanyCode as _FiscalYear on $projection.FiscalYear = _FiscalYear.FiscalYear
and $projection.CompanyCode = _FiscalYear.CompanyCode
association [1..1] to I_FiscalYearVariant as _FiscalYearVariant on $projection.FiscalYearVariant = _FiscalYearVariant.FiscalYearVariant
association [0..1] to I_FiscalPeriodForVariant as _FiscalPeriodForVariant on $projection.LedgerFiscalYear = _FiscalPeriodForVariant.FiscalYear
and $projection.FiscalPeriod = _FiscalPeriodForVariant.FiscalPeriod
and $projection.FiscalYearVariant = _FiscalPeriodForVariant.FiscalYearVariant
association [0..1] to I_FinancialManagementArea as _FinancialManagementArea on $projection.FinancialManagementArea = _FinancialManagementArea.FinancialManagementArea
association [0..1] to I_Fund as _Fund on $projection.FinancialManagementArea = _Fund.FinancialManagementArea
and $projection.Fund = _Fund.Fund
association [0..1] to I_BudgetPeriod as _BudgetPeriod on $projection.BudgetPeriod = _BudgetPeriod.BudgetPeriod
association [0..1] to I_WBSElementBasicData as _WBSElement on $projection.WBSElementInternalID = _WBSElement.WBSElementInternalID
association [0..1] to I_WBSElementBasicData as _WBSElement_2 on $projection.WBSElementInternalID_2 = _WBSElement_2.WBSElementInternalID
association [0..1] to I_FixedAssetNatlClfn as _FixedAssetNatlClfn on $projection.Country = _FixedAssetNatlClfn.Country
and $projection.nationalclassification = _FixedAssetNatlClfn.NationalClassification
association [0..1] to I_TaxDepreciationGroup as _TaxDepreciationGroup on $projection.Country = _TaxDepreciationGroup.Country
and $projection.taxdepreciationgroup = _TaxDepreciationGroup.TaxDepreciationGroup
association [0..1] to I_Country as _Country on $projection.Country = _Country.Country
association [0..1] to I_AccountingDocumentType as _AccountingDocumentType on $projection.AccountingDocumentType = _AccountingDocumentType.AccountingDocumentType
association [0..1] to I_JP_PrptyTxRptCity as _JP_PrptyTxRptCity on $projection.jp_prptytxrptcity = _JP_PrptyTxRptCity.JP_PrptyTxRptCity
association [0..1] to I_JP_PrptyTxRptClassfctnKey as _JP_PrptyTxRptClassfctnKey on $projection.jp_prptytxrptclassfctnkey = _JP_PrptyTxRptClassfctnKey.JP_PrptyTxRptClassfctnKey
association [0..1] to I_RU_AssetDepreciationGroup as _RU_AssetDepreciationGroup on $projection.ru_assetdepreciationgroup = _RU_AssetDepreciationGroup.RU_AssetDepreciationGroup
and $projection.Country = _RU_AssetDepreciationGroup.Country
and $projection.ru_assetokof = _RU_AssetDepreciationGroup.RU_AssetOKOF
association [0..1] to I_RU_AssetOKOF as _RU_AssetOKOF on $projection.ru_assetokof = _RU_AssetOKOF.RU_AssetOKOF
and $projection.Country = _RU_AssetOKOF.Country
association [1] to I_AssetRedesignSwitchStatus as _AssetRedesignSwitchStatus on _AssetRedesignSwitchStatus.AssetRedesignSwitchIsActive = ''
or _AssetRedesignSwitchStatus.AssetRedesignSwitchIsActive = 'X'
association [0..1] to I_FixedAssetForLedger as _FixedAssetForLedger on $projection.CompanyCode = _FixedAssetForLedger.CompanyCode
and $projection.MasterFixedAsset = _FixedAssetForLedger.MasterFixedAsset
and $projection.FixedAsset = _FixedAssetForLedger.FixedAsset
and $projection.Ledger = _FixedAssetForLedger.Ledger
association [0..1] to I_FixedAssetAssgmt as _FixedAssetAssgmt on _FixedAssetAssgmt.CompanyCode = $projection.CompanyCode
and _FixedAssetAssgmt.MasterFixedAsset = $projection.MasterFixedAsset
and _FixedAssetAssgmt.FixedAsset = $projection.FixedAsset
and _FixedAssetAssgmt.ValidityStartDate <= $parameters.P_KeyDate
and _FixedAssetAssgmt.ValidityEndDate >= $parameters.P_KeyDate
association [0..1] to I_AssetValuationForLedger as _AssetValuationForLedger on _AssetValuationForLedger.CompanyCode = $projection.CompanyCode
and _AssetValuationForLedger.MasterFixedAsset = $projection.MasterFixedAsset
and _AssetValuationForLedger.FixedAsset = $projection.FixedAsset
and _AssetValuationForLedger.Ledger = $projection.Ledger
and _AssetValuationForLedger.AssetRealDepreciationArea = $projection.AssetDepreciationArea
and _AssetValuationForLedger.ValidityStartDate <= $parameters.P_KeyDate
and _AssetValuationForLedger.ValidityEndDate >= $parameters.P_KeyDate
association [0..1] to I_GlobAssetAssignment as _GlobAssetAssignment on _GlobAssetAssignment.CompanyCode = $projection.CompanyCode
and _GlobAssetAssignment.MasterFixedAsset = $projection.MasterFixedAsset
and _GlobAssetAssignment.FixedAsset = $projection.FixedAsset
and _GlobAssetAssignment.ValidityStartDate <= $parameters.P_KeyDate
and _GlobAssetAssignment.ValidityEndDate >= $parameters.P_KeyDate
// Association to Extension View
association [1..1] to E_FixedAsset as _Extension on $projection.MasterFixedAsset = _Extension.MasterFixedAsset
and $projection.FixedAsset = _Extension.FixedAsset
and $projection.CompanyCode = _Extension.CompanyCode
association [0..1] to I_AssetBalanceDSt as _DocumentStore on _DocumentStore.tra_companycode = $projection.CompanyCode
and _DocumentStore.tra_00008 = $projection.AssetDepreciationArea
and _DocumentStore.tra_p_fiscalyear = $projection.FiscalYear
and _DocumentStore.tra_fiscalperiod = $projection.FiscalPeriod
and _DocumentStore.tra_00009 = $projection.AssetAccountingKeyFigureSet
and _DocumentStore.tra_00012 = $projection.AssetAccountingKeyFigure
and _DocumentStore.tra_00011 = $projection.AccountingDocument
and _DocumentStore.tra_00016 = $projection.MasterFixedAsset
and _DocumentStore.tra_fixedasset = $projection.FixedAsset
and _DocumentStore.tra_00080 = $projection.SubLedgerAcctLineItemType
and _DocumentStore.tra_00045 = $projection.AssetAcctTransClassfctn
and _DocumentStore.tra_00006 = $projection.LedgerGLLineItem
and _DocumentStore.tra_00015 = $projection.TransactionSubitem
and _DocumentStore.tra_ledger = $projection.Ledger
and _DocumentStore.tra_00097 = $projection.DebitCreditCode
and _DocumentStore.tra_currencyrole = $projection.CurrencyRole
{
@ObjectModel.foreignKey.association: '_CompanyCode'
key P_AssetBalanceCube1.CompanyCode,
@ObjectModel.foreignKey.association: '_DepreciationArea'
key P_AssetBalanceCube1.AssetDepreciationArea,
@ObjectModel.foreignKey.association: '_MasterFixedAsset'
key P_AssetBalanceCube1.MasterFixedAsset,
@ObjectModel.foreignKey.association: '_FixedAsset'
key P_AssetBalanceCube1.FixedAsset,
@ObjectModel.foreignKey.association: '_Ledger'
key P_AssetBalanceCube1.Ledger,
@ObjectModel.foreignKey.association: '_FiscalYear'
key P_AssetBalanceCube1.FiscalYear,
@ObjectModel.foreignKey.association: '_FiscalPeriodForVariant'
@Semantics.fiscal.period: true
key P_AssetBalanceCube1.FiscalPeriod,
@ObjectModel.foreignKey.association: '_SubledgerAccLineItemType'
key P_AssetBalanceCube1.SubLedgerAcctLineItemType,
@ObjectModel.foreignKey.association: '_AssetAcctTransClassfctn'
key P_AssetBalanceCube1.AssetAcctTransClassfctn,
@ObjectModel.foreignKey.association: '_AssetKeyFigure'
key P_AssetBalanceCube1.AssetAccountingKeyFigure,
@ObjectModel.foreignKey.association: '_AssetKeyFigureSet'
key P_AssetBalanceCube1.AssetAccountingKeyFigureSet,
@ObjectModel.foreignKey.association: '_JournalEntry'
key P_AssetBalanceCube1.AccountingDocument,
key P_AssetBalanceCube1.LedgerGLLineItem,
key P_AssetBalanceCube1.TransactionSubitem,
key P_AssetBalanceCube1.DebitCreditCode,
@ObjectModel.foreignKey.association: '_CurrencyRole'
key P_AssetBalanceCube1.CurrencyRole,
@Semantics.fiscal.year: true
@ObjectModel.foreignKey.association: null
P_AssetBalanceCube1.LedgerFiscalYear,
@ObjectModel.foreignKey.association: '_FiscalYearVariant'
@Semantics.fiscal.yearVariant: true
P_AssetBalanceCube1.FiscalYearVariant,
@Semantics.fiscal.yearPeriod: true
P_AssetBalanceCube1.FiscalYearPeriod,
P_AssetBalanceCube1.DepreciationFiscalPeriod,
P_AssetBalanceCube1.PostingDate,
@ObjectModel.foreignKey.association: '_AssetSortedKeyFigureSetSpec'
P_AssetBalanceCube1.AssetAccountingSortedKeyFigure,
@VDM.lifecycle: {status: #DEPRECATED}
@ObjectModel.foreignKey.association: '_LedgerGroup'
P_AssetBalanceCube1.LedgerGroup,
@ObjectModel.foreignKey.association: '_ChartOfAccounts'
P_AssetBalanceCube1.ChartOfAccounts,
@ObjectModel.foreignKey.association: '_AcqnProdnCostGLAccount'
_BalanceSheetAccount.AcqnProdnCostGLAccount,
@ObjectModel.foreignKey.association: '_GLAccountInChartOfAccounts'
P_AssetBalanceCube1.GLAccount,
@ObjectModel.foreignKey.association: '_AlternativeGLAccount'
P_AssetBalanceCube1.AlternativeGLAccount,
P_AssetBalanceCube1.GroupMasterFixedAsset,
P_AssetBalanceCube1.GroupFixedAsset,
@ObjectModel.foreignKey.association: '_FinancialAccountType'
P_AssetBalanceCube1.FinancialAccountType,
@Semantics.businessDate.at: true
P_AssetBalanceCube1.AccountingDocumentCreationDate,
P_AssetBalanceCube1.CreationTime,
P_AssetBalanceCube1.JointVentureCostRecoveryCode,
@ObjectModel.foreignKey.association: '_ChartOfDepreciation'
P_AssetBalanceCube1.ChartOfDepreciation,
@ObjectModel.foreignKey.association: '_CostCenter'
P_AssetBalanceCube1.CostCenter,
@ObjectModel.foreignKey.association: '_Plant'
P_AssetBalanceCube1.Plant,
@ObjectModel.foreignKey.association: '_BusinessArea'
P_AssetBalanceCube1.BusinessArea,
P_AssetBalanceCube1.PersonnelNumber,
@ObjectModel.foreignKey.association: '_FinancialManagementArea'
P_AssetBalanceCube1.FinancialManagementArea,
@ObjectModel.foreignKey.association: '_Fund'
P_AssetBalanceCube1.Fund,
P_AssetBalanceCube1.GrantID,
@ObjectModel.foreignKey.association: '_FunctionalArea'
P_AssetBalanceCube1.FunctionalArea,
@ObjectModel.foreignKey.association: '_BudgetPeriod'
P_AssetBalanceCube1.BudgetPeriod,
@ObjectModel.foreignKey.association: '_ProfitCenter'
P_AssetBalanceCube1.ProfitCenter,
@ObjectModel.foreignKey.association: '_Segment'
P_AssetBalanceCube1.Segment,
P_AssetBalanceCube1.FundsCenter,
@ObjectModel.foreignKey.association: '_AssetTransactionType'
P_AssetBalanceCube1.AssetTransactionType,
@ObjectModel.foreignKey.association: '_BusinessTransactionCategory'
P_AssetBalanceCube1.BusinessTransactionCategory,
@ObjectModel.foreignKey.association: '_BusinessTransactionType'
P_AssetBalanceCube1.BusinessTransactionType,
P_AssetBalanceCube1.FinancialClosingStep,
@ObjectModel.foreignKey.association: '_Country'
P_AssetBalanceCube1.Country,
@ObjectModel.foreignKey.association: '_ControllingArea'
P_AssetBalanceCube1.ControllingArea,
@ObjectModel.foreignKey.association: '_CountryChartOfAccounts'
P_AssetBalanceCube1.CountryChartOfAccounts,
P_AssetBalanceCube1.FinancialStatementVariant,
@ObjectModel.foreignKey.association: '_AccountingPrinciple'
P_AssetBalanceCube1.AccountingPrinciple,
P_AssetBalanceCube1.AssetValueDate,
P_AssetBalanceCube1.ReferenceDocument,
P_AssetBalanceCube1.ReferenceDocumentItem,
P_AssetBalanceCube1.IsReversal,
P_AssetBalanceCube1.IsReversed,
P_AssetBalanceCube1.DocumentDate,
@ObjectModel.foreignKey.association: '_AccountingDocumentType'
P_AssetBalanceCube1.AccountingDocumentType,
P_AssetBalanceCube1.DocumentItemText,
P_AssetBalanceCube1.AssignmentReference,
P_AssetBalanceCube1.GLBusinessTransactionType,
P_AssetBalanceCube1.LogicalSystem,
@Consumption.hidden: true
P_AssetBalanceCube1.PartnerCompanyCode,
P_AssetBalanceCube1.PartnerMasterFixedAsset,
P_AssetBalanceCube1.PartnerFixedAsset,
P_AssetBalanceCube1.ReferenceDocumentContext,
P_AssetBalanceCube1.ReferenceDocumentType,
@ObjectModel.foreignKey.association: '_SelectedCurrencyBranch'
@Environment.sql.passValue : true
P_AssetBalanceCube1.SelectedCurrencyBranch,
P_AssetBalanceCube1.DisplayCurrency,
@DefaultAggregation:#SUM
@Semantics.amount.currencyCode: 'DisplayCurrency'
P_AssetBalanceCube1.AmountInDisplayCurrency,
@ObjectModel.foreignKey.association: '_UnitOfMeasure'
FixedAsset.BaseUnit,
@VDM.lifecycle: {status: #DEPRECATED}
@DefaultAggregation: #SUM
@Semantics: { quantity : {unitOfMeasure: 'BaseUnit'} }
P_AssetBalanceCube1.Quantity,
/* Fields from Fixed Asset */
@ObjectModel.foreignKey.association: '_AssetAccountDetermination'
FixedAsset.AssetAccountDetermination,
@ObjectModel.foreignKey.association: '_AssetClass'
FixedAsset.AssetClass,
_FixedAssetForLedger.AssetCapitalizationDate,
_FixedAssetForLedger.FirstAcquisitionFiscalYear,
_FixedAssetForLedger.FirstAcquisitionFiscalPeriod,
_FixedAssetForLedger.AssetDeactivationDate,
_FixedAssetForLedger.AcquisitionValueDate,
@ObjectModel.foreignKey.association: '_FixedAssetGroup'
FixedAsset.FixedAssetGroup,
@ObjectModel.foreignKey.association: '_Supplier'
FixedAsset.Supplier,
@VDM.lifecycle: {status: #DEPRECATED}
FixedAsset.AssetSupplierName,
@ObjectModel.foreignKey.association: '_InvestmentOrder'
FixedAsset.InvestmentOrder,
FixedAsset.InventoryIsCounted,
FixedAsset.LastInventoryDate,
FixedAsset.Inventory,
@ObjectModel.foreignKey.association: '_Group1AssetEvaluationKey'
@VDM.lifecycle: {status: #DEPRECATED}
FixedAsset.Group1AssetEvaluationKey,
@ObjectModel.foreignKey.association: '_Group2AssetEvaluationKey'
@VDM.lifecycle: {status: #DEPRECATED}
FixedAsset.Group2AssetEvaluationKey,
@ObjectModel.foreignKey.association: '_Group3AssetEvaluationKey'
@VDM.lifecycle: {status: #DEPRECATED}
FixedAsset.Group3AssetEvaluationKey,
@ObjectModel.foreignKey.association: '_Group4AssetEvaluationKey'
@VDM.lifecycle: {status: #DEPRECATED}
FixedAsset.Group4AssetEvaluationKey,
@ObjectModel.foreignKey.association: '_Group5AssetEvaluationKey'
@VDM.lifecycle: {status: #DEPRECATED}
FixedAsset.Group5AssetEvaluationKey,
FixedAsset.AssetSerialNumber,
@Analytics.internalName: #LOCAL
FixedAsset.InvestmentProjectWBSElement_2 as WBSElementInternalID_2,
@API.element.releaseState: #DEPRECATED
@API.element.successor: 'WBSElementInternalID_2'
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'WBSElementInternalID_2'
@Analytics.internalName: #LOCAL
FixedAsset.InvestmentProjectWBSElement as WBSElementInternalID,
@Semantics.text
cast(FixedAsset.AssetAdditionalDescription as fis_txa50_more) as AssetAdditionalDescription,
@Consumption.hidden: true
@VDM.lifecycle: {status: #DEPRECATED}
_FixedAsset.AssetAuthorizationContext,
/* Fields from Fixed Asset (Time-Dependent Data) */
@ObjectModel.foreignKey.association: '_AssetCostCenter'
cast(_FixedAssetAssgmt.CostCenter as faa_kostl) as AssetCostCenter,
@ObjectModel.foreignKey.association: '_AssetWBSElement'
cast(_FixedAssetAssgmt.WBSElementInternalID_2 as faa_wbs_element_int ) as AssetWBSElementInternalID,
@ObjectModel.foreignKey.association: '_AssetBusinessArea'
cast(_FixedAssetAssgmt.BusinessArea as faa_gsber) as AssetBusinessArea,
cast(_FixedAssetAssgmt.Fund as faa_bp_geber) as AssetFund,
@ObjectModel.foreignKey.association: '_AssetProfitCenter'
cast(_FixedAssetAssgmt.ProfitCenter as faa_prctr) as AssetProfitCenter,
@ObjectModel.foreignKey.association: '_AssetSegment'
cast(_FixedAssetAssgmt.Segment as faa_fb_segment) as AssetSegment,
@ObjectModel.foreignKey.association: '_AssetPlant'
cast(_FixedAssetAssgmt.Plant as faa_werks) as AssetPlant,
cast(_FixedAssetAssgmt.BudgetPeriod as faa_budget_period) as AssetBudgetPeriod,
cast(_FixedAssetAssgmt.GrantID as faa_gm_grant_nbr) as AssetGrant,
@ObjectModel.foreignKey.association: '_AssetCostCenterActivityType'
cast(_FixedAssetAssgmt.CostCtrActivityType as faa_lstar) as AssetCostCtrActivityType,
cast(_FixedAssetAssgmt.PersonnelNumber as faa_pernr_d) as AssetPersonnelNumber,
@ObjectModel.foreignKey.association: '_AssetFunctionalArea'
cast(_FixedAssetAssgmt.FunctionalArea as faa_fkber) as AssetFunctionalArea,
@ObjectModel.foreignKey.association: '_AssetLocation'
_FixedAssetAssgmt.AssetLocation,
@ObjectModel.foreignKey.association: '_AssetRealEstateObject'
_FixedAssetAssgmt.REInternalFinNumber,
@API.element.releaseState: #DEPRECATED
@API.element.successor: 'REInternalFinNumber'
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'REInternalFinNumber'
_FixedAssetAssgmt.RealEstateObject,
cast(_FixedAssetAssgmt.FundsCenter as faa_fistl) as AssetFundsCenter,
_FixedAssetAssgmt.Room,
_FixedAssetAssgmt.VehicleLicensePlateNumber,
_FixedAssetAssgmt.TaxJurisdiction,
/* Fields from Fixed Asset Valuation */
@ObjectModel.foreignKey.association: '_InvestmentSupportMeasure'
_AssetValuationForLedger.InvestmentSupportMeasure,
_AssetValuationForLedger.DepreciationStartDate,
_AssetValuationForLedger.SpecialDeprStartDate,
@ObjectModel.foreignKey.association: '_DepreciationKey'
_AssetValuationForLedger.DepreciationKey,
_AssetValuationForLedger.PlannedUsefulLifeInYears,
_AssetValuationForLedger.PlannedUsefulLifeInPeriods,
_AssetValuationForLedger.OriglAstUsefulLifeInYears,
_AssetValuationForLedger.OriglAstUsefulLifeInPerds,
_AssetValuationForLedger.DeprKeyChangeoverYear,
_AssetValuationForLedger.DeprKeyChangeoverPeriod,
_AssetValuationForLedger.VintageYear,
_AssetValuationForLedger.VintageMonth,
@API.element.releaseState: #DEPRECATED
@API.element.successor: 'AssetRevaluationIndex'
@VDM.lifecycle: {status: #DEPRECATED}
@VDM.lifecycle.successor: 'AssetRevaluationIndex'
_AssetValuationForLedger.ReplacementValueIndexSers,
@API.element.releaseState: #DEPRECATED
@API.element.successor: 'AssetRevaluationIndex'
@VDM.lifecycle: {status: #DEPRECATED}
@VDM.lifecycle.successor: 'AssetRevaluationIndex'
_AssetValuationForLedger.RplcmtValueAgingIndexSers,
@ObjectModel.foreignKey.association: '_FixedAssetUsageObject'
_AssetValuationForLedger.FixedAssetUsageObject,
@ObjectModel.foreignKey.association: '_AssetRevaluationIndex'
_AssetValuationForLedger.AssetRevaluationIndex,
/* Fields from Fixed Asset Country Data */
@ObjectModel.foreignKey.association: '_FixedAssetNatlClfn'
_FixedAssetCountryData.NationalClassification,
@ObjectModel.foreignKey.association: '_TaxDepreciationGroup'
_FixedAssetCountryData.TaxDepreciationGroup,
@ObjectModel.foreignKey.association: '_JP_PrptyTxRptCity'
_FixedAssetCountryData.JP_PrptyTxRptCity,
@ObjectModel.foreignKey.association: '_JP_PrptyTxRptClassfctnKey'
_FixedAssetCountryData.JP_PrptyTxRptClassfctnKey,
@ObjectModel.foreignKey.association: '_RU_AssetOKOF'
_GlobAssetAssignment.RU_AssetOKOF,
@ObjectModel.foreignKey.association: '_RU_AssetDepreciationGroup'
_GlobAssetAssignment.RU_AssetDepreciationGroup,
cast( _WBSElement_2.WBSElementExternalID as faa_inv_wbs_element ) as WBSElementExternalID,
cast( _FixedAssetAssgmt._WBSElement.WBSElementExternalID as faa_wbs_element ) as AssetWBSElementExternalID,
/*Associations */
_CompanyCode,
_CountryChartOfAccounts,
_DepreciationArea,
_ChartOfAccounts,
_ControllingArea,
_MasterFixedAsset,
_FixedAsset,
_AssetAccountDetermination,
_AssetClass,
_Ledger,
_FiscalYear,
_JournalEntry,
_SubLedgerAccLineItemType,
_LedgerGroup,
_GLAccountInChartOfAccounts,
_AlternativeGLAccount,
_AssetAcctTransClassfctn,
_FinancialAccountType,
_ChartOfDepreciation,
_AccountingPrinciple,
_CostCenter,
_Plant,
_BusinessArea,
_ProfitCenter,
_Segment,
_FunctionalArea,
_AssetTransactionType,
_BusinessTransactionCategory,
_BusinessTransactionType,
_AssetCostCenter,
_AssetWBSElement,
_AssetBusinessArea,
_AssetProfitCenter,
_AssetSegment,
_AssetPlant,
_AssetRealEstateObject,
_AssetCostCenterActivityType,
_AssetFunctionalArea,
_AssetLocation,
_AssetKeyFigure,
_AssetKeyFigureSet,
_AssetSortedKeyFigureSetSpec,
_Currency,
_CurrencyRole,
_FixedAssetGroup,
_InvestmentOrder,
_UnitOfMeasure,
_Group1AssetEvaluationKey,
_Group2AssetEvaluationKey,
_Group3AssetEvaluationKey,
_Group4AssetEvaluationKey,
_Group5AssetEvaluationKey,
_InvestmentSupportMeasure,
_DepreciationKey,
_FixedAssetUsageObject,
_AssetRevaluationIndex,
_AcqnProdnCostGLAccount,
_FiscalYearVariant,
_FiscalPeriodForVariant,
_FixedAssetCountryData,
_FixedAssetNatlClfn,
_TaxDepreciationGroup,
_Country,
_FinancialManagementArea,
_Fund,
_BudgetPeriod,
_Supplier,
_SelectedCurrencyBranch,
_AccountingDocumentType,
_JP_PrptyTxRptCity,
_JP_PrptyTxRptClassfctnKey,
_RU_AssetDepreciationGroup,
_RU_AssetOKOF,
@Analytics.association.toDocumentStorage: true
_DocumentStore,
@Consumption.hidden: true
_AssetRedesignSwitchStatus //for DCL
}
where
P_AssetBalanceCube1.AssetAccountingKeyFigureSet = $parameters.P_AssetAccountingKeyFigureSet