C_WorkCenterObjPg

@AbapCatalog.sqlViewName: 'CWRKCENTROBJPG'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Work Center Object Page'
@Search.searchable: true
@Consumption.semanticObject: 'WorkCenter'

@VDM.viewType: #CONSUMPTION
//@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'WorkCenterInternalID'
@ObjectModel.semanticKey: 'WorkCenterInternalID'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}

/* UI annotations for header area of object page*/
@UI.headerInfo.typeName: 'Work Center'
@UI.headerInfo.typeNamePlural: 'List of Resources'
@UI.headerInfo.title.label: 'Work Center'
@UI.headerInfo.title.value: 'WorkCenter'
@UI.headerInfo.description.value: 'WorkCenterDesc'

define view C_WorkCenterObjPg
  as select from I_WorkCenter as WorkCenter

  association [1..1] to C_WorkCenterObjPgCap          as _Capacity                on  $projection.CapacityInternalID = _Capacity.CapacityInternalID
  association [0..*] to I_ProductionResourceUsageText as _ProductionResourceUsage on  $projection.WorkCenterUsage = WorkCenterUsage
  association [0..*] to C_WrkCntrObjPgTodayOp         as _WorkCenterTodayOp       on  $projection.WorkCenterInternalID              = _WorkCenterTodayOp.WorkCenterInternalID
                                                                                  and _WorkCenterTodayOp.ManufacturingOrderCategory = '10'
                                                                                  and _WorkCenterTodayOp.OperationIsConfirmed = ''                                                                               
  association [0..*] to C_WrkCntrObjPgQueueOp         as _WorkCenterQueuingOp     on  $projection.WorkCenterInternalID                = _WorkCenterQueuingOp.WorkCenterInternalID
                                                                                  and _WorkCenterQueuingOp.ManufacturingOrderCategory = '10'
  association [0..*] to C_WrkCtrObjPgInProcOp        as _WorkCenterInProcessOp    on  $projection.WorkCenterInternalID              = _WorkCenterInProcessOp.WorkCenterInternalID
                                                                                  and _WorkCenterInProcessOp.ManufacturingOrderCategory = '10'
                                                                                  
  association [0..*] to C_WrkCtrObjPgPlannedOrd       as _WorkCenterPlannedOrd    on  $projection.WorkCenterInternalID              = _WorkCenterPlannedOrd.WorkCenterInternalID
                                                                                                                    
                                                                                 
  //    left outer to one join I_WorkcenterObjPgCntOper   as CurrentOpNumber    on  WorkCenter.WorkCenterInternalID            = CurrentOpNumber.WorkCenterInternalID

  //                                                                            and CurrentOpNumber.ManufacturingOrderCategory = '10'

  //    left outer to one join C_Workcenterobjpgtdynprno  as TodaysOpNum        on  WorkCenter.WorkCenterInternalID        = TodaysOpNum.WorkCenterInternalID

  //                                                                            and TodaysOpNum.ManufacturingOrderCategory = '10'

  //    left outer to one join C_Workcenterobjpgoprstatus as TotalQueueQuantity on  WorkCenter.WorkCenterInternalID               = TotalQueueQuantity.WorkCenterInternalID

  //                                                                            and TotalQueueQuantity.ManufacturingOrderCategory = '10'

{
                    //General     Information

                    @Search.defaultSearchElement: true
                    @EndUserText.label:'Work Center Internal Id'
  key               WorkCenter.WorkCenterInternalID,
                    @EndUserText.label:'Work Center Type Code'
                    @ObjectModel.foreignKey.association: '_WorkCenterType'
  key               WorkCenterTypeCode,                  
                    @UI.identification: [{position:10}]
                    @UI.selectionField.position: 10
                    @ObjectModel.text.element: 'WorkCenterDesc'
                    @Consumption.semanticObject: 'WorkCenter'
                    @UI.lineItem:{position: 10,type: #WITH_INTENT_BASED_NAVIGATION,semanticObjectAction: 'display' }
                    @Consumption.valueHelpDefinition: [ { entity: { name: 'I_WrkCtrBySemanticKeyStdVH', element: 'WorkCenter' } } ]
                    WorkCenter,
                    @UI.hidden
                    _Text[1:Language=$session.system_language].WorkCenterText as WorkCenterDesc,
                    @UI.identification: [{position:20}]
                    @UI.dataPoint:{ title: 'Plant'}
                    @UI.selectionField.position: 20
                    @UI.lineItem:{position: 20}
                    @ObjectModel.foreignKey.association: '_Plant'
                    Plant,
                    @UI.identification: [{position:30}]
                    @UI.dataPoint:{ title: 'Category Code'}
                    @UI.selectionField.position: 30
                    @UI.lineItem:{position: 30}
                    WorkCenterCategoryCode,                 
                    @UI.fieldGroup: [ { qualifier: 'GeneralInformation2', position: 10 } ]
                    @ObjectModel.foreignKey.association: '_WorkCenterResponsible'
                    @UI.selectionField.position: 40
                    @UI.lineItem:{position: 40}
                    WorkCenterResponsible,
                    @Semantics.text: true
                    _WorkCenterResponsible.WorkCenterResponsibleName,
                    @UI.selectionField.position: 50
                    @UI.lineItem:{position: 50}
                    @UI.fieldGroup: [ { qualifier: 'GeneralInformation2', position: 20 } ]
                    SupplyArea,
                    @UI.selectionField.position: 60
                    @UI.lineItem:{position: 60}
                    @UI.fieldGroup: [ { qualifier: 'GeneralInformation2', position: 20 } ]
                    WorkCenterUsage,
                    CapacityInternalID,
                    // Current Operations Number (All operations with planned start <=now and planned end => now and WorkCenter = self)

                    //                    @EndUserText.label:'Operations In Process'

                    //                    CurrentOpNumber.NumberOfOperations,

                     //                     Todays Operations Number (Number of operations planned for today = number of rows in table in object page)

                    //                    @EndUserText.label:'Todays Operations No.'

                    //                    TodaysOpNum.MaintOrderNumberOfOperations,

                    //                    //  Total Queue Quantity (All operations with OperationIsRelease = true and OperationIsStarted = false and WorkCenter = self)

                    //                    @EndUserText.label:'Total Queue No.'

                    //                    TotalQueueQuantity.OpWorkQuantityUnit,

                    _ProductionResourceUsage,
                    _WorkCenter,
                    _WorkCenterCategory,
                    _WorkCenterResponsible,
                    _SupplyArea,
                    _WorkCenterUsage,
                    _Plant,
                    _Capacity,
                    _WorkCenterTodayOp,
                    _WorkCenterQueuingOp,
                    _WorkCenterType,
                    _WorkCenterInProcessOp,
                    _WorkCenterPlannedOrd
}