C_ARLockBoxBatchItem

@EndUserText.label: 'Lockbox Batch Item'
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA') //Partner's Bank Account - archiving is possible

@ObjectModel.usageType.sizeCategory: #XL 
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@UI.headerInfo:{ 
  typeName: 'Lockbox Batch Item',
  typeNamePlural: 'Lockbox Batch Items',
  title: { value: 'LockboxBatchItem' },
  description: { type: #STANDARD, value: '_Header.Lockbox'}
}
@UI.presentationVariant: [{requestAtLeast: [ 'FiscalYear' ]}]
define view entity C_ARLockBoxBatchItem 
   as select from I_ARLockBoxBatchItem as item

  association [1..1] to C_ARLockBoxBatch as _Header
    on  item.LockboxBatchInternalKey   = _Header.LockboxBatchInternalKey
    and item.LockboxBatch  = _Header.LockboxBatch
    
{
    @UI.facet: [
    {
      label: 'Lockbox Batch Item',
      id: 'COLLFAC2',
      type: #COLLECTION,
      position: 10
    },
    {
      label: '',
      id: 'Q1',
      parentId: 'COLLFAC2',
      type: #IDENTIFICATION_REFERENCE,
      position: 10      
    }
    ]
   @UI.identification: [{ position: 29 }]
   key LockboxBatchInternalKey, 
   
   @UI.identification: [{ position: 28 }]  
   key LockboxBatchItem,
   
   @UI.identification: [{ position: 1 }]
   key LockboxBatch,
   
   @UI.identification: [{ position: 3 }] 
   ValueDate, 
   
   @UI.identification: [{ position: 5 }]
   Currency,  
   
   @Semantics.amount.currencyCode: 'CURRENCY' 
@UI.identification: [{ position: 4 }]
   //To set the default table columns 

   @UI.lineItem: [ {position:60, importance: #HIGH } ]
   AmountInTransactionCurrency, 
   
   @UI.identification: [{ position: 8 }]  
   LockboxBatchItmStatus,
   
   @UI.identification: [{ position: 26 }]
   @UI.lineItem: [ { position:10, importance: #HIGH } ]
   LockboxBatchItmStatusName,
   
   @UI.identification: [{ position: 2 }] 
   @UI.lineItem: [{position:20}]
   Cheque, //until 02/2018 CustomerReferenceNumber was used here. By accident.     

   
   @UI.identification: [{ position: 25 }]
   @UI.lineItem: [ { position:30, importance: #HIGH } ]
   PartnerBankCountry,
   
   @UI.identification: [{ position: 24 }]
   @UI.lineItem: [ { position:40, importance: #HIGH } ]
   PartnerBank,
   
   @UI.identification: [{ position: 23 }]
   @UI.lineItem: [ { position:50, importance: #HIGH } ]
   PartnerBankAccount,
   
   @UI.identification: [{ position: 10 }]
   @UI.lineItem: [ { position:70, importance: #HIGH } ]
   @Consumption.semanticObject: 'AccountingDocument'
   BankLedgerDocument,
   
   @UI.identification: [{ position: 9 }]
   @UI.lineItem: [ { position:80, importance: #HIGH } ]
   Customer,   
   
   @UI.identification: [{ position: 27 }]
   ApplicationLog, 
   
   //not needed due to new string based persistence

   @UI.identification: [{ position: 7 }]
   @UI.lineItem: [ { position:90, importance: #HIGH } ]
   MemoLine1,
   
   @UI.identification: [{ position: 6 }]   
   MemoLine,
   
   @UI.identification: [{ position: 11 }]
   @UI.lineItem: [ { position:95, importance: #HIGH } ]
   @Consumption.semanticObject: 'PaymentAdvice'
   PaymentAdvice,
   
   @UI.identification: [{ position: 12 }]
   AssignmentReference,
   @UI.identification: [{ position: 13 }]
   PaymentExternalTransacType,
   @UI.identification: [{ position: 14 }]
   DocumentItemText,
   @UI.identification: [{ position: 15 }]
   DocumentReferenceID,
   @UI.identification: [{ position: 16 }]
   PaymentManualTransacType,
   @UI.identification: [{ position: 17 }]
   BankLedgerIsPosted,
   @UI.identification: [{ position: 18 }]
   SubledgerIsPostedSuccessfully,
   
   @UI.identification: [{ position: 19 }]
   @Consumption.semanticObject: 'AccountingDocument'
   LockboxSubledgerDocument,
   
   @UI.identification: [{ position: 20 }]
   CompanyCode,
   @UI.identification: [{ position: 21 }]
 //  @UI.lineItem: [ { position:100, importance: #HIGH } ]

   FiscalYear ,
   @UI.identification: [{ position: 22 }]
   @Consumption.semanticObject: 'AccountingDocument'
   SubledgerDocument,
   
   _Currency,
   _Header,
   _JournalEntry
   
}