C_POAccountAssignmentFactSheet

@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'CPOACCASSFS'

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #MIXED
@UI.headerInfo:{
  typeName: 'Purchase Order Account Assignment',
  typeNamePlural: 'Purchase Order Account Assignment',
  title.value: 'AccountAssignmentNumber'
  //description.value: 'PurchaseOrderItemCategory'

}
@ObjectModel: {
    semanticKey: ['PurchaseOrder', 'PurchaseOrderItem', 'AccountAssignmentNumber'],
    representativeKey: 'AccountAssignmentNumber'
}
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Purchase Order Account Assignment'
define view C_POAccountAssignmentFactSheet
  as select from I_PurOrdAccountAssignment
  association [0..*] to P_Purordmaintaincustproj       as _PurOrdCustProj               on  $projection.WBSElementInternalID = _PurOrdCustProj.WBSElementInternalID

  association [0..1] to I_MasterFixedAsset             as _MasterFixedAsset             on  $projection.CompanyCode      = _MasterFixedAsset.CompanyCode
                                                                                        and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset

  association [0..1] to I_FixedAsset                   as _FixedAsset                   on  $projection.MasterFixedAsset = _FixedAsset.MasterFixedAsset
                                                                                        and $projection.FixedAsset       = _FixedAsset.FixedAsset
                                                                                        and $projection.CompanyCode      = _FixedAsset.CompanyCode

  association [0..1] to I_ProjectNetwork               as _ProjectNetwork               on  $projection.ProjectNetwork = _ProjectNetwork.ProjectNetwork

  association [0..1] to I_NetworkActivityByInternalKey as _NetworkActivityByInternalKey on  $projection.ProjectNetworkInternalID  = _NetworkActivityByInternalKey.ProjectNetworkInternalID
                                                                                        and $projection.NetworkActivityInternalID = _NetworkActivityByInternalKey.NetworkActivityInternalID

  association [0..1] to I_CostCenterText               as _CostCenterDesc               on  $projection.CostCenter      =  _CostCenterDesc.CostCenter
                                                                                        and $projection.ControllingArea =  _CostCenterDesc.ControllingArea
                                                                                        and $projection.ValidityDate    <= _CostCenterDesc.ValidityEndDate
                                                                                        and $projection.ValidityDate    >= _CostCenterDesc.ValidityStartDate
                                                                                        and _CostCenterDesc.Language    = $session.system_language

  association [0..1] to I_GLAccountText                as _GLAccountDesc                on  $projection.GLAccount       = _GLAccountDesc.GLAccount
                                                                                        and $projection.ChartOfAccounts = _GLAccountDesc.ChartOfAccounts
                                                                                        and _GLAccountDesc.Language     = $session.system_language

  association [0..1] to I_FunctionalAreaText           as _FunctionalAreaDesc           on  $projection.FunctionalArea   = _FunctionalAreaDesc.FunctionalArea
                                                                                        and _FunctionalAreaDesc.Language = $session.system_language

  association [0..1] to I_ProfitCenterText             as _ProfitCenterDesc             on  $projection.ProfitCenter    =  _ProfitCenterDesc.ProfitCenter
                                                                                        and $projection.ControllingArea =  _ProfitCenterDesc.ControllingArea
                                                                                        and $projection.ValidityDate    <= _ProfitCenterDesc.ValidityEndDate
                                                                                        and $projection.ValidityDate    >= _ProfitCenterDesc.ValidityStartDate
                                                                                        and _ProfitCenterDesc.Language  = $session.system_language


