C_SlsQtanItemPartnerManageTP

DDL: C_SLSQTANITEMPARTNERMANAGETP Type: view_entity CONSUMPTION Package: ODATA_SD_QUOTATION

Sales Quotation Item Partner

C_SlsQtanItemPartnerManageTP is a Consumption CDS View that provides data about "Sales Quotation Item Partner" in SAP S/4HANA. It reads from 1 data source (R_SalesQuotationItemPartnerTP) and exposes 55 fields with key fields SalesQuotation, SalesQuotationItem, PartnerFunction. It has 1 association to related views. It is exposed through 1 OData service (UI_SALESQUOTATIONMANAGE). Part of development package ODATA_SD_QUOTATION.

1 data source(s) Exposed by 1 service(s) 55 fields

Data Sources (1)

SourceAliasJoin Type
R_SalesQuotationItemPartnerTP R_SalesQuotationItemPartnerTP projection

Associations (1)

CardinalityTargetAliasCondition
[0..1] C_PartnerFunctionUnconverted _PartnerFunction $projection.PartnerFunctionForEdit = _PartnerFunction.PartnerFunction

Annotations (10)

NameValueLevelField
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #CHECK view
Metadata.ignorePropagatedAnnotations true view
Metadata.allowExtensions true view
ObjectModel.modelingPattern #TRANSACTIONAL_QUERY view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.query.implementedBy ABAP:CL_S4RAP_STICKY_QRY view
EndUserText.label Sales Quotation Item Partner view

OData Services (1)

ServiceBindingVersionContractRelease
UI_SALESQUOTATIONMANAGE UI_SALESQUOTATIONMANAGE V4 C1 NOT_RELEASED

Fields (55)

KeyFieldSource TableSource FieldDescription
KEY SalesQuotation ItemPartner SalesQuotation
KEY SalesQuotationItem ItemPartner SalesQuotationItem
KEY PartnerFunction ItemPartner PartnerFunction
PartnerFunctionForEdit ItemPartner PartnerFunctionForEdit
Customer ItemPartner Customer
Supplier ItemPartner Supplier
Personnel ItemPartner Personnel
ContactPerson ItemPartner ContactPerson
Partner ItemPartner Partner
ReferenceBusinessPartner ItemPartner ReferenceBusinessPartner
FullName ItemPartner FullName
SDDocumentPartnerType ItemPartner SDDocumentPartnerType
PartnerIsSpecificForSDDocItem ItemPartner PartnerIsSpecificForSDDocItem
UnloadingPointName ItemPartner UnloadingPointName
VATRegistration ItemPartner VATRegistration
virtualSDCustomerAddressIDadrnr
virtualSDContactPersonAddressIDadrnr
SDDocPartnerAddrIsDocSpecific ItemPartner SDDocPartnerAddrIsDocSpecific
AddressID ItemPartner AddressID
AddressPersonID ItemPartner AddressPersonID
AddressObjectType ItemPartner AddressObjectType
FormOfAddress
PostalCode ItemPartner PostalCode
CityName ItemPartner CityName
Country ItemPartner Country
Region ItemPartner Region
DistrictName ItemPartner DistrictName
StreetName ItemPartner StreetName
HouseNumber ItemPartner HouseNumber
POBox ItemPartner POBox
POBoxPostalCode ItemPartner POBoxPostalCode
CorrespondenceLanguage ItemPartner CorrespondenceLanguage Correspondence Language
TaxJurisdiction ItemPartner TaxJurisdiction
TransportZone ItemPartner TransportZone
InternationalPhoneNumber
InternationalMobilePhoneNumber
EmailAddress
virtualBusinessPartnerName1ad_name1
virtualBusinessPartnerName2ad_name2
virtualBusinessPartnerName3ad_name3
virtualBusinessPartnerName4ad_name4
virtualUICT_VATRegistrationboole_d
virtualUICT_UnloadingPointNameboole_d
virtualUICT_BusinessPartnerName3boole_d
virtualUICT_BusinessPartnerName4boole_d
SalesQuotationType ItemPartner SalesQuotationType
SalesOrganization ItemPartner SalesOrganization
DistributionChannel ItemPartner DistributionChannel
OrganizationDivision ItemPartner OrganizationDivision
_PartnerFunction _PartnerFunction
_FormOfAddress ItemPartner _FormOfAddress
_Country ItemPartner _Country
_Region ItemPartner _Region
_CorrespondenceLanguage ItemPartner _CorrespondenceLanguage
_TransportationZone ItemPartner _TransportationZone 
@VDM: {
  viewType: #CONSUMPTION,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
}

@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@Metadata: {
  ignorePropagatedAnnotations: true,
  allowExtensions: true
}

