C_MfgOrderProdVersionObjPg

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Production Version'
@Search.searchable: true
@VDM.viewType: #CONSUMPTION
@Metadata.allowExtensions: true
@ObjectModel.representativeKey: 'ProductionVersion'
@Analytics.technicalName: 'CPRODVEROBJPAG'
@Analytics: { dataCategory: #DIMENSION}
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED }

@UI.headerInfo: {
  typeName: 'Production Version',
  typeNamePlural: 'List of Materials',
  title: {
    value: 'Material'
  },
  description: {
    value: 'MaterialName'
  }
}

define view entity C_MfgOrderProdVersionObjPg

  as select from I_ProductionVersion

  association [1..1] to I_BillOfMaterialUsage as I_BillOfMaterialUsage     on  $projection.BillOfMaterialVariantUsage = I_BillOfMaterialUsage.BillOfMaterialVariantUsage
  //Added to get other header material text

  association [1..1] to I_Material            as _OtherMaterial            on  $projection.MainProduct = _OtherMaterial.Material

  association [1..1] to I_StorageLocation     as _IssuingStorageLocation   on  $projection.IssuingStorageLocation = _IssuingStorageLocation.StorageLocation
                                                                           and $projection.Plant                  = _IssuingStorageLocation.Plant

  association [1..1] to I_StorageLocation     as _ReceivingStorageLocation on  $projection.ReceivingStorageLocation = _ReceivingStorageLocation.StorageLocation
                                                                           and $projection.Plant                    = _ReceivingStorageLocation.Plant
{
      @UI.lineItem:[{position:10}]
      @ObjectModel.text.element: [ 'MaterialName']
      @UI.selectionField: [ {position: 10 }]
      @ObjectModel.foreignKey.association: '_Material'
  key Material,

      @UI.lineItem:[{position:20}]
      @ObjectModel.text.element: [ 'PlantName']
      @UI.selectionField: [ {position: 20 }]
      @UI.dataPoint:{ title: 'Plant'}
      @ObjectModel.foreignKey.association: '_Plant'
  key Plant,
      @UI.lineItem:[{position:30}]
      @ObjectModel.text.element: [ 'ProductionVersionText']
      @UI.selectionField: [ {position: 30 }]
      @UI.dataPoint:{ title: 'Production Version'}
  key ProductionVersion,

      @Semantics.text: true
      _Material._Text[1: Language=$session.system_language].MaterialName                             as MaterialName,

      @Semantics.text: true
      @UI.dataPoint:{ title: 'Plant Name'}
      I_ProductionVersion._Plant.PlantName,

      @UI.dataPoint:{ title: 'Production Version Description'}
      ProductionVersionText,

      @UI.identification: [{position:10}]
      @EndUserText.label: 'Lock'
      ProductionVersionIsLocked,
      @UI.identification: [{position:20}]
      ChangeNumber,
      MaterialBaseUnit,
      @Semantics.quantity.unitOfMeasure: 'MATERIALBASEUNIT' 
@UI.lineItem:[{position:60}]
      @UI.identification: [{position:30}]
      MaterialMinLotSizeQuantity,
      @Semantics.quantity.unitOfMeasure: 'MATERIALBASEUNIT' 
@UI.lineItem:[{position:70}]
      @UI.identification: [{position:40}]
      MaterialMaxLotSizeQuantity,
      @UI.identification: [{position:50}]
      ValidityStartDate,
      @UI.identification: [{position:60}]
      ValidityEndDate,

      //@UI.hidden: true

      //BillOfOperationsType                                                          as BillOfOperations,


      // Routing

      @UI.fieldGroup: [{qualifier:'TaskList',position:10}]
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
      cast(BillOfOperationsType as plnty preserving type )                                           as BillOfOperationsType,
      @UI.fieldGroup: [{qualifier:'TaskList',position:20}]
      cast(BillOfOperationsGroup as plnnr preserving type)                                           as BillOfOperationsGroup,
      @UI.fieldGroup: [{qualifier:'TaskList',position:30}]
      cast(BillOfOperationsVariant as plnal)                                                         as BillOfOperationsVariant,

      // BOM

      BillOfMaterialVariantUsage,
      @UI.fieldGroup: [{qualifier:'BOM',position:20}]
      @EndUserText.label: 'BOM Usage'
      i_billofmaterialusage.BillOfMaterialVariantUsageDesc,
      @UI.fieldGroup: [{qualifier:'BOM',position:10}]
      BillOfMaterialVariant,
      @UI.fieldGroup: [{qualifier:'BOM',position:30}]
      @ObjectModel.foreignKey.association: '_MatlCostApportionmentStruc'
      MaterialCostApportionmentStruc,

      //Repetitive Manufacturing

      @UI.fieldGroup: [{qualifier:'RepeManufacturing',position:10}]
      ProdnVersIsAllowedForRptvMfg,
      @UI.lineItem:[{position:40}]
      @UI.selectionField: [ {position: 40 }]
      @UI.fieldGroup: [{qualifier:'RepeManufacturing',position:20}]
      ProductionLine,
      @UI.fieldGroup: [{qualifier:'RepeManufacturing',position:30}]
      @ObjectModel.foreignKey.association: '_ProductionVersionGroup'
      ProductionVersionGroup,

      //Administration

      @UI.fieldGroup: [{qualifier:'Administration',position:10}]
      CreationDate,
      @UI.fieldGroup: [{qualifier:'Administration',position:20}]
      CreatedByUser,
      @UI.fieldGroup: [{qualifier:'Administration',position:30}]
      LastChangeDate,
      @UI.fieldGroup: [{qualifier:'Administration',position:40}]
      LastChangedByUser,

      //OTHERS

      @UI.fieldGroup: [{qualifier:'Others',position:10}]
      @EndUserText.label: 'Other Header Material'
      @ObjectModel.foreignKey.association: '_OtherMaterial'
      MainProduct,
      @UI.fieldGroup: [{qualifier:'Others',position:20}]
      @EndUserText.label: 'Issue Storage Location'
      @ObjectModel.foreignKey.association: '_IssuingStorageLocation'
      IssuingStorageLocation,
      @UI.fieldGroup: [{qualifier:'Others',position:30}]
      @ObjectModel.foreignKey.association: '_ReceivingStorageLocation'
      ReceivingStorageLocation,
      @UI.fieldGroup: [{qualifier:'Others',position:40}]
      @EndUserText.label: 'OB Reference Material'
      OriginalBatchReferenceMaterial,
      @UI.fieldGroup: [{qualifier:'Others',position:50}]
      @UI.lineItem:[{position:50}]
      @UI.selectionField: [ {position: 50 }]
      ProductionSupplyArea,

      _Material,
      _OtherMaterial,
      _IssuingStorageLocation,
      _ReceivingStorageLocation,
      _Plant,
      _BillOfOperationsType,
      _ProductionLine,
      _ProductionSupplyArea,
      _MatlCostApportionmentStruc,
      _ProductionVersionGroup
};