I_NOTIFICATIONTASK

CDS View

Notification Task

I_NOTIFICATIONTASK is a CDS View in S/4HANA. Notification Task. It contains 45 fields. 6 CDS views read from this table.

Used by 6 CDS view(s) 45 fields

CDS Views using this table (6)

ViewTypeJoinVDMDescription
C_QltyNotificationTaskFDP view_entity from CONSUMPTION Task Data of Quality Notification
I_NotifItemAffectedObjLastTask view_entity inner COMPOSITE Last Task for affected object
I_NotifTaskTimeStamps view_entity from COMPOSITE Notification Task Time Stamps
I_QltyNotificationTask view_entity from COMPOSITE Quality Notification Task
I_QltyNotificationTaskVH view from COMPOSITE Search for Quality Notification Task
P_NotifItemAffcdObjActnParam view_entity from COMPOSITE Last action change of affected object

Fields (45)

KeyField CDS FieldsUsed in Views
KEY Notification Notification,QualityNotification 4
KEY NotificationItem NotificationItem 3
KEY NotificationTask NotificationTask 5
_ContactPerson _ContactPerson 2
_CreatedByUserContactCard _CreatedByUserContactCard 1
_Customer _Customer 2
_Employee _Employee 2
_LastChangedByUserContactCard _LastChangedByUserContactCard 1
_Notification _Notification 1
_PartnerFunction _PartnerFunction 2
_QualityTaskOrigin _QualityTaskOrigin 2
_StsObjConcatActiveStsILL _StsObjConcatActiveStsILL 1
_Supplier _Supplier 2
ChangedDateTime ChangedDateTime 3
CreatedByUser CreatedByUser 1
CreationDate CreationDate 3
CreationTime CreationTime 2
IsDeleted IsDeleted 1
LastChangeDate LastChangeDate 2
LastChangedByUser LastChangedByUser 1
LastChangeTime LastChangeTime 2
NotificationCauseID NotificationCauseID 1
NotificationTaskCatalog NotificationTaskCatalog,QualityTaskCodeCatalog 2
NotificationTaskCode NotificationTaskCode,QualityTaskCode 3
NotificationTaskCodeGroup NotificationTaskCodeGroup,QualityTaskCodeGroup 2
NotificationTaskSortNumber NotificationTaskSortNumber 1
NotificationTaskText NotificationTaskText 2
NotifTaskCompletedByUser NotifTaskCompletedByUser 1
NotifTaskCompletionDate NotifTaskCompletionDate 3
NotifTaskCompletionTime NotifTaskCompletionTime 3
NotifTaskPlannedEndDate NotifTaskPlannedEndDate 3
NotifTaskPlannedEndTime NotifTaskPlannedEndTime 3
NotifTaskPlannedStartDate NotifTaskPlannedStartDate 1
NotifTaskPlannedStartTime NotifTaskPlannedStartTime 1
NotifTaskResubmissionDate NotifTaskResubmissionDate 3
NotifTaskResubmissionTime NotifTaskResubmissionTime 3
NotifTaskTimeZone NotifTaskTimeZone 2
QltyTaskFllwUpActionSts QltyTaskFllwUpActionSts 2
QltyTaskFollowUpAction QltyTaskFollowUpAction 1
QltyTaskTimeBasedEffort QltyTaskTimeBasedEffort 1
QltyTaskTimeBasedEffortUoM QltyTaskTimeBasedEffortUoM 1
QualityTaskOrigin QualityTaskOrigin 2
ResponsiblePerson ResponsiblePerson 2
ResponsiblePersonFunctionCode ResponsiblePersonFunctionCode 1
StatusObject StatusObject 1 
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUserContactCard', '_LastChangedByUserContactCard', '_StsObjConcatActiveStsILL']