{
      @UI.facet: [
                  { label:'General Information',
                    id:'GeneralInformation',
                    isSummary: true,
                    type: #COLLECTION,
                    position: 10
                  },
                    {
                      label: 'Basic Data',
                      id: 'BasicData',
                      parentId: 'GeneralInformation',
                      type: #IDENTIFICATION_REFERENCE,
                      position: 10
                    },
                    {
                      label: 'Asset Management',
                      id: 'AssetManagementGroupID',
                      parentId: 'GeneralInformation',
                      type: #FIELDGROUP_REFERENCE,
                      position: 20,
                      targetQualifier: 'AssetManagementGroup'
                    },
                    {
                      label: 'Network',
                      id: 'NetworkGroupID',
                      parentId: 'GeneralInformation',
                      type: #FIELDGROUP_REFERENCE,
                      position: 30,
                      targetQualifier: 'NetworkGroup'
                    },
                    {
                      label: 'Sales and Distribution Information',
                      id: 'SDInfoGroupID',
                      parentId: 'GeneralInformation',
                      type: #FIELDGROUP_REFERENCE,
                      position: 40,
                      targetQualifier: 'SDInfoGroup'
                    },
                    {
                      label: 'Project',
                      id: 'ProjectGroupID',
                      parentId: 'GeneralInformation',
                      type: #FIELDGROUP_REFERENCE,
                      position: 50,
                      targetQualifier: 'ProjectGroup'
                    },
                    {
                      label: 'Service Order',
                      id: 'ServiceOrderGroupID',
                      parentId: 'GeneralInformation',
                      type: #FIELDGROUP_REFERENCE,
                      position: 60,
                      targetQualifier: 'ServiceOrderGroup'
                    }
                 ]

      @ObjectModel.foreignKey.association: '_PurchaseOrder'
  key PurchaseOrder,
      @ObjectModel.foreignKey.association: '_PurchaseOrderItem'
  key PurchaseOrderItem,

      @UI.lineItem: [{
                qualifier: 'AccAssItem',
                position: 10,
                importance: #HIGH }, {
                position: 10,
                importance: #HIGH
                }]
  key AccountAssignmentNumber,

      @Consumption.hidden: true
      CompanyCode,

      @Consumption.hidden: true
      ValidityDate,

      @UI:{ identification: {position: 90, importance: #HIGH}}
      @ObjectModel.text.association: '_CostCenterDesc'
      @UI.lineItem: [{
            qualifier: 'AccAssItem',
            position: 30,
            importance: #HIGH }, {
            position: 30,
            importance: #HIGH
            }]
      CostCenter,

      @UI.fieldGroup: [ { groupLabel: 'AssetManagement', position: 120, qualifier: 'AssetManagementGroup' } ]
      @ObjectModel.text.association: '_MasterFixedAsset'
      @UI.lineItem: [{
            qualifier: 'AccAssItem',
            position: 60,
            importance: #HIGH }, {
            position: 60,
            importance: #HIGH
            }]
      MasterFixedAsset,

      @UI.fieldGroup: [ { groupLabel: 'AssetManagement', position: 130, qualifier: 'AssetManagementGroup' } ]
      @ObjectModel.text.association: '_FixedAsset'
      FixedAsset,

      @UI.fieldGroup: [ { groupLabel: 'Network', position: 100, qualifier: 'NetworkGroup' } ]
      @ObjectModel.text.association: '_ProjectNetwork'
      @UI.lineItem: [{
            qualifier: 'AccAssItem',
            position: 50,
            importance: #HIGH }, {
            position: 50,
            importance: #HIGH
            }]
      ProjectNetwork,

      @Consumption.hidden: true
      NetworkActivityInternalID,

      @Consumption.hidden: true
      ProjectNetworkInternalID,

      @UI.fieldGroup: [ { groupLabel: 'Network', position: 110, qualifier: 'NetworkGroup' } ]
      _NetworkActivityByInternalKey.NetworkActivity,

      @UI:{ identification: {position: 20, importance: #HIGH}}
      @UI.lineItem: [{
            qualifier: 'AccAssItem',
            position: 20,
            importance: #HIGH }, {
            position: 20,
            importance: #HIGH
            }]
      MultipleAcctAssgmtDistrPercent,

      @UI:{ identification: {position: 80, importance: #HIGH}}
      @ObjectModel.text.association: '_GLAccountDesc'
      @UI.lineItem: [{
            qualifier: 'AccAssItem',
            position: 40,
            importance: #HIGH }, {
            position: 40,
            importance: #HIGH
            }]
      GLAccount,

      @Consumption.hidden: true
      ChartOfAccounts,

      @UI.fieldGroup: [ { groupLabel: 'SDInfo', position: 40, qualifier: 'SDInfoGroup' } ]
      SalesOrder,

      @UI.fieldGroup: [ { groupLabel: 'SDInfo', position: 50, qualifier: 'SDInfoGroup' } ]
      @EndUserText.label: 'SD Item'
      SalesOrderItem,

      @UI.fieldGroup: [ { groupLabel: 'SDInfo', position: 60, qualifier: 'SDInfoGroup' } ]
      OrderID,

      @UI.identification.position: 180
      UnloadingPointName,

      @UI.identification.position: 190
      @ObjectModel.text.association: '_ControllingArea'
      ControllingArea,

      @UI.identification.position: 110
      @ObjectModel.text.association: '_ProfitCenterDesc'
      ProfitCenter,

      @UI.fieldGroup: [ { groupLabel: 'Project', position: 10, qualifier: 'ProjectGroup' } ]
      @UI.lineItem: [{
            qualifier: 'AccAssItem',
            position: 70,
            importance: #HIGH }, {
            position: 70,
            importance: #HIGH
            }]
      WBSElementExternalID,

      @Consumption.hidden: true
      cast ( WBSElementInternalID as ps_s4_pspnr preserving type )  as WBSElementInternalID,

      @Consumption.hidden: true

      CommitmentItemShortID,

      @UI.identification.position: 240
      _CommitmentItemShortID.CommitmentItem,

      @UI.identification.position: 210
      FundsCenter,

      @UI.identification.position: 200
      Fund,

      @UI.identification.position: 100
      @ObjectModel.text.association: '_FunctionalAreaDesc'
      FunctionalArea,

      @UI.identification.position: 280
      GoodsRecipientName,

      @UI.identification.position: 270
      BusinessProcess,

      @UI.identification.position: 250
      GrantID,

      @UI.identification.position: 260
      BudgetPeriod,

      @UI.identification.position: 220
      EarmarkedFundsDocument,

      @UI.identification.position: 230
      EarmarkedFundsDocumentItem,

      @UI.fieldGroup: [ { groupLabel: 'ServiceOrder', position: 300, qualifier: 'ServiceOrderGroup' } ]
      ServiceDocumentType,

      @UI.fieldGroup: [ { groupLabel: 'ServiceOrder', position: 310, qualifier: 'ServiceOrderGroup' } ]
      ServiceDocument,

      @UI.fieldGroup: [ { groupLabel: 'ServiceOrder', position: 320, qualifier: 'ServiceOrderGroup' } ]
      ServiceDocumentItem,

      @UI.fieldGroup: [ { groupLabel: 'Project', position: 20, qualifier: 'ProjectGroup' } ]
      @EndUserText.label: 'Project Name'
      _PurOrdCustProj.CustomerProjectName     as ProjectName,

      @UI.fieldGroup: [ { groupLabel: 'Project', position: 30, qualifier: 'ProjectGroup' } ]
      @EndUserText.label: 'Work Package Name'
      _PurOrdCustProj.CustProjWorkPackageName as WorkPackageName,

      _PurchaseOrder,
      _PurchaseOrderItem,
      _CostCenterDesc,
      _ControllingArea,
      _MasterFixedAsset,
      _FixedAsset,
      _ProjectNetwork,
      _GLAccountDesc,
      _FunctionalAreaDesc,
      _ProfitCenterDesc

}