@ObjectModel: {
    modelingPattern:       #TRANSACTIONAL_QUERY,
    supportedCapabilities: [#TRANSACTIONAL_PROVIDER],
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    },
    query.implementedBy: 'ABAP:CL_S4RAP_STICKY_QRY'
}
@Consumption.dbHints: [ 'USE_HEX_PLAN', 'NO_SUBPLAN_SHARING' ]
@EndUserText.label: 'Sales Quotation Item Partner'
define view entity C_SlsQtanItemPartnerManageTP
  as projection on R_SalesQuotationItemPartnerTP as ItemPartner

  association [0..1] to C_PartnerFunctionUnconverted as _PartnerFunction on $projection.PartnerFunctionForEdit = _PartnerFunction.PartnerFunction
{

  key     ItemPartner.SalesQuotation,

  key     ItemPartner.SalesQuotationItem,

  key     ItemPartner.PartnerFunction,

          @ObjectModel.foreignKey.association: '_PartnerFunction'
          @ObjectModel.editableFieldFor: 'PartnerFunction'
          @Semantics.organization.role: true
          ItemPartner.PartnerFunctionForEdit,

          @ObjectModel.text.element: ['FullName']
          @Consumption.semanticObject: 'Customer'
          ItemPartner.Customer,

          @ObjectModel.text.element: ['FullName']
          @Consumption.semanticObject: 'Supplier'
          ItemPartner.Supplier,

          @ObjectModel.text.element: ['FullName']
          @Consumption.semanticObject: 'Employee'
          ItemPartner.Personnel,

          @ObjectModel.text.element: ['FullName']
          @Consumption.semanticObject: 'ContactPerson'
          ItemPartner.ContactPerson,

          ItemPartner.Partner,

          ItemPartner.ReferenceBusinessPartner,

          @Semantics.text: true
          ItemPartner.FullName,

          ItemPartner.SDDocumentPartnerType,

          ItemPartner.PartnerIsSpecificForSDDocItem,
          
          @Semantics.text: true
          ItemPartner.UnloadingPointName,

          ItemPartner.VATRegistration,
              
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
          @ObjectModel.text.element: ['FormattedPostalAddressDesc']
  virtual SDCustomerAddressID          : adrnr,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
          @ObjectModel.text.element: ['FormattedPostalAddressDesc']
  virtual SDContactPersonAddressID     : adrnr,

          @Semantics.nullValueIndicatorFor: 'PartnerIsSpecificForSDDocItem'
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_S4H_SDOC_ODATA_UTIL'
  virtual PartnerIsSpcfcForSDDocItem_H : rap_null_value_indicator,

          ItemPartner.SDDocPartnerAddrIsDocSpecific,

          @Semantics.nullValueIndicatorFor: 'SDDocPartnerAddrIsDocSpecific'
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_S4H_SDOC_ODATA_UTIL'
  virtual SDDocPartnerAddrIsDocSpcfc_H : rap_null_value_indicator,

          @ObjectModel.text.element: ['FormattedPostalAddressDesc']
          @ObjectModel.sort.enabled: false
          ItemPartner.AddressID,
          ItemPartner.AddressPersonID,
          ItemPartner.AddressObjectType,

          @Semantics.address.label: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_S4H_SDOC_ODATA_UTIL'
  virtual FormattedPostalAddressDesc   : ad_line_s,

          @ObjectModel.foreignKey.association: '_FormOfAddress'
          @Semantics.name.jobTitle: true
          cast( ItemPartner.FormOfAddress as ad_title preserving type ) as FormOfAddress,

          @Semantics.address.zipCode:true
          ItemPartner.PostalCode,

          @Semantics.address.city:true
          ItemPartner.CityName,

          @Semantics.address.country:true
          @ObjectModel.foreignKey.association: '_Country'
          ItemPartner.Country,

          @ObjectModel.foreignKey.association: '_Region'
          @Semantics.address.region: true
          ItemPartner.Region,

          ItemPartner.DistrictName,
          
          @Semantics.address.street: true
          ItemPartner.StreetName,

          @Semantics.address.streetNoNumber: true
          ItemPartner.HouseNumber,

          @Semantics.address.postBox: true
          ItemPartner.POBox,

          @Semantics.address.zipCode:true
          ItemPartner.POBoxPostalCode,

          @EndUserText.label: 'Correspondence Language'
          @ObjectModel.foreignKey.association: '_CorrespondenceLanguage'
          ItemPartner.CorrespondenceLanguage,

          ItemPartner.TaxJurisdiction,

          @ObjectModel.foreignKey.association: '_TransportationZone'
          ItemPartner.TransportZone,
          
          @Semantics.telephone.type: [#WORK]
          cast( ItemPartner.InternationalPhoneNumber as ad_telnrlg preserving type )       as InternationalPhoneNumber,

          @Semantics.telephone.type: [#CELL]
          cast( ItemPartner.InternationalMobilePhoneNumber as ad_telnrlg preserving type ) as InternationalMobilePhoneNumber,

          @Semantics.eMail.address: true
          @Semantics.eMail.type: [#WORK]
          cast( ItemPartner.EmailAddress as ad_smtpadr preserving type )                   as EmailAddress,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
  virtual BusinessPartnerName1         : ad_name1,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
  virtual BusinessPartnerName2         : ad_name2,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
  virtual BusinessPartnerName3         : ad_name3,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
  virtual BusinessPartnerName4         : ad_name4,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
  virtual UICT_VATRegistration         : boole_d,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
  virtual UICT_UnloadingPointName      : boole_d,
          
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
  virtual UICT_BusinessPartnerName3    : boole_d,
  
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_SD_QUOTATION_V4_UI_UTIL'
  virtual UICT_BusinessPartnerName4    : boole_d,
  
          // DCL

          @Consumption.hidden: true
          ItemPartner.SalesQuotationType,
          @Consumption.hidden: true
          ItemPartner.SalesOrganization,
          @Consumption.hidden: true
          ItemPartner.DistributionChannel,
          @Consumption.hidden: true
          ItemPartner.OrganizationDivision,

          //Associations

          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          ItemPartner._Item           : redirected to parent C_SalesQuotationItemManageTP,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          ItemPartner._SalesQuotation : redirected to C_SalesQuotationManageTP,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          _PartnerFunction,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          ItemPartner._FormOfAddress,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          ItemPartner._Country,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          ItemPartner._Region,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          ItemPartner._CorrespondenceLanguage,
          @ObjectModel.filter.enabled: false
          @ObjectModel.sort.enabled: false
          ItemPartner._TransportationZone
}

Learn More