C_QltyNotificationTaskFDP

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUserContactCard', '_LastChangedByUserContactCard', '_StsObjConcatActiveStsILL' ]
@EndUserText.label: 'Task Data of Quality Notification'
@VDM: {
    viewType: #CONSUMPTION,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel: {
    representativeKey: 'NotificationTask',
    supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #OUTPUT_FORM_DATA_PROVIDER ],
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #C }
}
@Analytics.technicalName: 'CQNOTIFTSKFDP'

define view entity C_QltyNotificationTaskFDP
  as select from I_NotificationTask

  association [0..1] to I_QltyNotification             as _Notification                 on  $projection.QualityNotification = _Notification.QualityNotification
  association [0..1] to I_UserContactCard              as _ResponsiblePersonContactCard on  $projection.ResponsiblePerson = _ResponsiblePersonContactCard.ContactCardID
  association [0..1] to I_QltyTskCodeGroup             as _QltyTskCodeGroup             on  $projection.QualityTaskCodeGroup = _QltyTskCodeGroup.QualityTaskCodeGroup
  association [0..1] to I_QltyTskCode                  as _QltyTskCode                  on  $projection.QualityTaskCodeGroup = _QltyTskCode.QualityTaskCodeGroup
                                                                                        and $projection.QualityTaskCode      = _QltyTskCode.QualityTaskCode

  association [0..*] to I_QltyNotificationTaskLongText as _QltyNotificationTaskLongText on  $projection.QualityNotification = _QltyNotificationTaskLongText.QualityNotification
                                                                                        and $projection.NotificationTask    = _QltyNotificationTaskLongText.NotificationTask

// === Extension

    association [1..1] to E_NotificationTask           as _Extension                    on  $projection.QualityNotification  = _Extension.Notification
                                                                                        and $projection.NotificationTask     = _Extension.NotificationTask


{
  key Notification                                 as QualityNotification,
  key NotificationTask,
      QualityTaskOrigin,
      NotificationTaskText,
      IsDeleted,
      _Notification.NotifProcessingPhase,
      NotifTaskPlannedStartDate,
      NotifTaskPlannedStartTime,
      NotifTaskPlannedEndDate,
      NotifTaskPlannedEndTime,
      StatusObject,
      NotifTaskTimeZone,
      NotifTaskCompletedByUser,
      NotifTaskCompletionDate,
      NotifTaskCompletionTime,
      NotifTaskResubmissionDate,
      NotifTaskResubmissionTime,
      ResponsiblePersonFunctionCode,
      ResponsiblePerson,
      NotificationTaskSortNumber,
      NotificationItem,
      _Notification.NotificationType,
      _Notification.Plant,
      _Notification.IsBusinessPurposeCompleted,
      I_NotificationTask.NotificationTaskCatalog   as QualityTaskCodeCatalog,
      @ObjectModel.foreignKey.association: '_QltyTskCodeGroup'
      I_NotificationTask.NotificationTaskCodeGroup as QualityTaskCodeGroup,
      @ObjectModel.foreignKey.association: '_QltyTskCode'
      I_NotificationTask.NotificationTaskCode      as QualityTaskCode,
      ChangedDateTime,
      CreatedByUser,
      CreationDate,
      CreationTime,
      LastChangedByUser,
      LastChangeDate,
      LastChangeTime,

      case I_NotificationTask._PartnerFunction.SDDocumentPartnerType
      when 'AP' then concat( I_NotificationTask._ContactPerson.FirstName, I_NotificationTask._ContactPerson.LastName)
      when 'KU' then I_NotificationTask._Customer.CustomerFullName
      when 'LI' then I_NotificationTask._Supplier.SupplierFullName
      when 'PE' then I_NotificationTask._Employee.PersonFullName
      when 'US' then _ResponsiblePersonContactCard.UserDescription
      else '' end                                  as ResponsibleFullName,

      /* Associations */
      _ContactPerson,
      _CreatedByUserContactCard,
      _Customer,
      _Employee,
      _ResponsiblePersonContactCard,
      _LastChangedByUserContactCard,
      _Notification,
      _PartnerFunction,
      _QltyNotificationTaskLongText,
      _QltyTskCode,
      _QltyTskCodeGroup,
      _QualityTaskOrigin,
      _StsObjConcatActiveStsILL,
      _Supplier

}