R_SALESQUOTATIONITEMPARTNERTP

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA'),
  privilegedAssociations: [ '_DfltAddrRprstn' ]
}
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #L
    }
}

@ObjectModel.semanticKey: ['SalesQuotation', 'SalesQuotationItem', 'PartnerFunction']

@Metadata.ignorePropagatedAnnotations: true
@Consumption.dbHints: [ 'USE_HEX_PLAN', 'NO_SUBPLAN_SHARING' ]
@EndUserText.label: 'Sales Quotation Item Partner - TP'
define view entity R_SalesQuotationItemPartnerTP
  as select from I_SalesDocItemCompletePartner as ItemPartner
    inner join   I_SalesDocumentBasic          as SalesQuotation on  SalesQuotation.SalesDocument      = ItemPartner.SalesDocument
                                                                 and SalesQuotation.SDDocumentCategory = 'B'
  association [1..1] to R_SalesQuotationTP            as _SalesQuotation         on  $projection.SalesQuotation = _SalesQuotation.SalesQuotation

  association        to parent R_SalesQuotationItemTP as _Item                   on  $projection.SalesQuotation     = _Item.SalesQuotation
                                                                                 and $projection.SalesQuotationItem = _Item.SalesQuotationItem

  association [0..1] to I_PartnerFunction             as _PartnerFunction        on  $projection.PartnerFunctionForEdit = _PartnerFunction.PartnerFunction
  association [0..1] to I_FormOfAddress               as _FormOfAddress          on  $projection.FormOfAddress = _FormOfAddress.FormOfAddress
  association [0..1] to I_Language                    as _CorrespondenceLanguage on  $projection.CorrespondenceLanguage = _CorrespondenceLanguage.Language
  association [0..1] to I_TransportationZone          as _TransportationZone     on  $projection.transportzone = _TransportationZone.TransportZone
                                                                                 and $projection.country       = _TransportationZone.CountryCode
{

  key cast(ItemPartner.SalesDocument as sales_quotation preserving type)          as SalesQuotation,

  key cast(ItemPartner.SalesDocumentItem as sales_quotation_item preserving type) as SalesQuotationItem,

  key cast(ItemPartner.PartnerFunction as parvw_unv preserving type )             as PartnerFunction,

      @ObjectModel.foreignKey.association: '_PartnerFunction'
      cast(ItemPartner.PartnerFunction as parvw_unv preserving type )             as PartnerFunctionForEdit,

      ItemPartner.Customer,

      ItemPartner.Supplier,

      ItemPartner.Personnel,

      ItemPartner.ContactPerson,

      @ObjectModel.text.element: ['FullName']
      ItemPartner.Partner,

      @Semantics.name.fullName: true
      @Semantics.text: true
      ItemPartner.FullName,

      _PartnerFunction.SDDocumentPartnerType,

      @ObjectModel.foreignKey.association: '_FormOfAddress'
      @Semantics.name.jobTitle: true
      ItemPartner.FormOfAddress,

      @Semantics.address.street: true
      ItemPartner._OrgNamePostalAddress.StreetName,

      @Semantics.address.streetNoNumber: true
      ItemPartner._OrgNamePostalAddress.HouseNumber,

      @Semantics.address.zipCode:true
      ItemPartner._OrgNamePostalAddress.PostalCode,

      @Semantics.address.country:true
      @ObjectModel.foreignKey.association: '_Country'
      ItemPartner._OrgNamePostalAddress.Country,

      @ObjectModel.foreignKey.association: '_Region'
      @Semantics.address.region: true
      ItemPartner._OrgNamePostalAddress.Region,

      ItemPartner._OrgNamePostalAddress.DistrictName,

      @Semantics.address.city:true
      ItemPartner._OrgNamePostalAddress.CityName,

      @Semantics.address.postBox: true
      ItemPartner._OrgNamePostalAddress.POBox,

      @Semantics.address.zipCode:true
      ItemPartner._OrgNamePostalAddress.POBoxPostalCode,

      @ObjectModel.foreignKey.association: '_CorrespondenceLanguage'
      ItemPartner.CorrespondenceLanguage,

      ItemPartner._OrgNamePostalAddress.TaxJurisdiction,

      @ObjectModel.foreignKey.association: '_TransportationZone'
      ItemPartner._OrgNamePostalAddress.TransportZone,

      ItemPartner.PartnerIsSpecificForSDDocItem,

      ItemPartner.ReferenceBusinessPartner,

      ItemPartner.AddressID,

      ItemPartner.AddressPersonID,

      ItemPartner.AddressObjectType,

      ItemPartner.SDDocPartnerAddrIsDocSpecific,

      ItemPartner.VATRegistration,

      @Semantics.text: true
      ItemPartner.UnloadingPointName,

      @Semantics.telephone.type: [#WORK]
      ItemPartner.InternationalPhoneNumber,

      @Semantics.telephone.type:  [#CELL]
      ItemPartner.InternationalMobilePhoneNumber,

      @Semantics.eMail.address: true
      @Semantics.eMail.type:  [#WORK]
      ItemPartner.EmailAddress,

      @Consumption.hidden: true
      ItemPartner.SDDocPartnerAddressRefType,
      @Consumption.hidden: true
      ItemPartner.BPAddrDeterminationTransaction,
      @Consumption.hidden: true
      ItemPartner.BPRefAddressIDForDocSpcfcAddr,

      @Consumption.hidden: true
      _SalesQuotation.SalesQuotationType,
      @Consumption.hidden: true
      _SalesQuotation.SalesOrganization,
      @Consumption.hidden: true
      _SalesQuotation.DistributionChannel,
      @Consumption.hidden: true
      _SalesQuotation.OrganizationDivision,

      //    Associations

      _Item,
      _SalesQuotation,
      _PartnerFunction,
      _CorrespondenceLanguage,
      _TransportationZone,
      _FormOfAddress,
      
      ItemPartner._ContactPerson,
      ItemPartner._DfltAddrRprstn,
      ItemPartner._BusinessPartnerAddress,
      ItemPartner._BPRefAddressForDocSpcfcAddr,
      ItemPartner._OrgNamePostalAddress._Country,
      ItemPartner._OrgNamePostalAddress._Region
}