C_PurchaseOrderPartnerTP

@AbapCatalog.sqlViewName: 'CPURORDPTNR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Purchase Order Partner'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@ObjectModel: {
    createEnabled : true,
    deleteEnabled : true,
    updateEnabled : true,
    draftEnabled  : true
}
@UI.headerInfo: {
      typeName        : 'Partner',
      typeNamePlural  : 'Partners'
}
@ObjectModel.transactionalProcessingDelegated: true
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AbapCatalog.preserveKey:true
@AccessControl.personalData.blocking: #REQUIRED
@Search.searchable: true

define view C_PurchaseOrderPartnerTP
  as select from I_PurchaseOrderPartnerTP as PurchaseOrderPartnerTP
  association [1..1] to C_PurchaseOrderTP           as _PurchaseOrder             on  _PurchaseOrder.PurchaseOrder = $projection.PurchaseOrder
  association [0..*] to I_PurOrderPartnerFunctionVH as _PurOrderPartnerFunctionVH on  _PurOrderPartnerFunctionVH.PartnerFunction = $projection.PartnerFunction
  association [0..1] to I_PurgDocumentPartnerVH     as _PurgDocumentPartnerVH     on  _PurgDocumentPartnerVH.PurchasingDocumentPartner     = $projection.PurchasingDocumentPartner
                                                                                  and _PurgDocumentPartnerVH.PurchasingDocumentPartnerType = $projection.PurchasingDocumentPartnerType
{
             @UI.hidden: true
  key        PurchaseOrderPartnerTP.PurchaseOrder,
             @UI.hidden: true
             @ObjectModel.readOnly: true
  key        PurchaseOrderPartnerTP.PartnerFunction,
             @UI.hidden: true
  key        PurchaseOrderPartnerTP.PurchasingOrganization,
             @UI.hidden: true
  key        PurchaseOrderPartnerTP.SupplierSubrange,
             @UI.hidden: true
  key        PurchaseOrderPartnerTP.Plant,
             @UI.hidden: true
  key        PurchaseOrderPartnerTP.PartnerCounter,
             @UI.hidden: true
             PurchaseOrderPartnerTP.CreatedByUser,
             @UI.hidden: true
             PurchaseOrderPartnerTP.CreationDate,
             @ObjectModel: { readOnly: true }
             @UI.hidden: true
             PurchaseOrderPartnerTP.PartnerFunctionName,
             @ObjectModel: { readOnly: true }
             @UI.hidden: true
             PurchaseOrderPartnerTP.PurchasingDocumentPartnerType,
             @Consumption.valueHelpDefinition: [{entity: {name: 'I_PurOrderPartnerFunctionVH', element: 'PartnerFunction'}, additionalBinding: [{ element: 'PurchaseOrderType', localElement: 'PurchaseOrderType' }] } ]
             @UI: {
             identification: [{position: 10, qualifier: 'PartnerItem'}],
             lineItem: [ {position: 10, importance: #HIGH, qualifier: 'PartnerItem'} ]
             }
             @ObjectModel.text.association: '_PartnerFunctionText'
             @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION'}
             @ObjectModel.editableFieldFor: 'PartnerFunction'
             @Search.defaultSearchElement: true
             PurchaseOrderPartnerTP.PartnerFunctionForEdit,
             @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
             @UI.hidden: true
             PurchaseOrderPartnerTP.Supplier,
             @UI.hidden: true
             PurchaseOrderPartnerTP.SupplierHierarchyCategory,
             @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
             @UI.hidden: true
             PurchaseOrderPartnerTP.SupplierContact,
             @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
             @UI.hidden: true
             PurchaseOrderPartnerTP.PersonWorkAgreement,
             @ObjectModel: { readOnly: true }
             PurchaseOrderPartnerTP.DefaultPartner,
             @UI: {
             identification: [{position: 20, qualifier: 'PartnerItem'}],
             lineItem: [ {position: 20, importance: #HIGH, qualifier: 'PartnerItem'} ]
             }
             @ObjectModel.text.element:  [ 'PurchasingDocumentPartnerName' ]
             @Consumption.valueHelpDefinition: [{entity: {name: 'I_PurgDocumentPartnerVH', element: 'PurchasingDocumentPartner'} }]
             @ObjectModel: { readOnly: 'EXTERNAL_CALCULATION' }
             //@Search.fuzzinessThreshold: 0.8    -> removed due to HANA search dump on dyn. generated fields (see DINC0471335)

             //@Search.defaultSearchElement: true -> removed due to HANA search dump on dyn. generated fields (see DINC0471335)

             PurchaseOrderPartnerTP.PurchasingDocumentPartner,
             @ObjectModel: { readOnly: true }
             @UI.hidden: true
             PurchaseOrderPartnerTP.PurchasingDocumentPartnerName,
             @UI.hidden: true
             @ObjectModel: { readOnly: true }
             _PurchaseOrder.PurchaseOrderType,
             /* Associations */
             _PurgDocumentPartnerVH,
             PurchaseOrderPartnerTP._PartnerFunction,
             PurchaseOrderPartnerTP._PartnerFunctionText,
             PurchaseOrderPartnerTP._PersonWorkAgreement,
             PurchaseOrderPartnerTP._Plant,
             PurchaseOrderPartnerTP._PurchasingOrganization,
             PurchaseOrderPartnerTP._Supplier,
             PurchaseOrderPartnerTP._SupplierContact,
             @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
             _PurchaseOrder,
             _PurOrderPartnerFunctionVH
}