R_VASCOMBINATIONTP

CDS View

VAS Combination - TP

R_VASCOMBINATIONTP is a CDS View in S/4HANA. VAS Combination - TP. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_VASCombination view_entity projection CONSUMPTION VAS Combination
I_VASCombinationTP view_entity projection TRANSACTIONAL Interface VAS Charc Value - TP 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'VAS Combination - TP'
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.privilegedAssociations: [ '_VASUsageVH' ]
@ObjectModel: {
                usageType.dataClass: #MASTER,
                usageType.serviceQuality: #C,
                usageType.sizeCategory: #L,
                transactionalProcessingEnabled: true,
                representativeKey: 'VASCombinationUUID'
               }

@AccessControl.personalData.blocking: #REQUIRED
@Metadata.allowExtensions: true
@VDM.lifecycle.contract.type:  #SAP_INTERNAL_API
@ObjectModel.sapObjectNodeType.name: 'VASCharacteristicCombination'
@VDM.viewType: #TRANSACTIONAL
 @Search.searchable: true
define root view entity R_VASCombinationTP
  as select from I_VASCombination
  composition [0..*] of R_VASCharacteristicTP      as _VASCharc
  composition [0..*] of R_VASCharacteristicValueTP as _VASCharcVal
  association [0..1] to I_UserDescription          as _User                         on $projection.CreatedByUser = _User.UserID
  association [0..1] to I_UserDescription          as _LastChangedByUser            on $projection.LastChangedByUser = _LastChangedByUser.UserID
  association [1..1] to I_UserContactCard          as _CreatedByUserContactCard     on $projection.CreatedByUser = _CreatedByUserContactCard.ContactCardID
  association [0..1] to I_UserContactCard          as _LastChangedByUserContactCard on $projection.LastChangedByUser = _LastChangedByUserContactCard.ContactCardID
  association [0..1] to I_VASCombinationTypeVH     as _VASUsageVH                   on $projection.VASUsage = _VASUsageVH.VASUsage


{
  key VASCombinationUUID,
      VASCombinationName,
      VASCombinationDesc,
      @ObjectModel.foreignKey.association: '_VASUsageVH'
     // @Consumption.valueHelp: '_VASUsageVH'

       @Consumption.valueHelpDefinition: [{ entity: { name: 'I_VASCombinationTypeVH', element: 'VASUsage' } }]
 
      VASUsage,
      CombinationPriority,
      @ObjectModel.text.element: [ 'VASStatusText' ]
      CombinationStatus,
      @Semantics.text:true
      VASStatusText,
      OverallStatusCriticality,
      VASUsageText,


      //      Admin fields

      @ObjectModel.text.element: ['CreatedByUserName']
      CreatedByUser,
      CreatedOnDateTime,
      @ObjectModel.text.element: ['LastChangedByUserName']
      LastChangedByUser,
      LastChangeDateTime,
     @Semantics.text: true
  @UI.hidden: true
  @Search.defaultSearchElement: true           // <— include this in global search

  @Search.ranking: #HIGH
      _User.UserDescription              as CreatedByUserName,
 @Semantics.text: true
  @UI.hidden: true
  @Search.defaultSearchElement: true           // <— include this in global search

  @Search.ranking: #HIGH
      _LastChangedByUser.UserDescription as LastChangedByUserName,
      //  composition

      _VASCharc,
      _VASCharcVal , 
      _User,

     // _VASUsageVH,

      _LastChangedByUser,
      _CreatedByUserContactCard,
      _LastChangedByUserContactCard
        
      
}

Learn More