I_ARLockBoxBatchItem

@EndUserText.label: 'Lockbox Batch Item Data'  
//@Analytics.dataCategory: #CUBE 

@VDM.viewType: #COMPOSITE 
@AccessControl.authorizationCheck: #NOT_REQUIRED 
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA') //Partner's Bank Account - archiving is possible

@ObjectModel.usageType.sizeCategory: #XL 
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED

define view entity I_ARLockBoxBatchItem 
     as select from P_ARLockBoxBatchItem  as item
   // select status description from fix values of the domain FAR_ASTAT

  left outer join dd07t            on dd07t.domvalue_l = item.LockboxBatchItmStatus
                                   and dd07t.domname = 'FAR_CHECT_ASTAT'
                                   and dd07t.ddlanguage = $session.system_language    
                                            
  association [0..1] to I_Currency    as _Currency    on _Currency.Currency   = $projection.Currency           
  
-- Association with Lockbox   
  association [1..1] to I_ARLockBoxBatch as _Header
                                          on  item.LockboxBatchInternalKey  = _Header.LockboxBatchInternalKey
                                          and item.LockboxBatch  = _Header.LockboxBatch
                                          
  association [0..1] to I_JournalEntry    as _JournalEntry     on  $projection.BankLedgerDocument      = _JournalEntry.AccountingDocument
                                                               and $projection.CompanyCode             = _JournalEntry.CompanyCode
                                                               and $projection.FiscalYear              = _JournalEntry.FiscalYear
                                                               
  association [0..1] to I_Arbsitmemolinewithorig as _MemoLine on  $projection.LockboxBatchInternalKey = _MemoLine.BankStatementShortID
                                                                   and $projection.LockboxBatchItem        = _MemoLine.BankStatementItem                                                             
{

   key  item.LockboxBatchInternalKey,   
   key  item.LockboxBatchItem,   
   key  item.LockboxBatch,
   item.ValueDate,
   item.Currency,
   @DefaultAggregation: #NONE
   @Semantics.amount.currencyCode: 'Currency' 
   cast(item.AmountInTransactionCurrency   as farp_fwbtr)          as AmountInTransactionCurrency,
   cast (item.LockboxBatchItmStatus as far_chect_astat)            as LockboxBatchItmStatus,  
   cast(dd07t.ddtext as far_lb_stat_desc)                     as LockboxBatchItmStatusName,   
   item.IsCompleted,    
   cast(item.Cheque as farp_chect)                                 as Cheque,//until 02/2018 CustomerReferenceNumber was used here. By accident.                                                                         

   cast(item.PartnerBankCountry as farp_pabks)                     as PartnerBankCountry,
   cast(item.PartnerBank as farp_pablz)                            as PartnerBank,
   cast(item.PartnerBankAccount as farp_pakto)                     as PartnerBankAccount,
   item.BankLedgerDocument, 
   cast(item.PaymentAdviceAccount as kunnr)                        as Customer,
   cast(item.ApplicationLog as far_applog)                         as ApplicationLog,
   _MemoLine.MemoLine                                         as MemoLine,
   //not needed due to new string based persistence

   cast(item.MemoLine1  as farp_memo_line_1)                       as MemoLine1,    
   item.AssignmentReference,
   cast(item.PaymentExternalTransacType as farp_vorgc)             as PaymentExternalTransacType,
   cast(item.DocumentItemText as text50)                           as DocumentItemText,
   item.DocumentReferenceID,
   cast(item.PaymentManualTransacType as vgman_eb)                 as PaymentManualTransacType,
   cast(item.BankLedgerIsPosted as farp_vb1ok)                     as BankLedgerIsPosted,
   cast(item.SubledgerIsPostedSuccessfully as farp_vb2ok)          as SubledgerIsPostedSuccessfully,
   cast(item.LockboxSubledgerDocument as far_sdoc2)                as LockboxSubledgerDocument,
   item.CompanyCode,
   item.FiscalYear ,
   item.BankLedgerAcctgDocFiscalYear,
   item.SubledgerDocument,
   item.AdditionalInformation                                      as LockboxBatchItmAdditionalInfo,
   item.SubledgerAcctgDocFiscalYear, 
   item.PaymentAdvice,
   _Currency,
   _Header,
   _JournalEntry,
   item.SubledgerOnAccountDocument ,
   _Header.Lockbox,
  item.BankStatementItemDraftUUID,
  item.BankStatementInternalID,
  item.LockboxProcessingStatus,
  item.BankPostingDate,
  item.BankPostingKey,
  item.BankReference,
  item.BusinessArea,
  item.BusinessPartnerName,
  item.TreasuryContract,
  item.DaybookEntry,
  item.DunningBlockingReason,
  item.ExchangeRate,
  @Semantics.amount.currencyCode: 'CURRENCY' 
item.FeeAmountInTransactionCrcy,
  @Semantics.amount.currencyCode: 'CURRENCY' 
item.FeeAmountInOriginalCrcy,
  item.MemoLineIsChanged,
  @Semantics.amount.currencyCode: 'CURRENCY' 
item.AmountInOriginalCurrency,
  item.OriginalCurrency,
  @Semantics.amount.currencyCode: 'CURRENCY' 
item.OverdueChargeAmtInTransacCrcy,
  item.PartnerBankIBAN,
  item.PartnerBankSWIFTCode,
  item.PaymentAdviceAccount,
  item.PaymentAdviceAccountType,
  item.PaymentAdviceAccountTypeName,
  item.PaymentReference,
  item.PostingDate,
  item.PostingErrorStatus,
  item.ReferenceDocument,
  item.ReferenceDocumentType,
  item.BankStmntItemReprocessReason,
  item.ReturnReason,
  item.TreasuryContractType,
  item.ValueDateTime,
  item.MachineLrngBankStmntItemStatus,
  item.CostCenter,
  item.ProfitCenter,
  item.DebitCreditCode
}