I_PURCHASEORDERPARTNERTP

CDS View

Purchase Order Partner - TP

I_PURCHASEORDERPARTNERTP is a CDS View in S/4HANA. Purchase Order Partner - TP. It contains 25 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 25 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_PurchaseOrderPartnerTP view from CONSUMPTION Purchase Order Partner

Fields (25)

KeyField CDS FieldsUsed in Views
KEY PartnerCounter PartnerCounter 1
KEY PartnerFunction PartnerFunction 1
KEY Plant Plant 1
KEY PurchaseOrder PurchaseOrder 1
KEY PurchasingOrganization PurchasingOrganization 1
KEY SupplierSubrange SupplierSubrange 1
_PartnerFunction _PartnerFunction 1
_PartnerFunctionText _PartnerFunctionText 1
_PersonWorkAgreement _PersonWorkAgreement 1
_Plant _Plant 1
_PurchasingOrganization _PurchasingOrganization 1
_Supplier _Supplier 1
_SupplierContact _SupplierContact 1
CreatedByUser CreatedByUser 1
CreationDate CreationDate 1
DefaultPartner DefaultPartner 1
PartnerFunctionForEdit PartnerFunctionForEdit 1
PartnerFunctionName PartnerFunctionName 1
PersonWorkAgreement PersonWorkAgreement 1
PurchasingDocumentPartner PurchasingDocumentPartner 1
PurchasingDocumentPartnerName PurchasingDocumentPartnerName 1
PurchasingDocumentPartnerType PurchasingDocumentPartnerType 1
Supplier Supplier 1
SupplierContact SupplierContact 1
SupplierHierarchyCategory SupplierHierarchyCategory 1 
@VDM.viewType: #TRANSACTIONAL
@AbapCatalog.sqlViewName: 'IPURORDPTNR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Purchase Order Partner - TP'
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
    createEnabled : true,
    deleteEnabled : true,
    updateEnabled : true
}
@ObjectModel.semanticKey: ['PurchaseOrder']
@ObjectModel.writeDraftPersistence: 'PURORDPTNR_D'
@AbapCatalog.preserveKey:true



define view I_PurchaseOrderPartnerTP
  as select from R_PurchaseOrderPartner as PurchaseOrderPartner
  association [1..1] to I_PurchaseOrderTP as _PurchaseOrder on _PurchaseOrder.PurchaseOrder = $projection.PurchaseOrder
{

  key PurchaseOrderPartner.PurchaseOrder,
      @ObjectModel.readOnly: true
  key PurchaseOrderPartner.PartnerFunction,
  key PurchaseOrderPartner.PurchasingOrganization,
  key PurchaseOrderPartner.SupplierSubrange,
  key PurchaseOrderPartner.Plant,
  key PurchaseOrderPartner.PartnerCounter,
      PurchaseOrderPartner.CreatedByUser,
      PurchaseOrderPartner.CreationDate,
      PurchaseOrderPartner.PurchasingDocumentPartnerType,
      PurchaseOrderPartner.Supplier,
      PurchaseOrderPartner.SupplierHierarchyCategory,
      PurchaseOrderPartner.SupplierContact,
      PurchaseOrderPartner.PersonWorkAgreement,
      PurchaseOrderPartner.EmploymentInternalID,
      PurchaseOrderPartner.DefaultPartner,
      @ObjectModel.editableFieldFor: 'PartnerFunction'
      PurchaseOrderPartner.PartnerFunction                                                               as PartnerFunctionForEdit,
      @ObjectModel.text.association: '_PartnerFunctionText'
      PurchaseOrderPartner._PartnerFunctionText[Language = $session.system_language].PartnerFunctionName as PartnerFunctionName,
      @ObjectModel.text.element:  [ 'PurchasingDocumentPartnerName' ]
      cast( case PurchasingDocumentPartnerType
        when 'LI' then PurchaseOrderPartner.Supplier
        when 'AP' then PurchaseOrderPartner.SupplierContact
        when 'PE' then PurchaseOrderPartner.PersonWorkAgreement
      end as mm_pur_partner )                                                                            as PurchasingDocumentPartner,

      cast( case PurchasingDocumentPartnerType
        when 'LI' then PurchaseOrderPartner._Supplier.SupplierFullName
        when 'AP' then PurchaseOrderPartner._SupplierContact.BusinessPartnerName
        when 'PE' then PurchaseOrderPartner._PersonWorkAgreement.PersonFullName
      end as mm_pur_partnername )                                                                        as PurchasingDocumentPartnerName,
      /* Associations */
      PurchaseOrderPartner._PartnerFunction,
      PurchaseOrderPartner._PersonWorkAgreement,
      PurchaseOrderPartner._Plant,
      PurchaseOrderPartner._PurchasingOrganization,
      PurchaseOrderPartner._Supplier,
      PurchaseOrderPartner._SupplierContact,
      PurchaseOrderPartner._PartnerFunctionText,
      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _PurchaseOrder

}

Learn More