C_VASCombination

DDL: C_VASCOMBINATION Type: view_entity CONSUMPTION Package: RFM_CONFIG_VAS_DETERMINATION

VAS Combination

C_VASCombination is a Consumption CDS View that provides data about "VAS Combination" in SAP S/4HANA. It reads from 1 data source (R_VASCombinationTP) and exposes 19 fields with key field VASCombinationUUID. It is exposed through 1 OData service (VASCOMBINATION). Part of development package RFM_CONFIG_VAS_DETERMINATION.

1 data source(s) Exposed by 1 service(s) 19 fields

Data Sources (1)

SourceAliasJoin Type
R_VASCombinationTP R_VASCombinationTP projection

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label VAS Combination view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MASTER view
VDM.viewType #CONSUMPTION view
Metadata.allowExtensions true view
Search.searchable true view
AccessControl.personalData.blocking #REQUIRED view

OData Services (1)

ServiceBindingVersionContractRelease
VASCOMBINATION VASCOMBINATION V4 C1 NOT_RELEASED

Fields (19)

KeyFieldSource TableSource FieldDescription
KEY VASCombinationUUID VASCombinationUUID
VASCombinationName VASCombinationName
VASUsage VASUsage
CombinationPriority CombinationPriority
CombinationStatus CombinationStatus
VASStatusText VASStatusText
VASUsageText VASUsageText
OverallStatusCriticality OverallStatusCriticality
VASCombinationDesc VASCombinationDesc
CreatedByUser CreatedByUser
CreatedOnDateTime CreatedOnDateTime
LastChangedByUser LastChangedByUser
LastChangeDateTime LastChangeDateTime
CreatedByUserName CreatedByUserName
LastChangedByUserName LastChangedByUserName
_CreatedByUserContactCard _CreatedByUserContactCard
_LastChangedByUser _LastChangedByUser
_LastChangedByUserContactCard _LastChangedByUserContactCard
_User _User 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'VAS Combination'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MASTER

  }
@VDM.viewType: #CONSUMPTION
@Metadata.allowExtensions: true
@UI.presentationVariant: [{ groupBy: [ 'VASUsage' ] , sortOrder: [{by: 'CombinationPriority' , direction: #ASC }] }]
@Search.searchable: true
@AccessControl.personalData.blocking : #REQUIRED
define root view entity C_VASCombination
  provider contract transactional_query
  as projection on R_VASCombinationTP
{
  key VASCombinationUUID,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      VASCombinationName,
      @Consumption.valueHelpDefinition: [
             { entity: { name: 'I_VASCombinationTypeVH', element: 'VASUsage' } }
            ]

      @ObjectModel.text.element: [ 'VASUsageText' ]
      VASUsage,
      CombinationPriority,
            @Search.defaultSearchElement: true
      @UI.defaultValue: ' '
      @ObjectModel.text.element: [ 'VASStatusText' ]
       @Consumption.valueHelpDefinition: [
             { entity: { name: 'I_VASCombinationStatusVH', element: 'CombinationStatus' } }
            ]
      CombinationStatus,
      
      @Semantics.text:true
      VASStatusText,
      @Semantics.text: true
      VASUsageText,
      OverallStatusCriticality,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.7
      VASCombinationDesc,
      @ObjectModel: { sort.enabled: false,
        text.element: ['CreatedByUserName']
        }

      CreatedByUser,
      CreatedOnDateTime,
      @ObjectModel: { sort.enabled: false,
          text.element: ['LastChangedByUserName']
          }

      LastChangedByUser,
      LastChangeDateTime,
      @Semantics.text:true
      CreatedByUserName,
      @Semantics.text:true
      LastChangedByUserName,
      /* Associations */
      _CreatedByUserContactCard,
      _LastChangedByUser,
      _LastChangedByUserContactCard,
      _User,
     // _VASUsageVH,

      _VASCharc    : redirected to composition child C_VASCharacteristic,
      _VASCharcVal : redirected to composition child C_VASCharacteristicValue
}

Learn More