C_NetworkActivityForGraph

@AbapCatalog.sqlViewName: 'CNWACFORGRAPH'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory : #XL
@ObjectModel.usageType.dataClass: #MIXED
@EndUserText.label: 'Network Activity For Graph'
@Metadata: { ignorePropagatedAnnotations: true,
             allowExtensions:true }
             
define view C_NetworkActivityForGraph
  as select from I_NetworkActivityByInternalKey
  association [1..1] to I_NetworkActivityDatesQuantity as _NetworkActivityDatesQuantity on  $projection.ProjectNetworkInternalID  = _NetworkActivityDatesQuantity.ProjectNetworkInternalID
                                                                                        and $projection.NetworkActivityInternalID = _NetworkActivityDatesQuantity.NetworkActivityInternalID
  association [1..1] to I_OperationControlProfileText  as _OperationControlProfileText  on  $projection.NetworkActivityControlProfile = _OperationControlProfileText.OperationControlProfile
                                                                                        and _OperationControlProfileText.Language     = $session.system_language
  association [0..1] to I_Supplier                     as _Supplier                     on  $projection.Supplier = _Supplier.Supplier
  association [0..1] to I_NetworkActivityByInternalKey as _Superior                     on  $projection.SuperiorNtwkActivityInternalID = _Superior.NetworkActivityInternalID
                                                                                        and $projection.ProjectNetworkInternalID       = _Superior.ProjectNetworkInternalID

{
  key ProjectNetworkInternalID,
  key NetworkActivityInternalID,
      NetworkActivityDescription,
      NetworkActivity,
      @EndUserText.label: 'Control Description'
      @Semantics.text: true
      cast ( _OperationControlProfileText.OperationControlProfileName as ps_s4_pph_steutxt ) as OperationControlProfileName,
      @EndUserText.label: 'Control Key'
      @ObjectModel.text.element: ['OperationControlProfileName']
      NetworkActivityControlProfile,
      _NetworkActivityDatesQuantity.SchedldBasicEarliestStartDate,
      _NetworkActivityDatesQuantity.SchedldBasicEarliestEndDate,
      _NetworkActivityDatesQuantity.SchedldBasicLatestStartDate,
      _NetworkActivityDatesQuantity.ScheduledBasicLatestEndDate,
      _NetworkActivityDatesQuantity.SchedldFcstdEarliestStartDate,
      _NetworkActivityDatesQuantity.SchedldFcstdEarliestEndDate,
      _NetworkActivityDatesQuantity.LatestSchedldFcstdStartDate,
      _NetworkActivityDatesQuantity.LatestSchedldFcstdEndDate,
      IsMarkedForDeletion,
      // Fields for Milestone Graph Overview

      SuperiorNtwkActivityInternalID,
      cast ( ( case
         when SuperiorNtwkActivityInternalID is initial
             then ''
         else _Superior.NetworkActivity
      end   ) as ps_vornr_el )                                                               as SuperiorNtwkActivityExternalID,
      // Fields and Association for DCL

      Plant,
      _WorkCenter.WorkCenter,
      Supplier,
      _Supplier,
      // Associations

      _NetworkActivityDatesQuantity,
      _OperationControlProfileText,
      // Association for Milestone Graph Overview

      _Superior
}