C_PurgInfoRecordOrgLevels

DDL: C_PURGINFORECORDORGLEVELS SQL: CPURGINFRECORG Type: view CONSUMPTION Package: ODATA_MM_PUR_INFOREC_FS

Organization Level

C_PurgInfoRecordOrgLevels is a Consumption CDS View that provides data about "Organization Level" in SAP S/4HANA. It reads from 1 data source (I_PurgInfoRecdOrgPlantData) and exposes 19 fields with key fields PurchasingInfoRecord, PurchasingOrganization, PurchasingInfoRecordCategory, Plant. Part of development package ODATA_MM_PUR_INFOREC_FS.

1 data source(s) 19 fields

Data Sources (1)

SourceAliasJoin Type
I_PurgInfoRecdOrgPlantData I_PurgInfoRecdOrgPlantData from

Annotations (11)

NameValueLevelField
AbapCatalog.sqlViewName CPURGINFRECORG view
AbapCatalog.compiler.compareFilter true view
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Organization Level view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MASTER view
ClientHandling.algorithm #SESSION_VARIABLE view
UI.headerInfo.typeName Purchasing Organization view
UI.headerInfo.typeNamePlural Purchasing Organization view

Fields (19)

KeyFieldSource TableSource FieldDescription
KEY PurchasingInfoRecord PurchasingInfoRecord
KEY PurchasingOrganization PurchasingOrganization
KEY PurchasingInfoRecordCategory PurchasingInfoRecordCategory
KEY Plant Plant
PurchasingGroup PurchasingGroup
Currency Currency
StandardPurchaseOrderQuantity StandardPurchaseOrderQuantity
MaterialPlannedDeliveryDurn MaterialPlannedDeliveryDurn
NetPriceAmount NetPriceAmount
MaterialPriceUnitQty MaterialPriceUnitQty
PurchaseOrderPriceUnit PurchaseOrderPriceUnit
PurchasingOrganizationName _PurchasingOrganization PurchasingOrganizationName
PurchasingGroupName _PurchasingGroup PurchasingGroupName
PlantName _Plant PlantName
_Currency _Currency
_Plant _Plant
_PurchaseOrderPriceUnit _PurchaseOrderPriceUnit
_PurchasingGroup _PurchasingGroup
_PurchasingOrganization _PurchasingOrganization 
@AbapCatalog.sqlViewName: 'CPURGINFRECORG'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Organization Level'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE
@UI.headerInfo: {
      typeName: 'Purchasing Organization',
      typeNamePlural: 'Purchasing Organization'}

define view C_PurgInfoRecordOrgLevels as select from I_PurgInfoRecdOrgPlantData

{

  key PurchasingInfoRecord,
 
  @ObjectModel.foreignKey.association: '_PurchasingOrganization' //Inserted by VDM CDS Suite Plugin 

  @ObjectModel.text.element:  [ 'PurchasingOrganizationName' ] 
  @UI.lineItem: { 
        position: 10, 
        label: 'Purchasing Organization', label_asOtr: '40F2E93067D51ED58EEEC1A60CED08B2',
        importance: #HIGH  }
  key PurchasingOrganization,

  key PurchasingInfoRecordCategory,

  @ObjectModel.foreignKey.association: '_Plant' //Inserted by VDM CDS Suite Plugin

  @ObjectModel.text.element:  [ 'PlantName' ] 
  @UI.lineItem: { 
        position: 30, 
        importance: #HIGH }
  key Plant,

  @ObjectModel.foreignKey.association: '_PurchasingGroup' //Inserted by VDM CDS Suite Plugin

  @Semantics.text: true 
  @UI.lineItem: { 
        position: 20, 
        label: 'Purchasing Group', label_asOtr: '40F2E93067D51ED58EEED083DE2A08EB',
        importance: #HIGH }
  @ObjectModel.text.element:  [ 'PurchasingGroupName' ] 
  PurchasingGroup,
  
  @Semantics.currencyCode:true 
  //@ObjectModel.foreignKey.association: '_Currency' //Inserted by VDM CDS Suite Plugin

  Currency, 
  
  @Semantics.quantity.unitOfMeasure: 'PurchaseOrderPriceUnit'
  @DefaultAggregation: #NONE 
  @UI.lineItem: { 
        position: 50, 
        importance: #HIGH }
  StandardPurchaseOrderQuantity, 
  
  @UI.lineItem: { 
        position: 40, 
        label: 'Planned Delivery Time in days', label_asOtr: '40F2E93067D51ED58EEED63F11C708EE',
        importance: #HIGH }
  MaterialPlannedDeliveryDurn,                          // Planned Delivery Time in days


  @Semantics.amount.currencyCode: 'Currency'
  @DefaultAggregation: #NONE
  @UI.lineItem: { 
        position: 60, 
        label: 'Net Price', label_asOtr: '40F2E93067D51ED58EEEDE40CDCCA926',
        importance: #HIGH }
  NetPriceAmount,                                       // Net Price

  
  @Semantics.quantity.unitOfMeasure: 'PurchaseOrderPriceUnit'
  @DefaultAggregation: #NONE
  @UI.lineItem: { 
        position: 70, 
        importance: #HIGH }
  MaterialPriceUnitQty,                                 // Price unit

  
  @Semantics.unitOfMeasure: true 
  @ObjectModel.foreignKey.association: '_PurchaseOrderPriceUnit' //Inserted by VDM CDS Suite Plugin

  PurchaseOrderPriceUnit, 

 /* Associations */
  @Semantics.text: true
  _PurchasingOrganization.PurchasingOrganizationName,   // Purchazing Organisation 

  
  _PurchasingGroup.PurchasingGroupName,                 // Purchasing Group

  
  _Plant.PlantName,                                     // Plant Name

  
  _Currency, 
  
  _Plant, 
  
  _PurchaseOrderPriceUnit, 
  
  _PurchasingGroup, 
  
  _PurchasingOrganization 
     
}

Learn More