C_RequirementTrackingPurOrd

@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Purchase Orders by Requirement Tracking'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.semanticKey: [ 'Material', 'Supplier' ]
@Search.searchable: true
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.lifecycle.contract.type:#NONE
@Environment.sql.passValueForClient: true

define view entity C_RequirementTrackingPurOrd
  as select from P_RequirementTrackingPurOrd

  association [1..1] to I_PurchasingCategoryMatlGroup  as _PurchasingCategoryMatlGrp   on  $projection.MaterialGroup = _PurchasingCategoryMatlGrp.MaterialGroup

  association [0..1] to C_MM_AccountAssignCatValueHelp as _AccAssignValHelp            on  _AccAssignValHelp.AccountAssignmentCategory = $projection.AccountAssignmentCategory

  association [1..1] to I_Supplier                     as _Supplier                    on  $projection.Supplier = _Supplier.Supplier

  association [1..1] to I_PurchasingOrganization       as _PurchasingOrganization      on  $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization

  association [1..1] to I_PurchasingGroup              as _PurchasingGroup             on  $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup

{
      @EndUserText.label: 'Purchase Order'
      @Consumption.semanticObject: 'PurchaseOrder'
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
  key PurchaseOrder,

      @EndUserText.label: 'Item'
      @Consumption.semanticObject: 'PurchaseOrderItem'
  key PurchaseOrderItem,

      @EndUserText.label: 'Purchase Order Item'
      @UI.lineItem: [ {position: 10 }]
      FormattedPurchaseOrderItem,

      @EndUserText.label: 'Requirement Tracking Number'
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 1 }
      RequirementTracking, //Req. Tracking Number


      @UI.lineItem: [ {position: 20 }]
      @Consumption.semanticObject: 'Material'
      @ObjectModel.foreignKey.association: '_Material'
      Material,

      @UI.lineItem: [ {position: 50 }]
      @EndUserText.label: 'Order Quantity'
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      OrderQuantity,

      @UI.hidden: true
      PurchaseOrderQuantityUnit, //Order Unit


      @UI.hidden: true
      OrderPriceUnit,

      @UI.lineItem: [ {position: 60 }]
      @EndUserText.label: 'Net Order Value'
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      NetAmount,

      @UI.hidden: true
      @EndUserText.label: 'Document Currency'
      DocumentCurrency,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 1 }
      @UI.lineItem: [ {position: 30 }]
      @Consumption.semanticObject: 'Supplier'
      @ObjectModel.foreignKey.association: '_Supplier'
      Supplier,


      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 1 }
      @ObjectModel.foreignKey.association: '_MaterialGroup'
      MaterialGroup,

      PurchasingText, //short text

   
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 1 }
      @EndUserText.label: 'Purchasing Organization'
      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
      PurchasingOrganization, //Purch. Organization


      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 1 }
      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      PurchasingGroup,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 1 }
      @ObjectModel.foreignKey.association: '_Plant'
      Plant,

      @EndUserText.label: 'Account Assignment Category'
      @ObjectModel.foreignKey.association: '_AccAssignValHelp'
      AccountAssignmentCategory, //Acct Assignment Cat.


      @ObjectModel.foreignKey.association: '_CompanyCode'
      CompanyCode,

      @ObjectModel.foreignKey.association: '_StorageLocation'
      StorageLocation,

      @ObjectModel.text.element:  [ 'PurgCatName' ]
      PurchasingCategory,

      @Semantics.text: true
      @UI.hidden: true
      @EndUserText: {
          label: 'Purchasing Category Name'
      }
      PurgCatName,

      @EndUserText.label: 'Purchasing Document Type'
      @ObjectModel: { text.element:  [ 'PurchasingDocumentTypeName' ] }
      PurchasingDocumentType,

      @EndUserText.label: 'Purchasing Document Category'
      PurchasingDocumentCategory,

      @UI.hidden: true
      @EndUserText: {
          label: 'Document Type Description'
      }
      PurchasingDocumentTypeName,

      @EndUserText.label: 'Item Category'
      @ObjectModel: { text.element:  [ 'PurgDocItemCategoryName' ] }
      PurgDocExternalItemCategory, //as PurchasingDocumentItemCategory,


      @UI.hidden: true
      PurchaseOrderItemCategory, //Item category


      @UI.hidden: true
      @EndUserText: {
          label: 'Item Category Text'
      }
      PurgDocItemCategoryName,

      PurchaseOrderDate,


      @ObjectModel.text.element:  [ 'UserDescription' ]
      @UI.hidden: true
      CreatedByUser,

      @EndUserText.label: 'Created By'
      @Semantics.text: true
      UserDescription,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      NetPriceAmount,

      @UI.lineItem: [ {position: 40 }, {criticality: 'DueDateCriticality' }, {criticalityRepresentation: #WITHOUT_ICON }]
      ScheduleLineDeliveryDate,

      @UI.hidden: true
      DueDateCriticality,

      @UI.lineItem: [ {position: 90 }]
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      OpenPurchaseOrderQuantity,

      @EndUserText.label: 'Supplier Block Status'
      PurchasingIsBlockedForSupplier,

      @Semantics.quantity.unitOfMeasure: 'OrderPriceUnit'
      @EndUserText.label: 'Price Unit'
      NetPriceQuantity,

      CreationDate,

      @EndUserText.label: 'Delivered Quantity'
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      GoodsReceiptQty,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      @UI.lineItem: [ {position: 70 }]
      StillToBeDeliveredQuantity,

      @EndUserText.label: 'Delivered Value'
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      GoodsReceiptAmountInDspCrcy,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      StillToBeDeliveredValue,

      @EndUserText.label: 'Invoice Quantity'
      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      InvoiceReceiptQty,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderQuantityUnit'
      StillToInvoiceQuantity,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      InvoicedAmountInDspCurrency,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      @UI.lineItem: [ {position: 80 }]
      StillToInvoiceValue,

      _PurchasingCategoryMatlGrp,
      _AccAssignValHelp,
      _Material,
      _MaterialGroup,
      _Plant,
      _CompanyCode,
      _StorageLocation,
      _Supplier,
      _PurchasingOrganization,
      _PurchasingGroup


}