C_PurchaseRequisitionValueHelp

@AbapCatalog.sqlViewName: 'CPURREQN_VH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@ObjectModel.semanticKey: ['PurchaseRequisition', 'PurchaseRequisitionItem']
@ObjectModel.representativeKey: 'PurchaseRequisition'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@EndUserText.label: 'Purchase Requisition Value Help'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.dataCategory: #VALUE_HELP
@Consumption.ranked: true
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

define view C_PurchaseRequisitionValueHelp
  as select from I_Purchaserequisitionitem as PurchaseRequisitionItem

  association [0..1] to I_MaterialText              as _MaterialText            on  $projection.Material   = _MaterialText.Material
                                                                                and _MaterialText.Language = $session.system_language

  association [0..1] to I_Plant                     as _Plant                   on  $projection.Plant = _Plant.Plant

  association [0..1] to C_PurReqnProcessingStatus   as _PurReqnProcessingStatus on  _PurReqnProcessingStatus.DomainValue = $projection.ProcessingStatus

  association [0..1] to C_PurchasingOrgValueHelp    as _PurchasingOrgValueHelp  on  _PurchasingOrgValueHelp.PurchasingOrganization = $projection.PurchasingOrganization

  association [0..1] to C_PurchasingGroupValueHelp  as _PurchasingGrpValueHelp  on  _PurchasingGrpValueHelp.PurchasingGroup = $projection.PurchasingGroup

  association [0..1] to C_PurchaseReqnTypeVH        as _PurchaseReqnTypeVH      on  _PurchaseReqnTypeVH.PurchaseRequisitionType = $projection.PurchaseRequisitionType

  association [0..1] to C_MM_MaterialGroupValueHelp as _MaterialGroupValueHelp  on  _MaterialGroupValueHelp.MaterialGroup = $projection.MaterialGroup

  association [0..1] to I_Supplier                  as _Supplier                on  _Supplier.Supplier = $projection.FixedSupplier

  association [1..1] to I_UnitOfMeasure             as _UnitOfMeasure           on  $projection.BaseUnit = _UnitOfMeasure.UnitOfMeasure

{

      @Search: { defaultSearchElement: true, ranking: #HIGH }
  key PurchaseRequisitionItem.PurchaseRequisition         as PurchaseRequisition,

      @Search: { defaultSearchElement: true, ranking: #HIGH }
      @EndUserText.label: 'Requisition Item'
  key PurchaseRequisitionItem.PurchaseRequisitionItem     as PurchaseRequisitionItem,

      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      PurchaseRequisitionItem.PurchaseRequisitionItemText as PurchaseRequisitionItemText,

      @Consumption.filter.hidden: true
      @Semantics.text: true
      _PurReqnProcessingStatus.DomainText                 as ProcessingStatusName,

      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      @ObjectModel: { text.element:  [ 'ProcessingStatusName' ] }
      @UI.textArrangement: #TEXT_FIRST
      @EndUserText.label: 'Processing Status'
      PurchaseRequisitionItem.ProcessingStatus            as ProcessingStatus,

      @ObjectModel: { text.element:  [ 'MaterialName' ] }
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_MM_MaterialValueHelp', element : 'Material' } }]
      @UI.textArrangement: #TEXT_FIRST
      PurchaseRequisitionItem.Material                    as Material,

      @Consumption.filter.hidden: true
      @ObjectModel: { text.element:  [ 'MaterialGroupName' ] }
      @UI.textArrangement: #TEXT_FIRST
      PurchaseRequisitionItem.MaterialGroup,

      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      @ObjectModel: { text.element:  [ 'PlantName' ] }
      @UI.textArrangement: #TEXT_FIRST
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_MM_PlantValueHelp', element: 'Plant' } }]
      PurchaseRequisitionItem.Plant                       as Plant,

      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_PurchasingOrgValueHelp', element: 'PurchasingOrganization' } }]
      @ObjectModel: { text.element:  [ 'PurchasingOrganizationName' ] }
      @UI.textArrangement: #TEXT_FIRST
      PurchaseRequisitionItem.PurchasingOrganization,

      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      @Consumption.valueHelpDefinition: [{ entity: { name : 'C_PurchasingGroupValueHelp', element : 'PurchasingGroup' } }]
      @ObjectModel: { text.element:  [ 'PurchasingGroupName' ] }
      @UI.textArrangement: #TEXT_FIRST
      PurchaseRequisitionItem.PurchasingGroup,

      @Consumption.filter.hidden: true
      @ObjectModel: {text: {element: [ 'PurchasingDocumentTypeName' ]}}
      @UI.textArrangement: #TEXT_FIRST
      PurchaseRequisitionItem.PurchaseRequisitionType,

      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      PurchaseRequisitionItem.RequirementTracking,

      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      @ObjectModel.text.element:['SupplierName']
      @Consumption.valueHelpDefinition: [{entity: {name: 'C_MM_SupplierValueHelp', element: 'Supplier'}}]
      @UI.textArrangement: #TEXT_FIRST
      PurchaseRequisitionItem.FixedSupplier,

      @Consumption.filter.hidden: true
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      @DefaultAggregation: #NONE
      PurchaseRequisitionItem.RequestedQuantity,

      @Consumption.filter.hidden: true
      @ObjectModel.foreignKey.association: '_UnitOfMeasure'
      @Semantics.unitOfMeasure: true
      @UI.hidden: true
      PurchaseRequisitionItem.BaseUnit,

      @Consumption.filter.hidden: true
      PurchaseRequisitionItem.DeliveryDate,

      @Consumption.filter.hidden: true
      @Semantics.text: true
      _Plant.PlantName,
      @Consumption.filter.hidden: true
      _UnitOfMeasure,

      @Consumption.filter.hidden: true
      @Semantics.text: true
      _MaterialText.MaterialName,
      @Consumption.filter.hidden: true
      _PurchasingOrgValueHelp,
      @Consumption.filter.hidden: true
      _PurchasingGrpValueHelp,
      @Consumption.filter.hidden: true
      _PurchaseReqnTypeVH,
      @Consumption.filter.hidden: true
      _MaterialGroupValueHelp,
      @Consumption.filter.hidden: true
      _PurchasingGrpValueHelp.PurchasingGroupName,
      @Consumption.filter.hidden: true
      _PurchasingOrgValueHelp.PurchasingOrganizationName,
      @Consumption.filter.hidden: true
      _PurchaseReqnTypeVH.PurchasingDocumentTypeName,
      @Consumption.filter.hidden: true
      _MaterialGroupValueHelp.MaterialGroupName,
      @Consumption.filter.hidden: true
      @Semantics.text: true
      _Supplier.SupplierName

}