C_WorkPackage

@AbapCatalog.sqlViewName: 'CWORKPACKAGE'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Work Package'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.authorizationCheck:#CHECK
@AccessControl.personalData.blocking:#REQUIRED
define view C_WorkPackage
  as select from           I_WorkPackage                 as WorkPackage

    inner join             P_EngagementProjFinancialPlan as FinancialPlan       on FinancialPlan.EngagementProjFinPlanUUID = WorkPackage.EngagementProjFinPlanUUID

    left outer to one join C_WorkPackagePlanData         as WorkPackagePlanData on  WorkPackagePlanData.WorkPackage = WorkPackage.WorkPackage
                                                                                and FinancialPlan.EngagementProject = WorkPackagePlanData.EngagementProject

    left outer to one join P_WorkPackageWorkItemCount    as WorkItemCount       on WorkItemCount.WorkPackage = WorkPackage.WorkPackage

  association [0..1] to I_EngagementProject            as _EngagementProject   on  $projection.EngagementProject = _EngagementProject.EngagementProject


  association [0..1] to E_Workpackage                  as _Extension           on  $projection.WorkPackageUUID = _Extension.WorkPackageUUID

  association [0..*] to C_WorkpackageWorkItem          as _WorkPackageWorkItem on  $projection.WorkPackage                        = _WorkPackageWorkItem.WorkPackage
                                                                               and _WorkPackageWorkItem.EngagementProjFinPlanUUID = WorkPackage.EngagementProjFinPlanUUID

  association [0..*] to I_EngmntProjectUnitDataVersion as _UnitPlanData        on  $projection.WorkPackage = _UnitPlanData.WorkPackage

  association [0..1] to I_UnitOfMeasure                as _UnitOfMeasure       on  $projection.WorkPackageUnitUoM = _UnitOfMeasure.UnitOfMeasure

  association [0..1] to I_EngagementProjectResource    as _WorkPackageUnit     on  $projection.WorkPackageUnit                    = _WorkPackageUnit.EngagementProjectResource
                                                                               and _WorkPackageUnit.EngagementProjectResourceType = '0SRV'

{
  WorkPackage.WorkPackage                as WorkPackage,
  WorkPackage.WorkPackageUUID            as WorkPackageUUID,
  WorkPackage.EngagementProjFinPlanUUID  as EngagementProjFinPlanUUID,
  WorkPackage.WorkPackageName            as WorkPackageName,
  WorkPackage.WorkPackageStartDate       as WorkPackageStartDate,
  WorkPackage.WorkPackageEndDate         as WorkPackageEndDate,
  WorkPackage.WBSElementObject           as WorkPackageWBSObjectNumber,
  WorkPackage.WBSDescription             as WBSDescription,
  //--[ GENERATED:012:GlBfhyJl7jY4oBIOE}WCZW

  @Consumption.valueHelpDefinition: [
    { entity:  { name:    'I_SalesOrderStdVH',
                 element: 'SalesOrder' }
    }]
  // ]--GENERATED

  WorkPackage.SalesOrder                 as SalesOrder,
  //--[ GENERATED:012:GlBfhyJl7jY4oBIOE}WCZW

  @Consumption.valueHelpDefinition: [
    { entity:  { name:    'I_SalesOrderItemStdVH',
                 element: 'SalesOrderItem' },
      additionalBinding: [{ localElement: 'SalesOrder',
                            element: 'SalesOrder' }]
    }]
  // ]--GENERATED

  WorkPackage.SalesOrderItem             as SalesOrderItem,
  WorkPackage.LastChangedByUser          as LastChangedByUser,
  @Semantics.dateTime:true
  @Semantics.systemDateTime.lastChangedAt:true
  WorkPackage.LastChangeDateTime         as LastChangeDateTime,
  WorkPackage.WorkPackageType            as WorkPackageType,

  @Semantics.currencyCode: true
  FinancialPlan.Currency                 as Currency,
  FinancialPlan.EngagementProject        as EngagementProject,

  @Semantics.amount.currencyCode: 'Currency'
  WorkPackagePlanData.PlndCostAmt        as PlndCostAmt,
  WorkPackagePlanData.PlndEffortQty      as PlndEffortQty,

  @Semantics.amount.currencyCode: 'Currency'
  WorkPackagePlanData.PlndRevnAmt        as PlndRevnAmt,

  @Semantics.amount.currencyCode: 'Currency'
  WorkPackagePlanData.PlannedUnitRevenue as PlannedUnitRevenue,

  WorkPackagePlanData.WorkPackageUnit    as WorkPackageUnit,
  @Semantics.quantity.unitOfMeasure:'WorkPackageUnitUoM'
  WorkPackagePlanData.PlanUnitQuantity   as WorkPackageUnitQuantity,
  @Semantics.unitOfMeasure: true
  WorkPackagePlanData.WorkPackageUnitUoM as WorkPackageUnitUoM,
  @Semantics.dateTime:true
  @Semantics.systemDateTime.createdAt:true
  WorkPackage.CreationDateTime           as CreationDateTime,
  WorkPackage.CreatedByUser              as CreatedByUser,
  WorkItemCount.NumberOfWorkItems        as NumberOfWorkItems,

  /* Associations */
  WorkPackage._EngagementProjFinancialPlan,
  WorkPackage._EngagementProjectPlanData,
  _WorkPackageWorkItem,
  _EngagementProject,
  _UnitPlanData,
  _WorkPackageUnit,
  _UnitOfMeasure

}