I_PURGINFORECDORGPLANTDATA

@AbapCatalog.sqlViewName: 'IINFORECORGDATA'
@EndUserText.label: 'Info Record Purch. Org. and Plant Data'
@VDM.viewType : #BASIC
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

define view I_PurgInfoRecdOrgPlantData
  as select from eine

  association [0..1] to I_PurchasingOrganization  as _PurchasingOrganization  on $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization

  association [0..1] to I_Plant                   as _Plant                   on $projection.Plant = _Plant.Plant

  association [0..1] to I_UnitOfMeasure           as _PurchaseOrderPriceUnit  on $projection.PurchaseOrderPriceUnit = _PurchaseOrderPriceUnit.UnitOfMeasure

  association [0..1] to I_Currency                as _Currency                on $projection.Currency = _Currency.Currency

  association [0..1] to I_PurchasingGroup         as _PurchasingGroup         on $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup

  association [0..*] to I_TaxCode                 as _TaxCode                 on $projection.TaxCode = _TaxCode.TaxCode

  association [0..1] to I_IncotermsClassification as _IncotermsClassification on $projection.IncotermsClassification = _IncotermsClassification.IncotermsClassification

  association [0..1] to I_User                    as _CreatedByUser           on $projection.CreatedByUser = _CreatedByUser.UserID
  
  association [0..1] to I_Country                 as _Country                 on $projection.TaxCountry = _Country.Country
{

  key eine.infnr                                                     as PurchasingInfoRecord,

      @ObjectModel.foreignKey.association: '_PurchasingOrganization'
  key eine.ekorg                                                     as PurchasingOrganization,

  key eine.esokz                                                     as PurchasingInfoRecordCategory,

      @ObjectModel.foreignKey.association: '_Plant'
  key eine.werks                                                     as Plant,

      //    @ObjectModel.foreignKey.association: '_CreatedByUser'

      eine.ernam                                                     as CreatedByUser, 
       
      eine.erdat                                                     as CreationDate,

      eine.loekz                                                     as IsMarkedForDeletion,

      @ObjectModel.foreignKey.association: '_PurchasingGroup'
      eine.ekgrp                                                     as PurchasingGroup,

      @Semantics.currencyCode:true
      @ObjectModel.foreignKey.association: '_Currency'
      eine.waers                                                     as Currency,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderPriceUnit'
//      @DefaultAggregation: #NONE 

      eine.minbm                                                     as MinimumPurchaseOrderQuantity,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderPriceUnit'
//      @DefaultAggregation: #NONE

      eine.norbm                                                     as StandardPurchaseOrderQuantity,

      eine.aplfz                                                     as MaterialPlannedDeliveryDurn,

      eine.uebto                                                     as OverdelivTolrtdLmtRatioInPct,

      eine.untto                                                     as UnderdelivTolrtdLmtRatioInPct,

      eine.uebtk                                                     as UnlimitedOverdeliveryIsAllowed,

      eine.ebeln                                                     as LastReferencingPurchaseOrder,

      eine.ebelp                                                     as LastReferencingPurOrderItem,

      @Semantics.amount.currencyCode: 'Currency'
//      @DefaultAggregation: #NONE

      eine.netpr                                                     as NetPriceAmount,
      
//      @Feature: 'FT_IR_EFFECTIVE_PRICE'

      eine.effpr                                                     as PurgInfoRecdEffctvPrc,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderPriceUnit'
//      @DefaultAggregation: #NONE

      eine.peinh                                                     as MaterialPriceUnitQty,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_PurchaseOrderPriceUnit'
      eine.bprme                                                     as PurchaseOrderPriceUnit,

      @Semantics.businessDate.to
      eine.prdat                                                     as PriceValidityEndDate,

      eine.bpumz                                                     as OrderPriceUnitToOrderUnitNmrtr,

      eine.bpumn                                                     as OrdPriceUnitToOrderUnitDnmntr,

      eine.webre                                                     as InvoiceIsGoodsReceiptBased,

//      @ObjectModel.foreignKey.association: '_TaxCode'

      eine.mwskz                                                     as TaxCode,
      
      eine.txdat_from                                                as TimeDependentTaxValidFromDate,
      
      @ObjectModel.foreignKey.association: '_Country'
      eine.tax_country                                               as TaxCountry,

      @ObjectModel.foreignKey.association: '_IncotermsClassification'
      eine.inco1                                                     as IncotermsClassification,

      eine.inco2                                                     as IncotermsTransferLocation,

      eine.inco2_l                                                   as IncotermsLocation1,
      
      cast( eine.inco2_key as /scmtms/inc_loc_1_key_nc  preserving type )  as IncotermsSupChnLoc1AddlUUID , 
      
      eine.inco3_l                                                   as IncotermsLocation2,
      
      cast( eine.inco3_key as /scmtms/inc_loc_2_key_nc preserving type ) as IncotermsSupChnLoc2AddlUUID,
      
      cast( eine.inco4_key as /scmtms/inc_dv_plce_dst_key_nc preserving type ) as IncotermsSupChnDvtgLocAddlUUID,

      @Semantics.quantity.unitOfMeasure: 'PurchaseOrderPriceUnit'
//      @DefaultAggregation: #NONE

      eine.bstma                                                     as MaximumOrderQuantity,

      eine.aut_source                                                as IsRelevantForAutomSrcg,

      eine.incov                                                     as IncotermsVersion,

      eine.angnr                                                     as SupplierQuotation,

      eine.angdt                                                     as SupplierQuotationDate,

      eine.mhdrz                                                     as MinRemainingShelfLife,

      eine.evers                                                     as ShippingInstruction,

      eine.xersn                                                     as IsEvaluatedRcptSettlmtAllowed,

      eine.spe_cre_ref_doc                                           as IsPurOrderAllwdForInbDeliv,

      eine.kzabs                                                     as IsOrderAcknRqd,

      eine.bstae                                                     as SupplierConfirmationControlKey,

      eine.rdprf                                                     as MaterialRoundingProfile,

      eine.staging_time                                              as MaterialStagingTime,

      eine.megru                                                     as ProductUnitGroup,

      eine.vendor_rma_req                                            as IsRetMatlAuthznRqdBySupplier,

      eine.sktof                                                     as IsCashDiscountGranted,

      eine.ekkol                                                     as MaterialConditionGroup,

      eine.meprf                                                     as PricingDateControl,

      eine.datlb                                                     as PurchasingDocumentDate,

      eine.iprkz                                                     as ShelfLifeExpirationDatePeriod,

      eine.iseopblocked                                              as IsEndOfPurposeBlocked,
//      2308 Addition: NoMText in Purchasing Info Record       

      eine.mtxno                                                     as MatlMstrTxtIsNotRlvtForPOItm,
      
      eine.verid                                                     as ProductionVersion,
      
      eine.exprf                                                     as PurgDocExportImportProcedure,
      

      _PurchasingOrganization,
      _Plant,
      _PurchaseOrderPriceUnit,
      _Currency,
      _PurchasingGroup,
      _TaxCode,
      _IncotermsClassification,
      _CreatedByUser,
      _Country

}
where
     iseopblocked <> 'X'
     or iseopblocked = ''