@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@EndUserText.label: 'Notification Task'
@ObjectModel: {
    representativeKey: 'NotificationTask',
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #A }
}
@Analytics.technicalName: 'INOTIFTSK'
define view entity I_NotificationTask
  as select from qmsm
  //=== Assocation to notification specific views

  association [0..1] to I_Notification               as _Notification                 on  $projection.Notification = _Notification.Notification
  association [0..*] to I_NotifTaskFllwUpActionParam as _NotifTaskFllwUpActionParam   on  $projection.Notification     = _NotifTaskFllwUpActionParam.Notification
                                                                                      and $projection.NotificationTask = _NotifTaskFllwUpActionParam.NotificationTask

  association [1..1] to I_QltyTaskOrigin             as _QualityTaskOrigin            on  $projection.QualityTaskOrigin = _QualityTaskOrigin.QualityTaskOrigin
  association [0..1] to I_BusinessPartner            as _QualityTaskProcessor         on  $projection.QualityTaskProcessor = _QualityTaskProcessor.BusinessPartner
  association [0..1] to I_PartnerFunction            as _PartnerFunction              on  $projection.ResponsiblePersonFunctionCode = _PartnerFunction.PartnerFunction
  association [0..1] to I_UserContactCard            as _CreatedByUserContactCard     on  $projection.CreatedByUser = _CreatedByUserContactCard.ContactCardID
  association [0..1] to I_UserContactCard            as _LastChangedByUserContactCard on  $projection.LastChangedByUser = _LastChangedByUserContactCard.ContactCardID
  association [0..1] to I_StsObjConcatActiveStsILL   as _StsObjConcatActiveStsILL     on  $projection.StatusObject = _StsObjConcatActiveStsILL.StatusObject
                                                                                   
  /* Associations - DPP */
  association [0..1] to I_ContactPerson              as _ContactPerson                on  _ContactPerson.ContactPerson = $projection.ResponsiblePerson
  association [0..1] to I_Customer                   as _Customer                     on  _Customer.Customer = $projection.ResponsiblePerson
  association [0..1] to I_WorkforcePerson            as _Employee                     on  _Employee.PersonExternalID = $projection.ResponsiblePerson
  association [0..1] to I_Supplier                   as _Supplier                     on  _Supplier.Supplier = $projection.ResponsiblePerson

{
      //=== Key Fields

      @ObjectModel.foreignKey.association: '_Notification'
  key qmsm.qmnum                                             as Notification,
  key qmsm.manum                                             as NotificationTask,

      //=== Common Fields

      @ObjectModel.foreignKey.association: '_QualityTaskOrigin'
      qmsm.taskorigin                                        as QualityTaskOrigin,
      qmsm.tasktype                                          as QualityTaskType,
      @ObjectModel.foreignKey.association: '_QualityTaskProcessor'
      qmsm.processor                                         as QualityTaskProcessor,
      @Semantics.text: true
      qmsm.matxt                                             as NotificationTaskText,
      qmsm.kzloesch                                          as IsDeleted,
      qmsm.pster                                             as NotifTaskPlannedStartDate,
      qmsm.pstur                                             as NotifTaskPlannedStartTime,
      qmsm.peter                                             as NotifTaskPlannedEndDate,
      qmsm.objnr                                             as StatusObject,
      qmsm.petur                                             as NotifTaskPlannedEndTime,
      qmsm.tzonsm                                            as NotifTaskTimeZone,
      qmsm.erlnam                                            as NotifTaskCompletedByUser,
      qmsm.erldat                                            as NotifTaskCompletionDate,
      qmsm.erlzeit                                           as NotifTaskCompletionTime,
      qmsm.wdvdat                                            as NotifTaskResubmissionDate,
      qmsm.wdvzeit                                           as NotifTaskResubmissionTime,
      @ObjectModel.foreignKey.association: '_PartnerFunction'
      cast(qmsm.parvw  as vdm_q_parvw_vera preserving type ) as ResponsiblePersonFunctionCode,
      qmsm.parnr                                             as ResponsiblePerson,
      qmsm.qsmnum                                            as NotificationTaskSortNumber,
      qmsm.fenum                                             as NotificationItem,
      qmsm.urnum                                             as NotificationCauseID,
      qmsm.mnkat                                             as NotificationTaskCatalog,
      qmsm.mngrp                                             as NotificationTaskCodeGroup,
      qmsm.mncod                                             as NotificationTaskCode,
      qmsm.folgeact                                          as QltyTaskFollowUpAction,
      qmsm.statfoa                                           as QltyTaskFllwUpActionSts,
      
      //====Time Recording for Task

      @Semantics.quantity.unitOfMeasure: 'QltyTaskTimeBasedEffortUoM'
      qmsm.timebasedeffort                                   as QltyTaskTimeBasedEffort,
      qmsm.timebasedeffortuom                                as QltyTaskTimeBasedEffortUoM,

      //=== Administrative Data

      qmsm.changeddatetime                                   as ChangedDateTime,
      @ObjectModel.foreignKey.association: '_CreatedByUserContactCard'
      qmsm.ernam                                             as CreatedByUser,
      @Semantics.systemDate.createdAt: true
      qmsm.erdat                                             as CreationDate,
      qmsm.erzeit                                            as CreationTime,
      @ObjectModel.foreignKey.association: '_LastChangedByUserContactCard'
      qmsm.aenam                                             as LastChangedByUser,
      @Semantics.systemDate.lastChangedAt: true
      qmsm.aedat                                             as LastChangeDate,
      qmsm.aezeit                                            as LastChangeTime,

      //=== Expose Associations

      _Notification,
      _NotifTaskFllwUpActionParam,
      _QualityTaskOrigin,
      _QualityTaskProcessor,
      _CreatedByUserContactCard,
      _LastChangedByUserContactCard,
      _StsObjConcatActiveStsILL,
      _PartnerFunction,
      _ContactPerson,
      _Employee,
      _Supplier,
      _Customer

}

Learn More