C_WrkCntrObjPgQueueOp

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Work Center Queuing Operation'
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {serviceQuality: #D, sizeCategory: #XL, dataClass: #MIXED}
@UI.headerInfo.typeName: 'Queuing Operation'
@UI.headerInfo.typeNamePlural: 'Queuing Operations'
@UI.presentationVariant: [{
  visualizations: [{ type: #AS_LINEITEM }],
  sortOrder: [{ by: 'OperationIsReleased', direction: #DESC} ]
}]
@UI.lineItem: [{criticality: 'OperationStatusCriticality'}]

define view entity C_WrkCntrObjPgQueueOp
  as select from P_QueuingOperations
{
      @UI.hidden: true
  key OrderInternalBillOfOperations,
      @UI.hidden: true
  key OrderIntBillOfOperationsItem,

      @UI.hidden: true
  key WorkCenterInternalID,
        @Consumption.semanticObject: 'ProductionOrder'
      @UI.lineItem: [ { position: 10, label: 'Production Order'}]
      @UI.identification: [{type: #FOR_INTENT_BASED_NAVIGATION, semanticObject: 'ProductionOrder'}]
      @EndUserText.label: 'Production Order'
      @ObjectModel.foreignKey.association: '_MfgOrder'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderStdVH', element: 'ManufacturingOrder' } } ]
      ManufacturingOrder,
      @ObjectModel.text.element: [ 'MfgOrderOperationText']
      @UI.lineItem: [ {position: 20 }]
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderOperationVH', element: 'ManufacturingOrderOperation' } } ]
      ManufacturingOrderOperation,
      @UI.hidden: true
      MfgOrderOperationText,
      @UI.hidden: true
      ManufacturingOrderCategory,
      @Consumption.semanticObject: 'Material'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
      @UI.lineItem: [ { position: 30, label: 'Material'}]
      @UI.identification: [{type: #FOR_INTENT_BASED_NAVIGATION, semanticObject: 'Material'}]
      @EndUserText.label: 'Material'
      Material,
      @UI.lineItem: [{position:35}]
      @EndUserText:{label:'Material Description',quickInfo: 'Material Description'}
      _Material._Text[1:Language=$session.system_language].MaterialName,
      @UI.lineItem: [{position:40}]
      @EndUserText:{label:'Operation Is Released ',quickInfo: 'Operation Is Released '}
      OperationIsReleased,
      @UI.lineItem: [{position:50}]
      @EndUserText.label: 'Planned Start Date'
      OpErlstSchedldExecStrtDte,
      @EndUserText.label: 'Planned Start Time'
      @UI.lineItem: [{position:60}]
      OpErlstSchedldExecStrtTme,
      @EndUserText.label: 'Planned End Date'
      @UI.lineItem: [{position:70}]
      OpErlstSchedldExecEndDte,
      @EndUserText.label: 'Planned End Time'
      @UI.lineItem: [{position:80}]
      OpErlstSchedldExecEndTme,
      @UI.lineItem: [{position:90}]
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @EndUserText.label: 'Total Queue Quantity'
      OpPlannedTotalQuantity,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' } } ]
      OperationUnit,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @EndUserText.label: 'Confirmed Quantity'
      OpTotalConfirmedYieldQty,
      @EndUserText.label: 'Planned Duration'
      ErlstSchedldExecDurnInWorkdays,
      @EndUserText.label: 'Remaining Duration'
      @Semantics.calendarItem.duration: true
      RemainingDuration,
      @ObjectModel.foreignKey.association: '_MfgOrderSequence'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderSequenceStdVH', element: 'ManufacturingOrderSequence' } } ]
      ManufacturingOrderSequence,
      @UI.hidden: true
      cast (case
        when (OpErlstSchedldExecStrtDte = $session.system_date and  OpErlstSchedldExecStrtTme >    tstmp_to_tims( tstmp_current_utctimestamp(), abap_system_timezone( $session.client,'NULL' ),
                     $session.client,
                     'NULL' ) )
        then 0
        when( OpErlstSchedldExecStrtDte = $session.system_date and  OpErlstSchedldExecStrtTme  <   tstmp_to_tims( tstmp_current_utctimestamp(), abap_system_timezone( $session.client,'NULL' ),
                     $session.client,
                     'NULL' ) )
        then 1
        when OpErlstSchedldExecStrtDte < $session.system_date
        then 1
       end as mpe_opstatuscritly )    as OperationStatusCriticality,


      _Material,
      _MfgOrder,
      _MfgOrderSequence
}