I_EngmntProjectUnitDataVersion

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IEPROJUNITDATVER'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Engment Project Unit Data'
@VDM.viewType: #BASIC
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
define view I_EngmntProjectUnitDataVersion
  as select from /cpd/plandata as EngagementProjectUnitData

  association [0..1] to I_EngagementProject           as _EngagementProject           on  $projection.EngagementProject = _EngagementProject.EngagementProject

  association [0..1] to I_EngagementProjFinancialPlan as _EngagementProjFinancialPlan on  $projection.EngagementProjFinPlanUUID = _EngagementProjFinancialPlan.EngagementProjFinPlanUUID

  association [1..1] to I_WorkPackage                 as _WorkPackage                 on  $projection.WorkPackage = _WorkPackage.WorkPackage

  association [0..1] to I_EngmtProjFinPlanVersion     as _EngmtProjFinPlanVersion     on  $projection.EngagementProjFinPlanUUID = _EngmtProjFinPlanVersion.EngagementProjFinPlanUUID
                                                                                      and $projection.EngmtProjFinPlanVersion   = _EngmtProjFinPlanVersion.EngmtProjFinPlanVersion


  association [0..1] to I_EngmntProjResourceType      as _EngmntProjResourceType      on  $projection.EngagementProjectResourceType = _EngmntProjResourceType.EngagementProjectResourceType

  association [0..*] to I_EngagementProjectResource   as _EngagementProjectResource   on  $projection.EngagementProjectResource = _EngagementProjectResource.EngagementProjectResource

  association [0..1] to I_Currency                    as _Currency                    on  $projection.Currency = _Currency.Currency

  association [0..1] to I_UnitOfMeasure               as _UnitOfMeasure               on  $projection.UnitOfMeasure = _UnitOfMeasure.UnitOfMeasure

  association [0..1] to I_EngagementProjectSrvcOrg    as _EngagementProjectServiceOrg on  $projection.EngagementProjectServiceOrg = _EngagementProjectServiceOrg.EngagementProjectServiceOrg

  association [0..1] to I_BillingControlCategory      as _BillingControlCategory      on  $projection.BillingControlCategory = _BillingControlCategory.BillingControlCategory

{
  key EngagementProjectUnitData.plan_line_guid                                                           as PlanLineItemUUID,

  key cast(EngagementProjectUnitData.mp_id  as /cpd/eng_mp_id preserving type)                           as EngagementProject,

  key EngagementProjectUnitData.wp_id                                                                    as WorkPackage,

  key cast(EngagementProjectUnitData.fp_key  as /cpd/eng_pfp_db_key preserving type )                    as EngagementProjFinPlanUUID,

  key cast(EngagementProjectUnitData.wp_key as /cpd/wp_db_key preserving type )                          as WorkPackageUUID,

  key EngagementProjectUnitData.version                                                                  as EngmtProjFinPlanVersion,

      @ObjectModel.foreignKey.association: '_EngmntProjResourceType'
  key EngagementProjectUnitData.res_type                                                                 as EngagementProjectResourceType,

      @Semantics.fiscal.period: true
  key EngagementProjectUnitData.period                                                                   as FiscalPeriod,

      @Semantics.fiscal.year: true
  key EngagementProjectUnitData.fc_year                                                                  as FiscalYear,

      @ObjectModel.foreignKey.association: '_EngagementProjectResource'
  key EngagementProjectUnitData.resource_id                                                              as EngagementProjectResource,

  key EngagementProjectUnitData.demand_key                                                               as ResourceDemandUUID,

      @ObjectModel.foreignKey: {
        association: '_BillingControlCategory'
      }
      EngagementProjectUnitData.billgctrlcat                                                             as BillingControlCategory,

      @ObjectModel.foreignKey.association:'_EngagementProjectServiceOrg'
      EngagementProjectUnitData.delvry_serv_org                                                          as EngagementProjectServiceOrg,

      @Semantics.currencyCode: true
      EngagementProjectUnitData.currency                                                                 as Currency,

      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #SUM
      EngagementProjectUnitData.cost                                                                     as PlndCostAmt,

      @Semantics.unitOfMeasure: true
      EngagementProjectUnitData.uom                                                                      as UnitOfMeasure,

      @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
      @DefaultAggregation: #SUM
      EngagementProjectUnitData.effort                                                                   as PlndEffortQty,

      @Semantics.amount.currencyCode: 'Currency'
      @DefaultAggregation: #SUM
      EngagementProjectUnitData.revenue                                                                  as PlndRevnAmt,

      EngagementProjectUnitData.line_type                                                                as EngmntProjPlanLineType,
  
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'SupplySource'
      EngagementProjectUnitData.source_of_supply                                                         as SourceOfSupply,
      EngagementProjectUnitData.source_of_supply                                                         as SupplySource,
      EngagementProjectUnitData.is_unit_based                                                            as IsUnitBased,

      EngagementProjectUnitData.parent_unit_demand_key                                                   as ParentUnitDemandUUID,

      _EngagementProject,
      _EngagementProjFinancialPlan,
      _EngmtProjFinPlanVersion,
      _WorkPackage,
      _EngmntProjResourceType,
      _EngagementProjectResource,
      _Currency,
      _EngagementProjectServiceOrg,
      _UnitOfMeasure,
      _BillingControlCategory

}
where
      is_draft      <> 'X'
  and is_unit_based =  'X'